Ссылка команд

В этой главе описываются команды, доступные для выполнения действий в сценариях AppleScript. Для получения информации о том, как команды работают, видят Обзор Команд.

Команды, описанные в этой главе, доступны любому сценарию — они или встроены в язык AppleScript или добавлены к нему посредством стандартных дополнений сценариев (описанный в Сценариях Дополнений).

Таблица 7-1 перечисляет каждую команду согласно комплекту (или связанная группа) команд, к которым это принадлежит и предоставляет краткое описание. Подробные описания команды следуют за таблицей в алфавитном порядке.

Выявляет приложение, запуская его при необходимости.

Синтаксис

Результат

Ни один.

Примеры

activate application "TextEdit"

tell application "TextEdit" to activate

Возвращает символ для конкретного количества.

Синтаксис

Результат

A text объект, содержащий символ, соответствующий конкретному количеству.

Если целое число вне диапазона, сигнализирует ошибку.

Примеры

set theChar to ASCII character 65 --result: "A"

set theChar to ASCII character 194 --result: "¬"

set theChar to ASCII character 2040 --result: invalid range error

Возвращает число, связанное с указанным символом.

Синтаксис

Результат

Код символа указанного символа как целое число.

Примеры

set codeValue to ASCII number "¬" --result: 194

Играет системное предупреждение звучат один или несколько раз.

Синтаксис

Результат

Ни один.

Примеры

Слышимые предупреждения могут быть полезными, когда никто, как не ожидают, будет смотреть на экран:

beep 3 --result: three beeps, to get attention

display dialog "Something is amiss here!" -- to show message

Позволяет пользователю выбирать приложение.

Синтаксис

Результат

Выбранное приложение, как любой application или alias объект; например, application "TextEdit". Если множественные выборы позволяются, возвращает список, содержащий один элемент для каждого выбранного приложения, если таковые имеются.

Сигнализирует, что “пользователь отменил” ошибку, если пользователь отменяет диалоговое окно. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

choose application with prompt "Choose a web browser:"

choose application with multiple selections allowed

choose application as alias

Позволяет пользователю выбирать цвет из диалогового окна палитры цветов.

Синтаксис

Результат

Выбранный цвет, представленный как список трех целых чисел от 0 до 65 535 соответствий красным, зеленым, и синим компонентам цвета; например, {0, 65535, 0} представляет зеленый.

Сигнализирует, что “пользователь отменил” ошибку, если пользователь отменяет choose color диалоговое окно. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

Этот пример позволяет пользователю выбрать цвет, затем использует тот цвет для выбирания цвета фона в их домашней папке (когда это находится в представлении в виде значков):

tell application "Finder"

    tell icon view options of window of home

        choose color default color (get background color)

        set background color to the result

    end tell

end tell

Позволяет пользователю выбирать файл.

Синтаксис

Результат

Выбранный файл, как alias. Если множественные выборы позволяются, возвращает список, содержащий один alias для каждого выбранного файла, если таковые имеются.

Сигнализирует, что “пользователь отменил” ошибку, если пользователь отменяет диалоговое окно. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

set aFile to choose file with prompt "HTML or RTF:" ¬

    of type {"public.html", "public.rtf"} invisibles false

UTI может указать общий класс файлов, не только определенный формат. Следующий сценарий позволяет пользователю выбирать любой файл образа, является ли его формат JPEG, PNG, GIF,или что бы то ни было. Это также использует default location параметр объединился с path to (folder) начать просматривать в пользователе Pictures папка:

set picturesFolder to path to pictures folder

choose file of type "public.image" with prompt "Choose an image:" ¬

    default location picturesFolder invisibles false

Позволяет пользователю указывать новое имя файла и расположение. Это не создает файл — скорее он возвращает спецификатор файла, который может использоваться для создания файла.

Синтаксис

Результат

Выбранное расположение, как a file. Например:

file "HD:Users:currentUser:Documents:untitled"

Сигнализирует, что “пользователь отменил” ошибку, если пользователь отменяет диалоговое окно. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

Следующий пример предоставляет быстрое и поисковое расположение не по умолчанию:

set fileName to choose file name with prompt "Save report as:" ¬

default name "Quarterly Report" ¬

default location (path to desktop folder)

Позволяет пользователю выбирать каталог, такой как папка или диск.

Синтаксис

Результат

Выбранный каталог, как alias. Если множественные выборы позволяются, возвращает список, содержащий один alias для каждого выбранного каталога, если таковые имеются.

Сигнализирует, что “пользователь отменил” ошибку, если пользователь отменяет choose folder диалоговое окно. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

Следующий пример указывает подсказку и позволяет множественные выборы:

set foldersList to choose folder ¬

    with prompt "Select as many folders as you like:" ¬

    with multiple selections allowed

Следующий пример получает путь POSIX к выбранной папке и использует quoted form свойство ( text класс) для обеспечения корректного заключения в кавычки получившей строки для использования с командами оболочки:

set folderName to quoted form of POSIX path of (choose folder)

Предположим, что Вы выбираете названную папку iWork '08 в Вашем Applications папка. Предыдущая выписка возвратила бы следующий результат, должным образом обрабатывающий встроенную одинарную кавычку и пробелы на имя папки:

"'/Applications/iWork '\\''08/'"

Позволяет пользователю выбирать элементы из списка.

Синтаксис

Результат

Если пользователь щелкает по кнопке OK, a возвратов list из выбранного number и/или text элементы; если пустой выбор позволяется, и ничто не выбрано, возвращает пустой список ({}). Если пользователь щелкает по Кнопке отмены, возвратам false.

Примеры

Этот сценарий выбирает из списка всех людей в Адресной книге, определивших дни рождения, и получает день рождения выбранного. Заметьте if the result is not false тест (choose from list возвраты false если пользователь нажимает Cancel), и set aName to item 1 of the result (choose from list возвращает список, даже если он содержит только один элемент).

tell application "Address Book"

    set bDayList to name of every person whose birth date is not missing value

    choose from list bDayList with prompt "Whose birthday would you like?"

    if the result is not false then

        set aName to item 1 of the result

        set theBirthday to birth date of person named aName

        display dialog aName & "'s birthday is " & date string of theBirthday

    end if

end tell

Позволяет пользователю выбирать запущенное приложение на удаленной машине.

Синтаксис

Результат

Выбранное приложение, как application объект.

Сигнализирует, что “пользователь отменил” ошибку, если пользователь отменяет диалоговое окно. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

set myApp to choose remote application with prompt "Choose a remote web browser:"

Позволяет пользователю указывать URL.

Синтаксис

Результат

URL для службы, как a text объект. Этот результат может быть передан open location или к любому приложению, которое может обработать URL, такой как браузер для http URLs.

Сигнализирует, что “пользователь отменил” ошибку, если пользователь отменяет диалоговое окно. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

Следующий сценарий просит, чтобы пользователь выбрал URL, или путем ввода в поле ввода текста или выбора одного из Добрый день расположенных серверов:

set myURL to choose URL

tell application Finder to open location myURL

Информация о возвратах о текущем содержании буфера обмена.

Синтаксис

Результат

A list содержа одну запись {class, size} для каждого типа данных по буферу обмена. Для получения фактических данных используйте the clipboard команда.

Примеры

clipboard info

clipboard info for Unicode text

Закрывает файл, открытый с open for access команда.

Синтаксис

Результат

Ни один.

Если указанный файл не открыт, сигнализирует ошибку.

Примеры

Необходимо всегда закрывать файлы, которые Вы открываете, будучи убеждающимися составить возможные ошибки при использовании открытого файла:

set aFile to choose file

set fp to open for access aFile

try

    --file reading and writing here

on error e number n

    --deal with errors here and don't resignal

end

close access fp

Копии одно или более значений, храня результат в одной или более переменных. Эта команда только копирует значения AppleScript, не определенные с помощью приложения объекты.

Синтаксис

Результат

Новая копия значения.

Примеры

Как упомянуто в Обсуждении, copy создает независимую копию исходного значения, и оно создает глубокую копию. Например:

set alpha to {1, 2, {"a", "b"}}

copy alpha to beta

set item 2 of item 3 of alpha to "change" --change the original list

set item 1 of beta to 42 --change a different item in the copy

{alpha, beta}

--result: {{1, 2, {"a", "change"}}, {42, 2, {"a", "b"}}}

Каждая переменная отражает только изменения, внесенные непосредственно в ту переменную. Сравните это с подобным примером в set.

Посмотрите set команда для примеров использования шаблонов переменных. Поведение является тем же за исключением того, что копируются значения.

Считает число элементов в другом объекте.

Синтаксис

Результат

Число элементов, как integer.

Примеры

В его самой простой форме, count, или эквивалентное псевдосвойство number, количества item элементы значения. Это может быть значением AppleScript, таким как список:

set aList to {"Yes", "No", 4, 5, 6}

count aList  --result: 5

number of aList  --result: 5

… или имеющий определенный с помощью приложения объект item элементы:

tell application "Finder" to count disk 1  --result: 4

Если значение является объектным спецификатором, оценивающим к списку, count считает элементы того списка. Это может быть Каждым спецификатором:

count every integer of aList  --result: 3

count words of "hello world"  --result: 2

tell application "Finder" to count folders of disk 1  --result: 4

… или спецификатор Фильтра:

tell application "Finder"

    count folders of disk 1 whose name starts with "A"  --result: 1

end tell

… или подобный. Для больше на объектных спецификаторах, посмотрите Объектные Спецификаторы.

Возвращает текущую дату и время.

Синтаксис

Результат

Текущая дата и время, как a date объект.

Примеры

current date  --result: date "Tuesday, November 13, 2007 11:13:29 AM"

Посмотрите date класс для получения информации о том, как получить доступ к свойствам даты, таким как день недели или месяца.

Ожидает конкретного количества секунд.

Синтаксис

Результат

Ни один.

Примеры

set startTime to current date

delay 3  --delay for three seconds

set elapsedTime to ((current date) - startTime)

display dialog ("Elapsed time: " & elapsedTime & " seconds")

Выводит на экран стандартизированное предупреждение, содержащее сообщение, объяснение, и от одной до трех кнопок.

Синтаксис

Результат

Если пользователь нажимает кнопку, не указанную как кнопка отмены, display alert возвращает запись, идентифицирующую кнопку, нажатую — например, {button returned: "OK"}. Если команда указывает a giving up after значение, запись будет также содержать a gave up:false элемент.

Если display alert команда указывает a giving up after значение и диалоговое окно отклонены вследствие таймаута, прежде чем пользователь нажмет кнопку, команда возвращает запись, указывающую, что никакая кнопка не была возвращена, и команда сдалась: {button returned:"", gave up:true}

Если пользователь щелкает по указанной кнопке отмены, команда сигнализирует, что “пользователь отменил” ошибку. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Примеры

set alertResult to display alert "Insert generic warning here." ¬

    buttons {"Cancel", "OK"} as warning ¬

    default button "Cancel" cancel button "Cancel" giving up after 5

Для дополнительного примера посмотрите раздел Examples для try оператор.

Выводит на экран диалоговое окно, содержащее сообщение, одну - три кнопки, и дополнительно значок и field, в котором пользователь может ввести текст.

Синтаксис

Результат

Запись, содержащая нажатую кнопку и текст, вошла, если таковые имеются. Например:

{text returned:"Cupertino", button returned:"OK"}

Если диалоговое окно не позволяет ввод текста, существует нет text returned элемент в возвращенной записи.

Если пользователь щелкает по указанной кнопке отмены, команда сигнализирует, что “пользователь отменил” ошибку. Для примера того, как обработать такие ошибки, посмотрите Операторы попытки.

Если display dialog команда указывает a giving up after значение и диалоговое окно отклонены вследствие таймаута, прежде чем пользователь нажмет кнопку, это возвращает запись, указывающую, что никакая кнопка не была возвращена, и команда сдалась: {button returned:"", gave up:true}

Примеры

Следующий пример показывает, как использовать многие параметры к a display dialog команда, как обработать возможные возвращенные значения и один способ обработать пользователя, отменила ошибку. Диалоговое окно выводит на экран две кнопки и предлагает пользователю вводить имя, сдаваясь, если они не делают ответ в течение пятнадцати секунд. Это показывает один способ обработать случай, где пользователь отменяет диалоговое окно, приводящее к AppleScript, сигнализирующему «ошибку» с кодом ошибки-128. Дополнительное использование сценария display dialog команды, чтобы показать поток логики и указать, где Вы могли добавить операторы для обработки определенных результатов.

set userCanceled to false

try

    set dialogResult to display dialog ¬

        "What is your name?" buttons {"Cancel", "OK"} ¬

        default button "OK" cancel button "Cancel" ¬

        giving up after 15 ¬

        default answer (long user name of (system info))

on error number -128

    set userCanceled to true

end try

if userCanceled then

    -- statements to execute when user cancels

    display dialog "User cancelled."

else if gave up of dialogResult then

    -- statements to execute if dialog timed out without an answer

    display dialog "User timed out."

else if button returned of dialogResult is "OK" then

    set userName to text returned of dialogResult

    -- statements to process user name

    display dialog "User name: " & userName

end if

end

Следующий пример выводит на экран диалоговое окно, просящее пароль. Это предоставляет ответ по умолчанию "wrong", и указывает, что ответ по умолчанию, а также любой текст, введенный пользователем, скрыт (выведенный на экран как серия маркеров). Это дает пользователю до трех возможностей ввести правильный пароль.

set prompt to "Please enter password:"

repeat 3 times

    set dialogResult to display dialog prompt ¬

        buttons {"Cancel", "OK"} default button 2 ¬

        default answer "wrong" with icon 1 with hidden answer

    set thePassword to text returned of dialogResult

    if thePassword = "magic" then

        exit repeat

    end if

end repeat

if thePassword = "magic" or thePassword = "admin" then

    display dialog "User entered valid password."

end if

Текст пароля копируется с возвращаемого значения dialogResult. Если пользователь отменяет выполнение остановок AppleScript сценария, сценарий не проверяет на отмененную ошибку пользователя, поэтому.

Отправляет уведомление с помощью Центра Уведомления, содержа заголовок, подзаголовок и объяснение, и дополнительно играя звук.

Синтаксис

Результат

Ни один.

Примеры

display notification "Encoding complete" subtitle "The encoded files are in the folder " & folderName

Выполняет сценарий оболочки с помощью sh оболочка.

Синтаксис

Результат

Вывод сценария оболочки.

Если сценарий оболочки выходит с ненулевым состоянием, сигнализирует ошибку. Код ошибки будет состоянием, сообщение об ошибке будет содержанием stderr.

Примеры

do shell script "uptime"

Оценивает объектный спецификатор и возвращает результат.

Название команды get является обычно дополнительным — выражения, появляющиеся как операторы, или операнды автоматически оценены, как будто ими предшествовали get. Однако get может использоваться для принуждения ранней оценки части объектного спецификатора.

Синтаксис

Результат

Значение оцененного выражения. Посмотрите Ссылочные Формы для подробных данных о том, каковы результаты оценки различных объектных спецификаторов.

Примеры

get может получить свойства или элементы AppleScript-определенных объектов, такие как списки:

get item 1 of {"How", "are", "you?"}  --result: "How"

… или определенных с помощью приложения объектов:

tell application "Finder" to get name of home  --result: "myname"

Как отмечено выше, get является обычно дополнительным. Например, эти операторы эквивалентны вышеупомянутым двум:

item 1 of {"How", "are", "you?"}  --result: "How"

tell application "Finder" to name of home  --result: "myname"

Однако явное get может быть полезно для принуждения ранней оценки части объектного спецификатора. Рассмотрите:

tell application "Finder" to get word 1 of name of home

--Finder got an error: Can’t get word 1 of name of folder "myname" of folder "Users" of startup disk.

Это перестало работать, потому что Средство поиска не знает об элементах text, такой как words. AppleScript делает, однако, таким образом, сценарий должен заставить Средство поиска добраться только name of ... часть:

tell application "Finder" to get word 1 of (get name of home)

--result: "myname"

Явное get силы, что часть спецификатора, который будет оценен; Средство поиска возвращает a text результат, от которого может тогда добраться AppleScript word 1.

Для получения дополнительной информации о спецификаторах посмотрите Объектные Спецификаторы.

Возвращает длину файла, в байтах.

Синтаксис

Результат

Логический размер файла, т.е. длины его содержания в байтах.

Примеры

Этот пример получает псевдоним к настольной папке изображения и использованию get eof получить его длину:

set desktopPicturesFolderPath to ¬

     (path to desktop pictures folder as text) & "Flow 1.jpg" as alias

--result: alias "Leopard:Library:Desktop Pictures:Flow 1.jpg"

get eof desktopPicturesFolderPath --result: 531486

Возвращает параметры громкости звукового вывода и ввода.

Синтаксис

Результат

Запись, содержащая параметры громкости звукового вывода и ввода. Все целочисленные настройки между 0 (тихи) и 100 (полный объем):

output volume ( integer)

Основной выходной объем.

input volume ( integer)

Входной объем.

alert volume ( integer)

Предупредительный объем. 100 для этой установки означает “столь же громкий как выходной объем”.

output muted (a boolean)

Вывод отключен звук? Если это правда, это переопределяет вывод и предупредительные объемы.

Примеры

set volSettings to get volume settings

--result: {output volume:43, input volume:35, alert volume:78, output muted:false}

Возвратите информацию для файла или папки.

Синтаксис

Результат

Рекордное, содержащее информацию об указанном файле или папке, со следующими полями. Некоторые поля только присутствуют для определенных видов элементов:

name (a text объект)

Полное имя элемента, как это появляется в файловой системе. Это всегда включает расширение, если таковые имеются. Например, "OmniOutliner Professional.app".

displayed name (a text объект)

Имя элемента, как это появляется в Средстве поиска. Это может отличаться, чем name если элемент имеет локализованное имя, если расширение скрыто или. Например, "OmniOutliner Professional".

short name (a text объект, только приложения)

Приложение CFBundleName, когда приложение активно, который является именем, выведенным на экран в строке меню. Это часто, но не всегда, то же как выведенное на экран имя. Например, "OmniOutliner Pro".

name extension (a text объект)

Дополнительная часть названия товара. Например, расширение имени файла “foo.txt” "txt".

bundle identifier (a text объект)

Идентификатор пакета пакета. Если пакет является приложением, это - приложение id.

type identifier (a text объект)

Тип элемента, как Uniform Type Identifier (UTI). Это - предпочтительная форма для идентификации типов изделия и может использоваться с choose file.

kind (a text объект)

Тип элемента, как выведено на экран в Средстве поиска. Это может быть локализовано и должно только использоваться в целях дисплея.

default application ( alias объект)

Приложение, которое откроет этот элемент.

creation date (a date объект)

Дата элемент создавалась.

modification date (a date объект)

Дата элемент была в последний раз изменена. Даты модификации папки не изменяются, когда элемент в них изменяется, хотя они действительно изменяются, когда элемент добавлен или удален.

file type (a text объект)

Тип элемента, как четыре кода символа. Это - классический эквивалент идентификатора типа, но менее точный и более твердый интерпретировать; использовать type identifier если это возможно.

file creator (a text объект)

Код создателя элемента с четырьмя символами. Для приложений это - классический эквивалент идентификатора пакета и будет работать на ссылку на приложение ID. Для файлов это может использоваться для выведения приложения по умолчанию, но не надежно; использовать default application если это возможно.

short version (a text объект)

Строка короткой версии элемента, как это появляется в окне «Get Info» Средства поиска. Любой элемент может иметь этот атрибут, но обычно только приложения делают.

long version (a text объект)

Долгая строка версии элемента, как это появляется в окне «Get Info» Средства поиска. Любой элемент может иметь этот атрибут, но обычно только приложения делают.

size ( integer)

Размер элемента, в байтах. Для получения дополнительной информации посмотрите size параметр.

alias (a boolean)

Действительно ли элемент является файлом псевдонима?

folder (a boolean)

Действительно ли элемент является папкой? Это - истина для пакетов, таких как пакеты приложений, а также нормальные папки.

package folder (a boolean)

Действительно ли элемент является папкой пакета, такой как приложение? Папка пакета появляется в Средстве поиска, как будто это - файл.

extension hidden (a boolean)

Имя действительно ли элемента является скрытым расширением?

visible (a boolean)

Действительно ли элемент видим? Как правило, только специальные системные файлы невидимы.

locked (a boolean)

Элемент заблокирован?

busy status (a boolean)

Действительно ли элемент используется в настоящее время?

Если true, элемент надежно занят. Если false, элемент может все еще быть занятым, потому что это состояние не может поддерживаться некоторыми приложениями или файловыми системами.

folder window (прямоугольник, только папки)

Ограничительный прямоугольник окна папки, как список четырех целых чисел: {вершина, оставленная, нижняя часть, право}.

Примеры

set downloadsFolder to path to downloads folder

    --result: alias "HD:Users:me:Downloads:"

info for downloadsFolder

    --result: {name:"Downloads", folder:true, alias:false, ...}

Запускает приложение, если оно уже не работает, но не отправляет ему a run команда.

Если приложение уже работает, отправляя ему a launch команда не имеет никакого эффекта. Это позволяет Вам открывать приложение, не выполняя его обычные процедуры запуска, такие как открытие нового окна или, в случае приложения сценария, выполняя его сценарий. Например, можно использовать launch команда, когда Вы не хотите, чтобы приложение открылось и закрылось явно. Это менее полезно в AppleScript 2.0, запускающем приложения, как скрытый по умолчанию (даже с run команда).

Посмотрите application ссылка класса для получения информации о том, как использовать application объект is running свойство, чтобы определить, работает ли это, не имея необходимость запускать его.

Синтаксис

Результат

Ни один.

Примеры

launch application "TextEdit"

tell application "TextEdit" to launch

Возвращает имена в настоящее время монтируемых объемов.

Синтаксис

Результат

A list из текстовых объектов, один для каждого в настоящее время монтируемого объема.

Возвращает имена элементов в указанной папке.

Синтаксис

Результат

A list из text объекты, один для каждого элемента в указанной папке.

Возвраты a script объект загрузился от указанного файла.

Синтаксис

Результат

script объект. Можно получить свойства этого объекта или вызвать его обработчики, как будто это была локальная переменная script объект.

Примеры

Для примеров посмотрите Сохранение и Загрузку Библиотек Обработчиков в приблизительно Обработчиках.

Возвращает локализованный текст для указанного ключа.

Синтаксис

Результат

A text объект, содержащий локализованный текст или исходный ключ, если нет никакого локализованного текста для того ключа.

Примеры

Для localized string чтобы быть полезными, необходимо создать данные локализованной строки для него для использования:

1. Сохраните свой сценарий как пакет сценария или комплект приложений.

2. Создать lproj папки в Resources каталог пакета для каждой локализации: например, English.lproj, French.lproj. Создайте названные файлы Localized.strings в каждом. Когда Вы сделаны, структура папок должна быть похожей на это:

   

3. Добавьте пары ключ/значение к каждому файлу Локэлизед.стрингса. Каждая пара является строкой текста "ключ" = "значение";, например:

   

Теперь localized string возвратит надлежащие значения, как определено в Ваших файлах. Например, при выполнении на французском языке:

localized string "hello"  --result: "bonjour"

В Редакторе сценариев, выводит на экран значение в конечном счете окно Log History или в конечном счете область Log окна сценария.

Синтаксис

Результат

Ни один.

Примеры

Следующее показывает простое использование журналирования:

set area to 7 * 43 as square feet

log area -- result (in Event Log pane): (*square feet 301.0*)

Операторы журнала могут быть полезны для отслеживания прогресса сценария. Для примера, показывающего, как зарегистрировать операторы в повторном цикле, посмотрите Журналирование.

Монтирует указанный сетевой том.

Синтаксис

Результат

Ни один.

Примеры

mount volume "afp://myserver.com/" -- guest access

mount volume "http://idisk.mac.com/myname/Public"

mount volume "http://idisk.mac.com/somebody" ¬

    as user name "myname" with password "mypassword"

Находит одну часть текста в другом.

Синтаксис

Результат

integer значение, указывающее позицию, в символах, исходного текста в цели, или 0, если не найденный.

Примеры

set myString to "Yours, mine, and ours"

offset of "yours" in myString  --result: 1, because case is ignored by default

offset of "mine" in myString  --result: 8

offset of "theirs" in myString  --result: 0, because "theirs" doesn't appear

considering case

    offset of "yours" in myString -- result: 0, because case is now considered

end considering

Открывает файл для чтения и записи.

Синтаксис

Результат

Дескриптор файла, как integer. Этот дескриптор файла может использоваться с любой из других команд файла: read, write, get eof, set eof, и close access.

Примеры

Следующий пример открывает файл по имени «NewFile» в указанном расположении path to desktop, но не просит доступ для записи:

set theFile to (path to desktop as text) & "NewFile"

set referenceNumber to open for access theFile

Для открытия файла с доступом для записи Вы заменили бы следующей строкой:

set referenceNumber to open for access theFile with write permission

Открывает URL с надлежащей программой.

Синтаксис

Результат

Ни один.

Примеры

Этот пример открывает веб-страницу Apple:

open location "http://www.apple.com"

Возвращает расположение указанного приложения.

Синтаксис

Результат

Расположение указанного приложения, как любой alias или a text объект, содержащий путь.

Примеры

path to application "TextEdit"

    --result: alias "Leopard:Applications:TextEdit.app:"

path to  --result: alias "Leopard:Applications:AppleScript:Script Editor.app:"

path to me  --result: same as above

path to it  --result: same as above

path to frontmost application  --result: same as above

path to current application

    --result: same, but could be different for a script application

Возвращает расположение указанной специальной папки.

Синтаксис

Результат

Расположение указанной папки, как любой alias или a text объект, содержащий путь.

Примеры

path to desktop --result: alias "Leopard:Users:johndoe:Desktop:"

path to desktop as string --result: "Leopard:Users:johndoe:Desktop:"

Возвращает расположение указанного ресурса.

Синтаксис

Результат

Расположение указанного ресурса, как alias.

Примеры

Следующий пример показывает, как можно получить путь к a .icns файл — в этом случае, в приложении Средства поиска.

tell application "Finder"

set gearIconPath to path to resource "Gear.icns"

end

--result: alias "HD:System:Library:CoreServices:Finder.app:Contents:Resources:Gear.icns"

Возвращает случайное число.

Синтаксис

Результат

Число между from и to пределы, включая предельные значения. В зависимости от предельных значений результатом может быть целое число или реальное. Если по крайней мере один предел указан, и все указанные пределы являются целыми числами, результатом является целое число. Иначе, результат является реальным, и может иметь дробную часть.

Примеры

random number  --result: 0.639215561057

random number from 1 to 10  --result: 8

Считывает данные из файла.

Синтаксис

Результат

Данные читают из файла. Если файл открыт, указатель файла совершенствуется числом чтения байтов, таким образом, следующее read команда запустится, где кончил предыдущий.

Примеры

Следующий пример открывает файл для доступа для чтения, чтений до (и включая) первое возникновение ".", закрывает файл и выводит на экран текст, который он считал. (См. раздел Examples для write команда для того, как создать подобный файл для чтения.)

set fp to open for access file "Leopard:Users:myUser:NewFile"

set myText to read fp until "."

close access fp

display dialog myText

Считать весь текст в файле, замене set myText to read fp until "." с set myText to read fp.

Округляет число к целому числу.

Синтаксис

Результат

Округленное значение, как integer если это в допустимом диапазоне ^(±229), или как a real если нет.

Примеры

Окружение или вниз не является тем же как округлением далеко от или к нулю, хотя это может появиться так для положительных чисел. Например:

round 1.1 rounding down --result: 1

round -1.1 rounding down --result: -2

К раунду к самому близкому кратному числу чего-то другого, чем 1, разделитесь на то число сначала, вокруг, и затем умножьтесь. Например, к раунду число к самым близким 0.01:

set x to 5.1234

set quantum to 0.01

(round x/quantum) * quantum --result: 5.12

round 1.5 --result: 2

round 0.5 --result: 0

Выполняется run обработчик указанной цели.

Для запуска приложения это должно быть на локальном или смонтированном объеме. Если приложение уже работает, эффект run команда зависит от приложения. Некоторые приложения не затронуты; другие повторяют свои процедуры запуска каждый раз, когда они получают a run команда.

run команда запускает приложение, как скрытый; использовать activate выявлять приложение.

Для a script объект, run команда вызывает или явное или неявное run обработчик, если таковые имеются, чтобы быть выполненным. Для соответствующей информации посмотрите выполненные Обработчики.

Синтаксис

Результат

Результат, если таковые имеются, возвращенный указанным объектом run обработчик.

Примеры

run application "TextEdit"

tell application "TextEdit" to run

run myScript --where myScript is a script object

Для получения информации об использовании run команда с script объекты, посмотрите Передающие Команды к Объектам сценария.

Выполняет указанный файл сценария или сценария.

См. также store script.

Синтаксис

Результат

Результат сценария run обработчик.

Примеры

Следующий сценарий предназначается для приложения Средство поиска, выходя из двойных кавычек вокруг имени приложения с символом наклонной черты влево (для получения дополнительной информации об использовании наклонной черты влево, посмотрите раздел Special String Characters в text описание класса):

run script "get name of front window of app \"Finder\"" --result: a window name

Этот пример выполняет сценарий, сохраненный на диске:

set scriptAlias to "Leopard:Users:myUser:Documents:savedScript.scptd:" as alias

run script scriptAlias --result: script is executed

Говорит указанный текст.

Синтаксис

Результат

Ни один.

Примеры

say "You are not listening to me!" using "Bubbles" -- result: spoken in Bubbles

Следующий пример сохранил разговорный текст в звуковой файл:

set soundFile to choose file name -- specify name ending in ".aiff"

    --result: a file URL

say "I love oatmeal." using "Victoria" saving to soundFile

    --result: saved to specified sound file

Возвращает список имен всех в настоящее время доступных компонентов сценариев, таких как компонент AppleScript.

Синтаксис

Результат

A list из text элементы, один для каждого установили сценарии компонента.

Примеры

scripting components --result: {"AppleScript"}

Присваивает одно или более значений одной или более переменным.

Синтаксис

Результат

Значение присвоилось.

Примеры

set может использоваться для создания новых переменных:

set myWeight to 125

... присвойте новые значения существующим переменным:

set myWeight to myWeight + 23

... свойства изменения или элементы объектов, такие как списки:

set intList to {1, 2, 3}

set item 3 of intList to 42

... или определенные с помощью приложения объекты:

tell application "Finder" to set name of startup disk to "Happy Fun Ball"

Как упомянуто в Обсуждении, устанавливая одну переменную в другого заставляет обе переменные относиться к тому же самому объекту. Если объект является непостоянным, т.е. он имеет перезаписываемые свойства или элементы, изменения в объекте появятся в обеих переменных:

set alpha to {1, 2, {"a", "b"}}

set beta to alpha

set item 2 of item 3 of alpha to "change" --change the original variable

set item 1 of beta to 42 --change a different item in the new variable

{alpha, beta}

--result: {{42, 2, {"a", "change"}}, {42, 2, {"a", "change"}}}

Обе переменные показывают те же изменения, потому что они оба обращаются к тому же объекту. Сравните это с подобным примером в copy. Присвоение нового объекта к переменной не является той же вещью как изменение самого объекта и не влияет ни на какие другие переменные, относящиеся к тому же объекту. Например:

set alpha to {1, 2, 3}

set beta to alpha --result: beta refers to the same object as alpha

set alpha to {4, 5, 6}

    --result: assigns a new object to alpha; this does not affect beta.

{alpha, beta}

--result: {{4, 5, 6}, {1, 2, 3}}

set может присвоить несколько переменных сразу с помощью образца, который может быть списком или записью. Например:

tell application "Finder" to set {x, y} to position of front window

С тех пор position of front window оценивает к списку двух целых чисел, это устанавливает x к первому элементу в списке и y к второму элементу.

Можно думать о присвоении образца как о сокращении для серии простых присвоений, но это не совсем точно, потому что присвоения эффективно одновременны. Это означает, что можно использовать присвоение образца для обмена двумя переменными:

set {x, y} to {1, 2} --now x is 1, and y is 2.

set {x, y} to {y, x} --now x is 2, and y is 1.

Для выполнения второго оператора с помощью только простые присвоения Вам была бы нужна временная третья переменная.

Для получения дополнительной информации об использовании команды набора, включая более сложный пример образца, посмотрите Объявление Переменных с Командой набора.

Устанавливает длину файла, в байтах.

Синтаксис

Результат

Ни один.

Если файл был открыт с помощью, сигнализирует “ошибку” разрешения записи open for access без разрешения записи.

Примеры

Если Вы хотите полностью заменить содержание существующего файла, первый шаг должен быть должен изменить свою длину для обнуления:

set theFile to choose file with prompt "Choose a file to clobber:"

set eof theFile to 0

Данные мест по буферу обмена.

Синтаксис

Результат

Ни один.

Примеры

Следующий текст мест сценария на буфере обмена, затем получает текст в TextEdit с a the clipboard команда:

set the clipboard to "Important new text."

tell application "TextEdit"

    activate  --make sure TextEdit is running

    set clipText to the clipboard  --result: "Important new text."

    --perform operations with retrieved text

end tell

Устанавливает звуковой вывод, ввод и предупредительные объемы.

Синтаксис

Результат

Ни один.

Примеры

Следующий пример сохраняет текущие параметры громкости, прежде, чем увеличить выходной объем, говоря некоторый текст, и восстанавливая исходное значение:

set savedSettings to get volume settings

-- {output volume:32, input volume:70, alert volume:78, output muted:false}

set volume output volume 90

say "This is pretty loud."

set volume output volume (output volume of savedSettings)

delay 1

say "That's better."

Хранилища a script объект в файл.

См. также run script.

Синтаксис

Результат

Ни один.

Примеры

Этот пример хранит сценарий на диске, с помощью Сохранения В качестве диалогового окна для указания расположения на рабочем столе и имени storedScript. Это тогда создает псевдоним к сохраненному сценарию и выполняет его с run script:

script test

    display dialog "Test"

end script

store script test --specify "Leopard:Users:myUser:Desktop:storedScript"

set localScript to alias "Leopard:Users:myUser:Desktop:storedScript" run script localScript --result: displays dialog "Test"

store script команда хранит только содержание сценария — в этом случае, один оператор, display dialog "Test". Это не хранит начало и конечные операторы определения сценария.

Суммирует указанный текст или текстовый файл.

Синтаксис

Результат

A text объект, содержащий итоговую версию текста или файла.

Примеры

Этот пример суммирует известную Геттисбергскую речь Линкольна вниз к одному предложению — жесткое задание даже для AppleScript:

set niceSpeech to "Four score and seven years ago our fathers brought forth on this continent a new nation, conceived in Liberty, and dedicated to the proposition that all men are created equal.

Now we are engaged in a great civil war, testing whether that nation, or any nation, so conceived and so dedicated, can long endure. We are met on a great battle-field of that war. We have come to dedicate a portion of that field, as a final resting place for those who here gave their lives that that nation might live. It is altogether fitting and proper that we should do this.

But, in a larger sense, we can not dedicate—we can not consecrate—we can not hallow—this ground. The brave men, living and dead, who struggled here, have consecrated it, far above our poor power to add or detract. The world will little note, nor long remember what we say here, but it can never forget what they did here. It is for us the living, rather, to be dedicated here to the unfinished work which they who fought here have thus far so nobly advanced. It is rather for us to be here dedicated to the great task remaining before us—that from these honored dead we take increased devotion to that cause for which they gave the last full measure of devotion—that we here highly resolve that these dead shall not have died in vain—that this nation, under God, shall have a new birth of freedom—and that government of the people, by the people, for the people, shall not perish from the earth."

set greatSummary to summarize niceSpeech in 1

display dialog greatSummary --result: displays one inspiring sentence

Получите переменные окружения или атрибуты этого компьютера.

Синтаксис

Результат

Если указанный атрибут является селектором Гештальта, или код ответа Гештальта или true или false в зависимости от has параметр.

Если указанный атрибут является переменной окружения, значением той переменной или пустой строкой ("") если это не определяется.

Если никакой атрибут не предоставляется, список всех определенных переменных окружения.

Примеры

Получить текущую оболочку:

system attribute "SHELL" --result: "/bin/bash" (for example)

Получить список всех определенных переменных окружения:

system attribute

(* result: (for example)

{"PATH", "TMPDIR", "SHELL", "HOME", "USER", "LOGNAME", "DISPLAY", "SSH_AUTH_SOCK", "Apple_PubSub_Socket_Render", "__CF_USER_TEXT_ENCODING", "SECURITYSESSIONID", "COMMAND_MODE"}

*)

Получает информацию о системе.

Синтаксис

Результат

Рекордное, содержащее различную информацию о системе и текущем пользователе. Эта запись содержит следующие поля:

AppleScript version (a text объект)

Номер версии AppleScript, например, "2.0". Это может быть полезно для тестирования на существование функций AppleScript. При сравнении номеров версий использовать considering numeric strings чтобы заставить их выдержать сравнение в числовом порядке, начиная с, стандартное лексикографическое упорядочивание рассмотрело бы "1.9" прибыть после "1.10".

AppleScript Studio version (a text объект)

Номер версии AppleScript Studio, например, "1.5".

Примечание: AppleScript Studio осуждается в OS X v10.6.

system version (a text объект)

Номер версии OS X, например, "10.5.1".

short user name (a text объект)

Краткое название текущего пользователя, например, "hoser". Это установлено в панели Advanced Options в предпочтительной области Учетных записей, или в поле «Short Name» при создании учетной записи. Это также доступно от использования Системных событий name of current user.

long user name (a text объект)

Длинное имя текущего пользователя, например, "Random J. Hoser". Это - поле «User Name» в предпочтительной области Учетных записей, или в поле «Name» при создании учетной записи. Это также доступно от использования Системных событий full name of current user.

user ID ( integer)

Идентификатор пользователя текущего пользователя. Это установлено в панели Advanced Options в предпочтительной области Учетных записей.

user locale (a text объект)

Код локали текущего пользователя, например "en_US".

home directory ( alias объект)

Расположение домашней папки текущего пользователя. Это также доступно от Средства поиска home свойство, или Системные события home folder свойство.

boot volume (a text объект)

Имя загрузочного тома, например, "Macintosh HD". Это также доступно от использования Системных событий или Средства поиска name of startup disk.

computer name (a text объект)

Имя компьютера, например "mymac". Это - поле «Computer Name» в Совместном использовании предпочтительной области.

host name (a text объект)

Имя DNS компьютера, например "mymac.local".

IPv4 address (a text объект)

Адрес IPv4 компьютера, например "192.201.168.13".

primary Ethernet address (a text объект)

MAC-адрес основного интерфейса Ethernet, например "00:1c:63:91:4e:db".

CPU type (a text объект)

Тип ЦП, например "Intel 80486".

CPU speed ( integer)

Тактовая частота CPU в MHz, например 2400.

physical memory ( integer)

Сумма физического RAM, установленного в компьютере, в мегабайтах (МБ), например 2048.

Примеры

system info --result: long record of information

Возвращает содержание буфера обмена.

Синтаксис

Результат

Данные от буфера обмена, который может иметь любой тип.

Примеры

Следующий текст мест сценария на буфере обмена, и затем добавляет содержание буфера обмена к документу frontmost TextEdit:

set the clipboard to "Add this sentence at the end."

tell application "TextEdit"

    activate  --make sure TextEdit is running

    make new paragraph at end of document 1 with data (return & the clipboard)

end tell

Возвращает различие между местным временем и GMT (Среднее время по Гринвичу) или Всемирное время, в секундах.

Синтаксис

Результат

integer число различия секунд между зоной текущего времени и Всемирное время.

Примеры

Следующий пример вычисляет разницу во времени между текущим расположением и Купертино:

set localOffset to time to GMT  --local difference, in seconds

set cupertinoOffset to -8.0 * hours

    --doesn't account for Daylight Savings; may actually be -7.0.

set difference to (localOffset - cupertinoOffset) / hours

display dialog ("Hours to Cupertino: " & difference)

Данные записей к указанному файлу.

Синтаксис

Результат

Ни один. Если файл открыт, write усовершенствует указатель файла числом записанных байтов, таким образом, следующее write команда начнет писать, где закончился последний.

Сигнализирует ошибку, если файл открыт без разрешения записи, или если существует какая-либо другая проблема, предотвращающая запись в файл, такой как отсутствие дискового пространства.

Примеры

Следующий пример открывает файл с разрешением записи, создавая его, если это уже не существует, текст записей к нему, и закрывает его.

set fp to open for access file "HD:Users:myUser:NewFile" with write permission

write "Some text. And some more text." to fp

close access fp