FindPackageHandleStandardArgs

Этот модуль предоставляет функцию, предназначенную для использования в Модулях поиска при реализации вызовов find_package(<PackageName>). Он обрабатывает REQUIRED, QUIET и аргументы, связанные с версиями, find_package. Он также устанавливает переменную <PackageName>_FOUND. Пакет считается найденным, если все перечисленные переменные содержат допустимые результаты, например, допустимые пути к файлам.

find_package_handle_standard_args

Существует две подписи:

find_package_handle_standard_args(<PackageName>
  (DEFAULT_MSG|<custom-failure-message>)
  <required-var>...
  )

find_package_handle_standard_args(<PackageName>
  [FOUND_VAR <result-var>]
  [REQUIRED_VARS <required-var>...]
  [VERSION_VAR <version-var>]
  [HANDLE_COMPONENTS]
  [CONFIG_MODE]
  [FAIL_MESSAGE <custom-failure-message>]
  )

Переменная <PackageName>_FOUND будет установлена в значение TRUE, если все переменные <required-var>... являются допустимыми и выполняются любые дополнительные ограничения, и в FALSE в противном случае. В зависимости от результатов и от того, был ли задан параметр REQUIRED или QUIET вызову find_package(), может быть выведено сообщение об успехе или об ошибке.

Параметры:

(DEFAULT_MSG|<custom-failure-message>)

В простой подписи это указывает сообщение об ошибке. Используйте DEFAULT_MSG для запроса вычисления стандартного сообщения (рекомендуется). Недействительно в полной подписи.

FOUND_VAR <result-var>

Устарело. Указывает <PackageName>_FOUND или <PACKAGENAME>_FOUND в качестве переменной результата. Это существует только для совместимости со старыми версиями CMake и теперь игнорируется. Переменные результатов с обоих именами всегда устанавливаются для совместимости.

REQUIRED_VARS <required-var>...

Укажите переменные, необходимые для этого пакета. Их имена могут быть указаны в сгенерированном сообщении об ошибке, в котором пользователя просят установить пропущенные значения переменных. Поэтому они обычно должны быть записями кэша, такими как FOO_LIBRARY, а не переменными вывода, такими как FOO_LIBRARIES.

VERSION_VAR <version-var>

Укажите имя переменной, которая хранит версию найденного пакета. Эта версия будет проверена по отношению к (возможно) заданной требуемой версии, предоставленной вызову find_package(), включая его параметр EXACT . Стандартные сообщения содержат информацию о требуемой версии и версии, которая фактически была найдена, как если версия подходит, так и если нет.

HANDLE_COMPONENTS

Включить обработку компонентов пакета. В этом случае команда сообщит, какие компоненты были найдены, а какие отсутствуют, и переменная <PackageName>_FOUND будет установлена в значение FALSE, если отсутствует любой из необходимых компонентов (т.е. не те, которые перечислены после параметра OPTIONAL_COMPONENTS вызова find_package()).

CONFIG_MODE

Укажите, что вызывающий модуль поиска является оболочкой для вызова find_package(<PackageName> NO_MODULE). Это подразумевает значение VERSION_VAR равное <PackageName>_VERSION. Команда автоматически проверит, был ли найден файл конфигурации пакета.

FAIL_MESSAGE <custom-failure-message>

Укажите пользовательское сообщение об ошибке вместо использования сгенерированного стандартного сообщения. Не рекомендуется.

Пример для простой подписи:

find_package_handle_standard_args(LibXml2 DEFAULT_MSG
  LIBXML2_LIBRARY LIBXML2_INCLUDE_DIR)

Пакет LibXml2 считается найденным, если оба LIBXML2_LIBRARY и LIBXML2_INCLUDE_DIR являются допустимыми. Тогда также LibXml2_FOUND устанавливается в значение TRUE. Если он не найден и был использован REQUIRED, он завершается с помощью message(FATAL_ERROR), независимо от того, использовался ли QUIET или нет. Если он найден, будет сообщено об успехе, включая содержимое первого <required-var>. При повторных запусках CMake данное сообщение не будет выведено повторно.

Пример для полной подписи:

find_package_handle_standard_args(LibArchive
  REQUIRED_VARS LibArchive_LIBRARY LibArchive_INCLUDE_DIR
  VERSION_VAR LibArchive_VERSION)

В этом случае пакет LibArchive считается найденным, если оба LibArchive_LIBRARY и LibArchive_INCLUDE_DIR являются допустимыми. Также будет проверена версия LibArchive, используя версию, содержащуюся в LibArchive_VERSION. Поскольку не указан FAIL_MESSAGE, будут напечатаны стандартные сообщения.

Еще один пример для полной подписи:

find_package(Automoc4 QUIET NO_MODULE HINTS /opt/automoc4)
find_package_handle_standard_args(Automoc4  CONFIG_MODE)

В этом случае модуль FindAutmoc4.cmake оборачивает вызов find_package(Automoc4 NO_MODULE) и добавляет дополнительный каталог поиска для automoc4. Затем вызов find_package_handle_standard_args генерирует надлежащее сообщение об успехе/ошибке.