cmake-qt(7)

• Введение
• Инструменты сборки Qt
  • AUTOMOC
  • AUTOUIC
  • AUTORCC
• Генераторы Visual Studio
• qtmain.lib в Windows

Введение

CMake может находить и использовать библиотеки Qt 4 и Qt 5. Библиотеки Qt 4 находятся с помощью модуля поиска FindQt4, поставляемого с CMake, в то время как библиотеки Qt 5 находятся с помощью «Пакеты файлов конфигурации», поставляемых с Qt 5. См. cmake-packages(7) для получения дополнительной информации о пакетах CMake, и см. руководство Qt по CMake для вашей версии Qt.

Qt 4 и Qt 5 могут использоваться вместе в одной и той же CMake buildsystem:

cmake_minimum_required(VERSION 3.8.0 FATAL_ERROR)

project(Qt4And5)

set(CMAKE_AUTOMOC ON)

find_package(Qt5 COMPONENTS Widgets DBus REQUIRED)
add_executable(publisher publisher.cpp)
target_link_libraries(publisher Qt5::Widgets Qt5::DBus)

find_package(Qt4 REQUIRED)
add_executable(subscriber subscriber.cpp)
target_link_libraries(subscriber Qt4::QtGui Qt4::QtDBus)

Цель CMake не может быть связана одновременно с Qt 4 и Qt 5. Выдаётся сообщение об ошибке, если это пытаются сделать или если это результат вычисления зависимости целевого объекта.

Инструменты сборки Qt

Qt полагается на некоторые инструменты, включенные в комплект, для генерации кода, такие как moc для генерации метаобъектного кода, uic для макета и заполнения виджетов, и rcc для генерации содержимого виртуальной файловой системы. Эти инструменты могут быть автоматически вызваны cmake(1), если выполнены соответствующие условия. Автоматическое вызов инструментов может быть использован с Qt 4 и Qt 5.

Инструменты выполняются как часть сгенерированной CMake пользовательской цели. Зависимости целевых объектов могут быть добавлены к этой пользовательской цели, добавив их в свойство целевого объекта AUTOGEN_TARGET_DEPENDS.

AUTOMOC

Свойство целевого объекта AUTOMOC управляет тем, проверяет ли cmake(1) файлы C++ в целевом объекте, чтобы определить, требуется ли запуск moc, и создавать правила для выполнения moc в нужное время.

Если в заголовочном файле найден макрос из AUTOMOC_MACRO_NAMES, будет запущен moc. Результат будет помещен в файл, имя которого соответствует moc_<basename>.cpp. Если макрос найден в файле реализации C++, вывод moc будет помещён в файл с именем, соответствующим <basename>.moc, следуя соглашениям Qt. <basename>.moc должен быть включён пользователем в файл реализации C++ с помощью препроцессора #include.

Включённые moc_*.cpp и *.moc файлы будут сгенерированы в каталоге <AUTOGEN_BUILD_DIR>/include, который автоматически добавляется в INCLUDE_DIRECTORIES целевого объекта.

• Это отличается от CMake 3.7 и ниже; см. их документацию для получения подробностей.
• Для multi configuration generators, каталог включения — <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
• См. AUTOGEN_BUILD_DIR.

Не включённые moc_<basename>.cpp файлы будут сгенерированы в пользовательских папках, чтобы избежать коллизий имён, и включены в отдельный <AUTOGEN_BUILD_DIR>/mocs_compilation.cpp файл, который компилируется в целевой объект.

• См. AUTOGEN_BUILD_DIR.

Команда moc будет использовать свойства целевого объекта COMPILE_DEFINITIONS и INCLUDE_DIRECTORIES из целевого объекта, для которого она вызывается, и для соответствующей конфигурации сборки.

Свойство целевого объекта AUTOMOC может быть предварительно установлено для всех последующих целевых объектов путём установки переменной CMAKE_AUTOMOC. Свойство целевого объекта AUTOMOC_MOC_OPTIONS может быть заполнено для установки параметров, передаваемых moc. Переменная CMAKE_AUTOMOC_MOC_OPTIONS может быть заполнена для предварительной установки параметров для всех последующих целей.

Дополнительные имена макросов для поиска могут быть добавлены в AUTOMOC_MACRO_NAMES.

Дополнительные moc имена файлов зависимостей могут быть извлечены из исходного кода, используя AUTOMOC_DEPEND_FILTERS.

Файлы исходного кода C++ могут быть исключены из обработки AUTOMOC путём включения SKIP_AUTOMOC или более широкого SKIP_AUTOGEN.

AUTOUIC

Свойство целевого объекта AUTOUIC управляет тем, проверяет ли cmake(1) файлы C++ в целевом объекте, чтобы определить, требуется ли запуск uic, и создавать правила для выполнения uic в нужное время.

Если найден препроцессорная директива #include которая соответствует <path>ui_<basename>.h, и существует файл <basename>.ui, то будет выполнен uic для генерации соответствующего файла. Файл <basename>.ui ищется в следующих местах

1. <source_dir>/<basename>.ui
2. <source_dir>/<path><basename>.ui
3. <AUTOUIC_SEARCH_PATHS>/<basename>.ui
4. <AUTOUIC_SEARCH_PATHS>/<path><basename>.ui

где <source_dir> — это каталог файла C++, а AUTOUIC_SEARCH_PATHS — список дополнительных путей поиска.

Сгенерированные файлы ui_*.h помещаются в каталог <AUTOGEN_BUILD_DIR>/include, который автоматически добавляется в INCLUDE_DIRECTORIES целевого объекта.

• Это отличается от CMake 3.7 и ниже; см. их документацию для получения подробностей.
• Для multi configuration generators, каталог включения — <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
• См. AUTOGEN_BUILD_DIR.

Цель AUTOUIC свойство может быть предварительно задано для всех последующих целей, установив переменную CMAKE_AUTOUIC. Свойство цели AUTOUIC_OPTIONS может быть заполнено для установки параметров, которые нужно передать uic. Переменная CMAKE_AUTOUIC_OPTIONS может быть заполнена для предварительной установки параметров для всех последующих целей. Свойство файла исходного кода AUTOUIC_OPTIONS может быть установлено для файла <basename>.ui, чтобы установить конкретные параметры для файла. Это переопределяет параметры из свойства цели AUTOUIC_OPTIONS.

Цель может заполнить свойство цели INTERFACE_AUTOUIC_OPTIONS параметрами, которые должны использоваться при вызове uic. Это должно быть согласовано с содержимым свойства цели AUTOUIC_OPTIONS зависимой цели. Переменная CMAKE_DEBUG_TARGET_PROPERTIES может использоваться для отслеживания целевой цели таких INTERFACE_AUTOUIC_OPTIONS. Это означает, что библиотека, предоставляющая альтернативную систему перевода для Qt, может указать параметры, которые должны использоваться при запуске uic:

add_library(KI18n klocalizedstring.cpp)
target_link_libraries(KI18n Qt5::Core)

# KI18n uses the tr2i18n() function instead of tr().  That function is
# declared in the klocalizedstring.h header.
set(autouic_options
  -tr tr2i18n
  -include klocalizedstring.h
)

set_property(TARGET KI18n APPEND PROPERTY
  INTERFACE_AUTOUIC_OPTIONS ${autouic_options}
)

Потребляемый проект, ссылающийся на целевой объект, экспортированный из upstream, автоматически использует соответствующие параметры, когда uic запускается AUTOUIC в результате связи с целью IMPORTED:

set(CMAKE_AUTOUIC ON)
# Uses a libwidget.ui file:
add_library(LibWidget libwidget.cpp)
target_link_libraries(LibWidget
  KF5::KI18n
  Qt5::Widgets
)

Файлы исходного кода могут быть исключены из обработки AUTOUIC путём включения SKIP_AUTOUIC или более широкого SKIP_AUTOGEN.

AUTORCC

Свойство цели AUTORCC управляет тем, создаёт ли cmake(1) правила для выполнения rcc в соответствующее время для файлов исходного кода с расширением .qrc.

add_executable(myexe main.cpp resource_file.qrc)

Свойство цели AUTORCC может быть предварительно задано для всех последующих целей путём установки переменной CMAKE_AUTORCC. Свойство цели AUTORCC_OPTIONS может быть заполнено для установки параметров, которые нужно передать rcc. Переменная CMAKE_AUTORCC_OPTIONS может быть заполнена для предварительной установки параметров для всех последующих целей. Свойство файла исходного кода AUTORCC_OPTIONS может быть установлено для файла <name>.qrc для установки конкретных параметров для файла. Это переопределяет параметры из свойства цели AUTORCC_OPTIONS.

Файлы исходного кода могут быть исключены из обработки AUTORCC путём включения SKIP_AUTORCC или более широкого SKIP_AUTOGEN.

Генераторы Visual Studio

При использовании Visual Studio generators, CMake использует PRE_BUILD custom command для AUTOMOC и AUTOUIC. Если обработка AUTOMOC и AUTOUIC зависит от файлов, используется custom target. Это происходит, когда

• Зависимая цель зависит от файлов GENERATED, которые не исключены из AUTOMOC и AUTOUIC с помощью SKIP_AUTOMOC, SKIP_AUTOUIC, SKIP_AUTOGEN или CMP0071
• AUTOGEN_TARGET_DEPENDS перечисляет файл исходного кода

qtmain.lib в Windows

Цели Qt 4 и 5 IMPORTED для библиотек QtGui указывают, что статическая библиотека qtmain.lib, поставляемая с Qt, будет связана со всеми зависимыми исполняемыми файлами, которые имеют включённое свойство WIN32_EXECUTABLE.

Чтобы отключить это поведение, включите свойство цели Qt5_NO_LINK_QTMAIN для целей Qt 5 или свойство цели QT4_NO_LINK_QTMAIN для целей Qt 4.

add_executable(myexe WIN32 main.cpp)
target_link_libraries(myexe Qt4::QtGui)

add_executable(myexe_no_qtmain WIN32 main_no_qtmain.cpp)
set_property(TARGET main_no_qtmain PROPERTY QT4_NO_LINK_QTMAIN ON)
target_link_libraries(main_no_qtmain Qt4::QtGui)