cmake-qt(7)

• Введение
• Инструменты сборки Qt
  • AUTOMOC
  • AUTOUIC
  • AUTORCC
• Генераторы Visual Studio
• qtmain.lib в Windows

Введение

CMake может находить и использовать библиотеки Qt 4 и Qt 5. Библиотеки Qt 4 находятся с помощью модуля поиска FindQt4, поставляемого с CMake, в то время как библиотеки Qt 5 находятся с помощью «пакетов файла конфигурации», поставляемых с Qt 5. Смотрите cmake-packages(7) для получения дополнительной информации о пакетах CMake и руководство по CMake Qt для вашей версии Qt.

Qt 4 и Qt 5 можно использовать вместе в той же CMake buildsystem:

cmake_minimum_required(VERSION 3.8.0 FATAL_ERROR)

project(Qt4And5)

set(CMAKE_AUTOMOC ON)

find_package(Qt5 COMPONENTS Widgets DBus REQUIRED)
add_executable(publisher publisher.cpp)
target_link_libraries(publisher Qt5::Widgets Qt5::DBus)

find_package(Qt4 REQUIRED)
add_executable(subscriber subscriber.cpp)
target_link_libraries(subscriber Qt4::QtGui Qt4::QtDBus)

Целевая задача CMake не может ссылаться одновременно на Qt 4 и Qt 5. Если это будет сделано или произойдет из-за транзитивной зависимости целей, будет выведено диагностическое сообщение.

Инструменты сборки Qt

Qt полагается на некоторые инструменты, входящие в его состав, для генерации кода, такие как moc для генерации мета-объектного кода, uic для макета и заполнения виджетов, и rcc для генерации контента виртуальной файловой системы. Эти инструменты могут быть автоматически вызваны cmake(1), если выполнены соответствующие условия. Автоматическое вызов инструментов может быть использован как с Qt 4, так и с Qt 5.

Инструменты выполняются как часть сгенерированной CMake пользовательской целевой задачи. Зависимости от целей могут быть добавлены в эту пользовательскую целевую задачу, добавив их в свойство цели AUTOGEN_TARGET_DEPENDS.

AUTOMOC

Свойство цели AUTOMOC управляет тем, проверяет ли cmake(1) файлы C++ в целевой задаче на необходимость выполнения moc, и создает правила для выполнения moc в нужное время.

Если в заголовочном файле найден макрос из AUTOMOC_MACRO_NAMES, moc будет запущен на файле. Результат будет помещен в файл, имя которого соответствует moc_<basename>.cpp. Если макрос найден в файле реализации C++, вывод moc будет помещен в файл с именем, соответствующим <basename>.moc, следуя соглашениям Qt. Файл <basename>.moc должен быть включен пользователем в файл реализации C++ с препроцессорной #include.

Включенные moc_*.cpp и *.moc файлы будут сгенерированы в каталоге <AUTOGEN_BUILD_DIR>/include, который автоматически добавляется в INCLUDE_DIRECTORIES целевой задачи.

• Это отличается от CMake 3.7 и ниже; см. их документацию для подробностей.
• Для multi configuration generators, каталог включений – <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
• См. AUTOGEN_BUILD_DIR.

Не включенные moc_<basename>.cpp файлы будут сгенерированы в пользовательских папках, чтобы избежать конфликтов имен, и включены в отдельный файл <AUTOGEN_BUILD_DIR>/mocs_compilation.cpp, который компилируется в целевой задаче.

• См. AUTOGEN_BUILD_DIR.

Командная строка moc будет использовать COMPILE_DEFINITIONS и INCLUDE_DIRECTORIES свойства целевой задачи из целевой задачи, для которой она вызывается, и для соответствующей конфигурации сборки.

Свойство цели AUTOMOC может быть предварительно установлено для всех последующих целей путем установки переменной CMAKE_AUTOMOC. Свойство цели AUTOMOC_MOC_OPTIONS может быть заполнено для установки опций, которые нужно передать moc. Переменная CMAKE_AUTOMOC_MOC_OPTIONS может быть заполнена для предварительной установки опций для всех последующих целей.

Дополнительные имена макросов для поиска можно добавить в AUTOMOC_MACRO_NAMES.

Дополнительные имена зависимостей файлов moc могут быть извлечены из исходного кода с помощью AUTOMOC_DEPEND_FILTERS.

Исходные файлы C++ могут быть исключены из обработки AUTOMOC путем включения SKIP_AUTOMOC или более широкого SKIP_AUTOGEN.

AUTOUIC

Свойство цели AUTOUIC управляет тем, проверяет ли cmake(1) файлы C++ в целевой задаче на необходимость выполнения uic, и создает правила для выполнения uic в нужное время.

Если найдена препроцессорная #include директива, соответствующая <path>ui_<basename>.h, и существует файл <basename>.ui, тогда uic будет выполнен для генерации соответствующего файла. Файл <basename>.ui ищется в следующих местах

1. <source_dir>/<basename>.ui
2. <source_dir>/<path><basename>.ui
3. <AUTOUIC_SEARCH_PATHS>/<basename>.ui
4. <AUTOUIC_SEARCH_PATHS>/<path><basename>.ui

где <source_dir> - это каталог файла C++, а AUTOUIC_SEARCH_PATHS - список дополнительных путей поиска.

Сгенерированные файлы ui_*.h помещаются в каталог <AUTOGEN_BUILD_DIR>/include, который автоматически добавляется в INCLUDE_DIRECTORIES целевой задачи.

• Это отличается от CMake 3.7 и ниже; см. их документацию для подробностей.
• Для multi configuration generators, каталог включений – <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
• См. AUTOGEN_BUILD_DIR.

Цель AUTOUIC может быть предварительно установлена для всех последующих целей путём установки переменной CMAKE_AUTOUIC. Свойство цели AUTOUIC_OPTIONS может быть заполнено для установки параметров, которые следует передать uic. Переменная CMAKE_AUTOUIC_OPTIONS может быть заполнена для предварительной установки параметров для всех последующих целей. Свойство файла исходного кода AUTOUIC_OPTIONS может быть установлено для файла <basename>.ui, чтобы установить определённые параметры для файла. Это переопределяет параметры из свойства цели AUTOUIC_OPTIONS.

Цель может заполнить свойство цели INTERFACE_AUTOUIC_OPTIONS параметрами, которые следует использовать при вызове uic. Это должно быть согласованно с содержимым свойства цели AUTOUIC_OPTIONS цели-зависимости. Переменная CMAKE_DEBUG_TARGET_PROPERTIES может использоваться для отслеживания исходной цели такого INTERFACE_AUTOUIC_OPTIONS. Это означает, что библиотека, которая предоставляет альтернативную систему перевода для Qt, может указать параметры, которые следует использовать при запуске uic.

add_library(KI18n klocalizedstring.cpp)
target_link_libraries(KI18n Qt5::Core)

# KI18n uses the tr2i18n() function instead of tr().  That function is
# declared in the klocalizedstring.h header.
set(autouic_options
  -tr tr2i18n
  -include klocalizedstring.h
)

set_property(TARGET KI18n APPEND PROPERTY
  INTERFACE_AUTOUIC_OPTIONS ${autouic_options}
)

Проект, использующий целевой объект, экспортированный из upstream, автоматически использует соответствующие параметры, когда uic запускается с помощью AUTOUIC, в результате связи с целью IMPORTED:

set(CMAKE_AUTOUIC ON)
# Uses a libwidget.ui file:
add_library(LibWidget libwidget.cpp)
target_link_libraries(LibWidget
  KF5::KI18n
  Qt5::Widgets
)

Файлы исходного кода могут быть исключены из обработки AUTOUIC путём включения SKIP_AUTOUIC или более широкого SKIP_AUTOGEN.

AUTORCC

Свойство цели AUTORCC управляет тем, создаёт ли cmake(1) правила для выполнения rcc в нужное время для файлов исходного кода с расширением .qrc.

add_executable(myexe main.cpp resource_file.qrc)

Свойство цели AUTORCC может быть предварительно установлено для всех последующих целей путём установки переменной CMAKE_AUTORCC. Свойство цели AUTORCC_OPTIONS может быть заполнено для установки параметров, которые следует передать rcc. Переменная CMAKE_AUTORCC_OPTIONS может быть заполнена для предварительной установки параметров для всех последующих целей. Свойство файла исходного кода AUTORCC_OPTIONS может быть установлено для файла <name>.qrc для установки определённых параметров для файла. Это переопределяет параметры из свойства цели AUTORCC_OPTIONS.

Файлы исходного кода могут быть исключены из обработки AUTORCC путём включения SKIP_AUTORCC или более широкого SKIP_AUTOGEN.

Генераторы Visual Studio

При использовании Visual Studio generators CMake пытается использовать PRE_BUILD custom command вместо custom target для autogen. PRE_BUILD не может быть использован, когда целевой объект autogen зависит от файлов. Это происходит, когда

• AUTOMOC или AUTOUIC включены, и исходная цель зависит от файлов GENERATED, которые не исключены из autogen с помощью SKIP_AUTOMOC, SKIP_AUTOUIC, SKIP_AUTOGEN или CMP0071
• AUTORCC включен, и файл .qrc указан в источниках исходной цели
• AUTOGEN_TARGET_DEPENDS перечисляет файл исходного кода

qtmain.lib в Windows

Цели Qt 4 и 5 IMPORTED для библиотек QtGui указывают, что статическая библиотека qtmain.lib, поставляемая с Qt, будет подключена ко всем зависимым исполняемым файлам, у которых включено свойство WIN32_EXECUTABLE.

Чтобы отключить это поведение, включите свойство цели Qt5_NO_LINK_QTMAIN для целей, основанных на Qt 5, или свойство цели QT4_NO_LINK_QTMAIN для целей, основанных на Qt 4.

add_executable(myexe WIN32 main.cpp)
target_link_libraries(myexe Qt4::QtGui)

add_executable(myexe_no_qtmain WIN32 main_no_qtmain.cpp)
set_property(TARGET main_no_qtmain PROPERTY QT4_NO_LINK_QTMAIN ON)
target_link_libraries(main_no_qtmain Qt4::QtGui)