macro

Начало записи макроса для последующего вызова в качестве команды

macro(<name> [<arg1> ...])
  <commands>
endmacro()

Определяет макрос с именем <name>, принимающий аргументы с именами <arg1>, … Команды, перечисленные после макроса, но перед соответствующим endmacro(), не выполняются до вызова макроса.

В соответствии с наследием, команда endmacro() допускает необязательный <name> аргумент. Если используется, он должен быть точной копией аргумента открывающей команды macro.

См. документацию команды cmake_policy() для поведения политик внутри макросов.

См. раздел Макрос против функции ниже для различий между макросами CMake и functions.

Вызов

Вызов макроса не чувствителен к регистру. Макрос, определенный как

macro(foo)
  <commands>
endmacro()

может быть вызван с помощью любого из

foo()
Foo()
FOO()

и так далее. Однако настоятельно рекомендуется использовать регистр, выбранный при определении макроса. Обычно макросы используют имена с маленькими буквами.

Аргументы

При вызове макроса, команды, записанные в макросе, сначала изменяются путем замены формальных параметров (${arg1}, …) переданными аргументами, а затем вызываются как обычные команды.

В дополнение к ссылкам на формальные параметры вы можете ссылаться на значения ${ARGC}, которые будут установлены в количество переданных аргументов, а также ${ARGV0}, ${ARGV1}, ${ARGV2}, …, которые будут содержать фактические значения переданных аргументов. Это упрощает создание макросов с необязательными аргументами.

Кроме того, ${ARGV} содержит список всех переданных макросу аргументов, а ${ARGN} содержит список аргументов, следующих за последним ожидаемым аргументом. Ссылка на аргументы ${ARGV#} за пределами ${ARGC} имеет неопределенное поведение. Проверка того, что ${ARGC} больше, чем #, — единственный способ гарантировать, что ${ARGV#} был передан функции в качестве дополнительного аргумента.

Макрос против функции

Команда macro очень похожа на команду function(). Тем не менее, есть несколько важных отличий.

В функции ARGN, ARGC, ARGV и ARGV0, ARGV1, … являются истинными переменными в обычном смысле CMake. В макросе они таковыми не являются, они представляют собой подстановки строк, подобные тому, как это делает препроцессор C с макросом. Это имеет ряд последствий, как объясняется в разделе Примечания к аргументам ниже.

Другое различие между макросами и функциями заключается в управлении потоком. Функция выполняется путем передачи управления от вызывающей инструкции к телу функции. Макрос выполняется так, как будто тело макроса было вставлено вместо вызывающей инструкции. Это означает, что return() в теле макроса не просто завершает выполнение макроса, а возвращает управление из области вызова макроса. Чтобы избежать путаницы, рекомендуется вообще избегать использования return() в макросах.

Примечания к аргументам

Поскольку ARGN, ARGC, ARGV, ARGV0 и т. д. не являются переменными, вы НЕ сможете использовать такие команды, как

if(ARGV1) # ARGV1 is not a variable
if(DEFINED ARGV2) # ARGV2 is not a variable
if(ARGC GREATER 2) # ARGC is not a variable
foreach(loop_var IN LISTS ARGN) # ARGN is not a variable

В первом случае можно использовать if(${ARGV1}). Во втором и третьем случае правильный способ проверки, был ли необязательный аргумент передан макросу, заключается в использовании if(${ARGC} GREATER 2). В последнем случае можно использовать foreach(loop_var ${ARGN}), но это пропустит пустые аргументы. Если вам нужно их включить, можно использовать

set(list_var "${ARGN}")
foreach(loop_var IN LISTS list_var)

Обратите внимание, что если у вас есть переменная с тем же именем в области, из которой вызывается макрос, использование неиспользуемых имен приведет к использованию существующей переменной вместо аргументов. Например:

macro(bar)
  foreach(arg IN LISTS ARGN)
    <commands>
  endforeach()
endmacro()

function(foo)
  bar(x y z)
endfunction()

foo(a b c)

Будет циклиться по a;b;c, а не по x;y;z, как можно было бы ожидать. Если вам нужны истинные переменные CMake и/или лучшее управление областью видимости CMake, обратите внимание на команду function.