FindPkgConfig

A pkg-config модуль для CMake.

Ищет исполняемый файл pkg-config и добавляет команды pkg_get_variable(), pkg_check_modules() и pkg_search_module(). Также будут установлены следующие переменные:

PKG_CONFIG_FOUND          ... if pkg-config executable was found
PKG_CONFIG_EXECUTABLE     ... pathname of the pkg-config program
PKG_CONFIG_VERSION_STRING ... the version of the pkg-config program found
                              (since CMake 2.8.8)

pkg_get_variable

Извлекает значение переменной pkg-config varName и сохраняет его в переменную результата resultVar в области вызова.

pkg_get_variable(<resultVar> <moduleName> <varName>)

Если pkg-config возвращает несколько значений для указанной переменной, resultVar будет содержать список.

Например:

pkg_get_variable(GI_GIRDIR gobject-introspection-1.0 girdir)

pkg_check_modules

Проверяет наличие всех указанных модулей, устанавливая различные переменные результата в области вызова.

pkg_check_modules(<prefix>
                  [REQUIRED] [QUIET]
                  [NO_CMAKE_PATH]
                  [NO_CMAKE_ENVIRONMENT_PATH]
                  [IMPORTED_TARGET]
                  <moduleSpec> [<moduleSpec>...])

При указании аргумента REQUIRED, команда завершится ошибкой, если модуль(и) не найден(ы).

При указании аргумента QUIET, сообщения об операции не будут выводиться.

По умолчанию, если CMAKE_MINIMUM_REQUIRED_VERSION имеет версию 3.1 или выше, или если PKG_CONFIG_USE_CMAKE_PREFIX_PATH установлено в логическое True значение, то пути CMAKE_PREFIX_PATH, CMAKE_FRAMEWORK_PATH и CMAKE_APPBUNDLE_PATH из кэша и переменных среды будут добавлены в pkg-config путь поиска. Аргументы NO_CMAKE_PATH и NO_CMAKE_ENVIRONMENT_PATH отключают это поведение для переменных кэша и переменных среды соответственно.

Аргумент IMPORTED_TARGET создаст импортированный целевой объект с именем PkgConfig::<prefix>, который можно использовать напрямую в качестве аргумента к target_link_libraries().

Каждый <moduleSpec> должен иметь один из следующих форматов:

{moduleName}            ... matches any version
{moduleName}>={version} ... at least version <version> is required
{moduleName}={version}  ... exactly version <version> is required
{moduleName}<={version} ... modules must not be newer than <version>

После выполнения могут быть установлены следующие переменные. Существуют два набора значений: один для общего случая (<XXX> = <prefix>) и другой для информации, которую предоставляет pkg-config, когда она вызывается с опцией --static (<XXX> = <prefix>_STATIC):

<XXX>_FOUND          ... set to 1 if module(s) exist
<XXX>_LIBRARIES      ... only the libraries (without the '-l')
<XXX>_LIBRARY_DIRS   ... the paths of the libraries (without the '-L')
<XXX>_LDFLAGS        ... all required linker flags
<XXX>_LDFLAGS_OTHER  ... all other linker flags
<XXX>_INCLUDE_DIRS   ... the '-I' preprocessor flags (without the '-I')
<XXX>_CFLAGS         ... all required cflags
<XXX>_CFLAGS_OTHER   ... the other compiler flags

Все, кроме <XXX>_FOUND, могут быть списками , если соответствующая переменная, возвращенная из pkg-config, имеет несколько значений.

Есть некоторые специальные переменные, префикс которых зависит от количества <moduleSpec> значений. Если указано только одно <moduleSpec>, <YYY> будет просто <prefix>, но если указано два или более <moduleSpec> значения, <YYY> будет <prefix>_<moduleName>.

<YYY>_VERSION    ... version of the module
<YYY>_PREFIX     ... prefix directory of the module
<YYY>_INCLUDEDIR ... include directory of the module
<YYY>_LIBDIR     ... lib directory of the module

Примеры

pkg_check_modules (GLIB2 glib-2.0)

Ищет любую версию glib2. Если найдена, переменная результата GLIB2_VERSION будет содержать фактическую найденную версию.

pkg_check_modules (GLIB2 glib-2.0>=2.10)

Ищет glib2 версии 2.10 или выше. Если найдена, переменная результата GLIB2_VERSION будет содержать фактическую найденную версию.

pkg_check_modules (FOO glib-2.0>=2.10 gtk+-2.0)

Ищет glib2-2.0 (версия 2.10 или выше) и любую версию gtk2+-2.0. Только если оба модуля будут найдены, FOO будет считаться найденным. Переменные FOO_glib-2.0_VERSION и FOO_gtk+-2.0_VERSION будут установлены на соответствующие версии найденных модулей.

pkg_check_modules (XRENDER REQUIRED xrender)

Требует любую версию xrender. Пример выходных переменных, установленных в случае успешного вызова:

XRENDER_LIBRARIES=Xrender;X11
XRENDER_STATIC_LIBRARIES=Xrender;X11;pthread;Xau;Xdmcp

pkg_search_module

Поведение этой команды такое же, как у pkg_check_modules(), за исключением того, что вместо проверки всех указанных модулей, она ищет только первый успешно совпавший.

pkg_search_module(<prefix>
                  [REQUIRED] [QUIET]
                  [NO_CMAKE_PATH]
                  [NO_CMAKE_ENVIRONMENT_PATH]
                  [IMPORTED_TARGET]
                  <moduleSpec> [<moduleSpec>...])

Примеры

pkg_search_module (BAR libxml-2.0 libxml2 libxml>=2)

Переменные, влияющие на поведение

PKG_CONFIG_EXECUTABLE

Можно установить путь к исполняемому файлу pkg-config. Если не указан, он будет установлен модулем в результате вызова find_program() в виде внутренней функции. Переменная среды PKG_CONFIG может использоваться в качестве подсказки.

PKG_CONFIG_USE_CMAKE_PREFIX_PATH

Указывает, следует ли pkg_check_modules() и pkg_search_module() добавлять пути из переменных кэша CMAKE_PREFIX_PATH, CMAKE_FRAMEWORK_PATH и CMAKE_APPBUNDLE_PATH и переменных среды в pkg-config путь поиска.

Если эта переменная не установлена, это поведение включено по умолчанию, если CMAKE_MINIMUM_REQUIRED_VERSION имеет версию 3.1 или выше, в противном случае отключено.