FindPackageHandleStandardArgs

Этот модуль предоставляет функции, предназначенные для использования в Поиске модулей, реализующих вызовы find_package(<PackageName>).

find_package_handle_standard_args

Эта команда обрабатывает REQUIRED, QUIET и аргументы, связанные с версиями, вызова find_package(). Она также устанавливает переменную <PackageName>_FOUND. Пакет считается найденным, если все перечисленные переменные содержат допустимые результаты, например, допустимые пути к файлам.

Существует две сигнатуры:

find_package_handle_standard_args(<PackageName>
  (DEFAULT_MSG|<custom-failure-message>)
  <required-var>...
  )

find_package_handle_standard_args(<PackageName>
  [FOUND_VAR <result-var>]
  [REQUIRED_VARS <required-var>...]
  [VERSION_VAR <version-var>]
  [HANDLE_VERSION_RANGE]
  [HANDLE_COMPONENTS]
  [CONFIG_MODE]
  [NAME_MISMATCHED]
  [REASON_FAILURE_MESSAGE <reason-failure-message>]
  [FAIL_MESSAGE <custom-failure-message>]
  )

Переменная <PackageName>_FOUND будет установлена в значение TRUE, если все переменные <required-var>... являются допустимыми и любые дополнительные ограничения удовлетворены, и в значение FALSE в противном случае. В зависимости от результатов и от того, был ли задан параметр REQUIRED или QUIET для вызова find_package(), может быть выведено сообщение об успехе или неудаче.

Параметры:

(DEFAULT_MSG|<custom-failure-message>)

В простой сигнатуре это определяет сообщение об ошибке. Используйте DEFAULT_MSG для запроса вычисления стандартного сообщения (рекомендуется). Недопустимо в полной сигнатуре.

FOUND_VAR <result-var>

Устаревшее начиная с версии 3.3.

Определяет <PackageName>_FOUND или <PACKAGENAME>_FOUND в качестве переменной результата. Это существует только для совместимости со старыми версиями CMake и теперь игнорируется. Переменные результата с обеими именами всегда устанавливаются для совместимости.

REQUIRED_VARS <required-var>...

Укажите переменные, необходимые для данного пакета. Эти имена могут быть указаны в сгенерированном сообщении об ошибке, которое просит пользователя установить значения отсутствующих переменных. Поэтому они, как правило, должны быть записями кэша, такими как FOO_LIBRARY, а не переменными вывода, такими как FOO_LIBRARIES.

Изменено в версии 3.18: Если HANDLE_COMPONENTS указан, этот параметр можно опустить.

VERSION_VAR <version-var>

Укажите имя переменной, содержащей найденную версию пакета. Эта версия будет проверена на соответствие (возможно, указанной) требуемой версии, заданной вызовом find_package(), включая её параметр EXACT. Стандартные сообщения содержат информацию о требуемой версии и фактически найденной версии, как при согласовании, так и при несоответствии версий.

HANDLE_VERSION_RANGE

Добавлена в версии 3.19.

Включить обработку диапазона версий, если он задан. Без этого параметра будет выведено предупреждение разработчику, если указан диапазон версий.

HANDLE_COMPONENTS

Включить обработку компонентов пакета. В этом случае команда сообщит, какие компоненты найдены, а какие отсутствуют, и переменная <PackageName>_FOUND будет установлена в значение FALSE, если отсутствует любой из требуемых компонентов (то есть не те, которые перечислены после параметра OPTIONAL_COMPONENTS вызова find_package()).

CONFIG_MODE

Укажите, что вызывающий модуль поиска является оболочкой для вызова find_package(<PackageName> NO_MODULE). Это подразумевает значение VERSION_VAR как <PackageName>_VERSION. Команда автоматически проверит, был ли найден файл конфигурации пакета.

REASON_FAILURE_MESSAGE <reason-failure-message>

Добавлена в версии 3.16.

Укажите пользовательское сообщение о причине ошибки, которое будет добавлено к стандартному сгенерированному сообщению.

FAIL_MESSAGE <custom-failure-message>

Укажите пользовательское сообщение об ошибке вместо использования стандартного сгенерированного сообщения. Не рекомендуется.

NAME_MISMATCHED

Добавлена в версии 3.17.

Укажите, что <PackageName> не соответствует ${CMAKE_FIND_PACKAGE_NAME}. Обычно это ошибка, и она вызывает предупреждение, но может быть преднамеренным при использовании команды для компонентов более крупного пакета.

Пример для простой сигнатуры:

find_package_handle_standard_args(LibXml2 DEFAULT_MSG
  LIBXML2_LIBRARY LIBXML2_INCLUDE_DIR)

Пакет LibXml2 считается найденным, если LIBXML2_LIBRARY и LIBXML2_INCLUDE_DIR являются допустимыми. Тогда также LibXml2_FOUND устанавливается в TRUE. Если он не найден и был использован REQUIRED, происходит ошибка с message(FATAL_ERROR), независимо от использования QUIET. Если пакет найден, будет сообщено об успехе, включая содержимое первого <required-var>. При повторных запусках CMake это сообщение не будет выведено снова.

Пример для полной сигнатуры:

find_package_handle_standard_args(LibArchive
  REQUIRED_VARS LibArchive_LIBRARY LibArchive_INCLUDE_DIR
  VERSION_VAR LibArchive_VERSION)

В этом случае пакет LibArchive считается найденным, если LibArchive_LIBRARY и LibArchive_INCLUDE_DIR являются допустимыми. Также будет проверена версия LibArchive, используя версию, содержащуюся в LibArchive_VERSION. Поскольку не указан FAIL_MESSAGE, будут напечатаны стандартные сообщения.

Ещё один пример полной сигнатуры:

find_package(Automoc4 QUIET NO_MODULE HINTS /opt/automoc4)
find_package_handle_standard_args(Automoc4  CONFIG_MODE)

В этом случае модуль FindAutmoc4.cmake оборачивает вызов find_package(Automoc4 NO_MODULE) и добавляет дополнительный каталог поиска для automoc4. Затем вызов find_package_handle_standard_args генерирует надлежащее сообщение об успехе/неуспехе.

find_package_check_version

Добавлена в версии 3.19.

Вспомогательная функция, которую можно использовать для проверки того, является ли <version> допустимым по отношению к аргументам, связанным с версиями, в вызове find_package().

find_package_check_version(<version> <result-var>
  [HANDLE_VERSION_RANGE]
  [RESULT_MESSAGE_VARIABLE <message-var>]
  )

Переменная <result-var> будет содержать булево значение, обозначающее результат проверки.

Параметры:

HANDLE_VERSION_RANGE

Включить обработку диапазона версий, если он задан. Без этого параметра будет выведено предупреждение разработчику, если указан диапазон версий.

RESULT_MESSAGE_VARIABLE <message-var>

Указать переменную, чтобы получить сообщение, описывающее результат проверки.

Пример использования:

find_package_check_version(1.2.3 result HANDLE_VERSION_RANGE
  RESULT_MESSAGE_VARIABLE reason)
if (result)
  message (STATUS "${reason}")
else()
  message (FATAL_ERROR "${reason}")
endif()