FindPackageHandleStandardArgs

Этот модуль предоставляет функцию, предназначенную для использования в Поиске модулей, реализующей вызовы find_package(<PackageName>). Он обрабатывает REQUIRED, QUIET и аргументы, связанные с версией, find_package. Также он устанавливает переменную <PackageName>_FOUND. Пакет считается найденным, если все перечисленные переменные содержат корректные результаты, например, корректные пути к файлам.

find_package_handle_standard_args

Существует два варианта сигнатуры:

find_package_handle_standard_args(<PackageName>
  (DEFAULT_MSG|<custom-failure-message>)
  <required-var>...
  )

find_package_handle_standard_args(<PackageName>
  [FOUND_VAR <result-var>]
  [REQUIRED_VARS <required-var>...]
  [VERSION_VAR <version-var>]
  [HANDLE_COMPONENTS]
  [CONFIG_MODE]
  [FAIL_MESSAGE <custom-failure-message>]
  )

Переменная <PackageName>_FOUND будет установлена в значение TRUE, если все переменные <required-var>... являются корректными и выполнены все дополнительные ограничения, и в FALSE в противном случае. Сообщение об успехе или ошибке может быть выведено в зависимости от результатов и от того, был ли задан параметр REQUIRED и/или QUIET для вызова find_package().

Параметры:

(DEFAULT_MSG|<custom-failure-message>)

В простой сигнатуре это определяет сообщение об ошибке. Используйте DEFAULT_MSG для запроса вычисления стандартного сообщения (рекомендуется). Недействительно в полной сигнатуре.

FOUND_VAR <result-var>

Устаревший. Устанавливает переменную результата в <PackageName>_FOUND или <PACKAGENAME>_FOUND. Существует только для совместимости со старыми версиями CMake и сейчас игнорируется. Переменные результатов с обеими именами всегда устанавливаются для совместимости.

REQUIRED_VARS <required-var>...

Указывает переменные, необходимые для этого пакета. Их имена могут быть указаны в сгенерированном сообщении об ошибке, которое просит пользователя установить значения отсутствующих переменных. Поэтому их обычно следует использовать в качестве переменных кеша, например FOO_LIBRARY, а не в качестве выходных переменных, таких как FOO_LIBRARIES.

VERSION_VAR <version-var>

Указывает имя переменной, хранящей версию найденного пакета. Эта версия будет проверена по отношению к (возможно) заданной необходимой версии, переданной вызову find_package(), включая опцию EXACT. Стандартные сообщения включают информацию о требуемой версии и фактически найденной версии, как если версия корректна, так и нет.

HANDLE_COMPONENTS

Включает обработку компонентов пакета. В этом случае команда сообщит, какие компоненты были найдены и какие отсутствуют, и переменная <PackageName>_FOUND будет установлена в значение FALSE, если какие-либо из требуемых компонентов (т.е. не те, которые указаны после опции OPTIONAL_COMPONENTS вызова find_package()) отсутствуют.

CONFIG_MODE

Указывает, что вызывающий модуль поиска является оболочкой для вызова find_package(<PackageName> NO_MODULE). Это подразумевает значение VERSION_VAR как <PackageName>_VERSION. Команда автоматически проверит, был ли найден файл конфигурации пакета.

FAIL_MESSAGE <custom-failure-message>

Указывает пользовательское сообщение об ошибке вместо использования стандартного сгенерированного сообщения. Не рекомендуется.

Пример для простой сигнатуры:

find_package_handle_standard_args(LibXml2 DEFAULT_MSG
  LIBXML2_LIBRARY LIBXML2_INCLUDE_DIR)

Пакет LibXml2 считается найденным, если LIBXML2_LIBRARY и LIBXML2_INCLUDE_DIR являются корректными. Тогда также LibXml2_FOUND устанавливается в значение TRUE. Если он не найден и REQUIRED был использован, происходит ошибка с сообщением message(FATAL_ERROR), независимо от того, был ли использован QUIET или нет. Если он найден, то будет сообщено об успехе, включая содержимое первого <required-var>. При повторных запусках CMake это сообщение не будет выведено снова.

Пример для полной сигнатуры:

find_package_handle_standard_args(LibArchive
  REQUIRED_VARS LibArchive_LIBRARY LibArchive_INCLUDE_DIR
  VERSION_VAR LibArchive_VERSION)

В этом случае пакет LibArchive считается найденным, если LibArchive_LIBRARY и LibArchive_INCLUDE_DIR являются корректными. Также будет проверена версия LibArchive, используя версию, содержащуюся в LibArchive_VERSION. Так как опция FAIL_MESSAGE не задана, будут выведены стандартные сообщения.

Еще один пример для полной сигнатуры:

find_package(Automoc4 QUIET NO_MODULE HINTS /opt/automoc4)
find_package_handle_standard_args(Automoc4  CONFIG_MODE)

В этом случае модуль поиска FindAutmoc4.cmake оборачивает вызов find_package(Automoc4 NO_MODULE) и добавляет дополнительный каталог поиска для automoc4. Затем вызов find_package_handle_standard_args генерирует правильное сообщение об успехе/ошибке.