Справочник по Ada (Ada 2022)

A.4.8 Обработка Wide_Wide_String

Средства для обработки строк элементов Wide_Wide_Character содержатся в пакетах Strings.Wide_Wide_Maps, Strings.Wide_Wide_Fixed, Strings.Wide_Wide_Bounded, Strings.Wide_Wide_Unbounded и Strings.Wide_Wide_Maps.Wide_Wide_Constants, а также в библиотечных функциях Strings.Wide_Wide_Hash, Strings.Wide_Wide_Fixed.Wide_Wide_Hash, Strings.Wide_Wide_Bounded.Wide_Wide_Hash, Strings.Wide_Wide_Unbounded.Wide_Wide_Hash, Strings.Wide_Wide_Hash_Case_Insensitive, Strings.Wide_Wide_Fixed.Wide_Wide_Hash_Case_Insensitive, Strings.Wide_Wide_Bounded.Wide_Wide_Hash_Case_Insensitive, Strings.Wide_Wide_Unbounded.Wide_Wide_Hash_Case_Insensitive, Strings.Wide_Wide_Equal_Case_Insensitive, Strings.Wide_Wide_Fixed.Wide_Wide_Equal_Case_Insensitive, Strings.Wide_Wide_Bounded.Wide_Wide_Equal_Case_Insensitive и Strings.Wide_Wide_Unbounded.Wide_Wide_Equal_Case_Insensitive. Они предоставляют те же операции по обработке строк, что и соответствующие пакеты и функции для строк элементов Character.

Статическая семантика

Библиотечный пакет Strings.Wide_Wide_Maps имеет следующее объявление.

package Ada.Strings.Wide_Wide_Maps
with Preelaborate, Nonblocking, Global => in out synchronized is

-- Представление набора значений Wide_Wide_Character:
type Wide_Wide_Character_Set is private
with Preelaborable_Initialization;

Null_Set : constant Wide_Wide_Character_Set;

type Wide_Wide_Character_Range is
record
Low : Wide_Wide_Character;
High : Wide_Wide_Character;
end record;
-- Представляет диапазон Wide_Wide_Character Low..High

type Wide_Wide_Character_Ranges is array (Positive range <>)
of Wide_Wide_Character_Range;

function To_Set (Ranges : in Wide_Wide_Character_Ranges)
return Wide_Wide_Character_Set;

function To_Set (Span : in Wide_Wide_Character_Range)
return Wide_Wide_Character_Set;

function To_Ranges (Set : in Wide_Wide_Character_Set)
return Wide_Wide_Character_Ranges;

function "=" (Left, Right : in Wide_Wide_Character_Set) return Boolean;

function "not" (Right : in Wide_Wide_Character_Set)
return Wide_Wide_Character_Set;
function "and" (Left, Right : in Wide_Wide_Character_Set)
return Wide_Wide_Character_Set;
function "or" (Left, Right : in Wide_Wide_Character_Set)
return Wide_Wide_Character_Set;
function "xor" (Left, Right : in Wide_Wide_Character_Set)
return Wide_Wide_Character_Set;
function "-" (Left, Right : in Wide_Wide_Character_Set)
return Wide_Wide_Character_Set;

function Is_In (Element : in Wide_Wide_Character;
Set : in Wide_Wide_Character_Set)
return Boolean;

function Is_Subset (Elements : in Wide_Wide_Character_Set;
Set : in Wide_Wide_Character_Set)
return Boolean;

function "<=" (Left : in Wide_Wide_Character_Set;
Right : in Wide_Wide_Character_Set)
return Boolean renames Is_Subset;

-- Альтернативное представление набора значений Wide_Wide_Character:
subtype Wide_Wide_Character_Sequence is Wide_Wide_String;

function To_Set (Sequence : in Wide_Wide_Character_Sequence)
return Wide_Wide_Character_Set;

function To_Set (Singleton : in Wide_Wide_Character)
return Wide_Wide_Character_Set;

function To_Sequence (Set : in Wide_Wide_Character_Set)
return Wide_Wide_Character_Sequence;

-- Представление отображения Wide_Wide_Character в Wide_Wide_Character
-- :
type Wide_Wide_Character_Mapping is private
with Preelaborable_Initialization;

function Value (Map : in Wide_Wide_Character_Mapping;
Element : in Wide_Wide_Character)
return Wide_Wide_Character;

Identity : constant Wide_Wide_Character_Mapping;

function To_Mapping (From, To : in Wide_Wide_Character_Sequence)
return Wide_Wide_Character_Mapping;

function To_Domain (Map : in Wide_Wide_Character_Mapping)
return Wide_Wide_Character_Sequence;

function To_Range (Map : in Wide_Wide_Character_Mapping)
return Wide_Wide_Character_Sequence;

type Wide_Wide_Character_Mapping_Function is
access function (From : in Wide_Wide_Character)
return Wide_Wide_Character;

private
... -- не определено языком
end Ada.Strings.Wide_Wide_Maps;

Пункт контекста для каждого из пакетов Strings.Wide_Wide_Fixed, Strings.Wide_Wide_Bounded и Strings.Wide_Wide_Unbounded указывает на Strings.Wide_Wide_Maps вместо Strings.Maps.

Типы Wide_Wide_Character_Set и Wide_Wide_Character_Mapping требуют завершения.

Для каждого из пакетов Strings.Fixed, Strings.Bounded, Strings.Unbounded и Strings.Maps.Constants, и для библиотечных функций Strings.Hash, Strings.Fixed.Hash, Strings.Bounded.Hash, Strings.Unbounded.Hash, Strings.Hash_Case_Insensitive, Strings.Fixed.Hash_Case_Insensitive, Strings.Bounded.Hash_Case_Insensitive, Strings.Unbounded.Hash_Case_Insensitive, Strings.Equal_Case_Insensitive, Strings.Fixed.Equal_Case_Insensitive, Strings.Bounded.Equal_Case_Insensitive и Strings.Unbounded.Equal_Case_Insensitive, соответствующий пакет или функция для широких строк имеет то же содержимое, за исключением того, что

Wide_Wide_Space заменяет Space

Wide_Wide_Character заменяет Character

Wide_Wide_String заменяет String

Wide_Wide_Character_Set заменяет Character_Set

Wide_Wide_Character_Mapping заменяет Character_Mapping

Wide_Wide_Character_Mapping_Function заменяет Character_Mapping_Function

Wide_Wide_Maps заменяет Maps

Bounded_Wide_Wide_String заменяет Bounded_String

Null_Bounded_Wide_Wide_String заменяет Null_Bounded_String

To_Bounded_Wide_Wide_String заменяет To_Bounded_String

To_Wide_Wide_String заменяет To_String

Set_Bounded_Wide_Wide_String заменяет Set_Bounded_String

Unbounded_Wide_Wide_String заменяет Unbounded_String

Null_Unbounded_Wide_Wide_String заменяет Null_Unbounded_String

Wide_Wide_String_Access заменяет String_Access

To_Unbounded_Wide_Wide_String заменяет To_Unbounded_String

Set_Unbounded_Wide_Wide_String заменяет Set_Unbounded_String

Следующие дополнительные объявления присутствуют в Strings.Wide_Wide_Maps.Wide_Wide_Constants:

Character_Set : constant Wide_Wide_Maps.Wide_Wide_Character_Set;
-- Содержит каждое значение Wide_Wide_Character WWC, такое что
-- Characters.Conversions.Is_Character(WWC) равно True
Wide_Character_Set : constant Wide_Wide_Maps.Wide_Wide_Character_Set;
-- Содержит каждое значение Wide_Wide_Character WWC, такое что
-- Characters.Conversions.Is_Wide_Character(WWC) равно True

Каждая константа Wide_Wide_Character_Set в пакете Strings.Wide_Wide_Maps.Wide_Wide_Constants не содержит значений, выходящих за пределы части Character типа Wide_Wide_Character. Аналогично, каждая константа Wide_Wide_Character_Mapping в этом пакете является отображением тождества, когда она применяется к любому элементу за пределами части Character типа Wide_Wide_Character.

Аспект Pure заменен аспектами Preelaborate, Nonblocking, Global => in out synchronized в Strings.Wide_Wide_Maps.Wide_Wide_Constants.

ПРИМЕЧАНИЕ Если в любой из подпрограмм обработки Wide_Wide_String передается нулевая Wide_Wide_Character_Mapping_Function, возникает Constraint_Error.