cmake_parse_arguments

Обработка аргументов функций или макросов.

cmake_parse_arguments(<prefix> <options> <one_value_keywords>
                      <multi_value_keywords> <args>...)

cmake_parse_arguments(PARSE_ARGV <N> <prefix> <options>
                      <one_value_keywords> <multi_value_keywords>)

Эта команда предназначена для использования в макросах или функциях. Она обрабатывает аргументы, переданные данному макросу или функции, и определяет набор переменных, которые хранят значения соответствующих опций.

Первый вариант обрабатывает аргументы, переданные в <args>.... Это может быть использовано как в macro(), так и в function().

Вариант PARSE_ARGV предназначен только для использования в теле function(). В этом случае аргументы, которые обрабатываются, берутся из переменных ARGV# вызывающей функции. Обработка начинается с <N>-го аргумента, где <N> — целое без знака. Это позволяет значениям содержать специальные символы, такие как ;.

Аргумент <options> содержит все опции для соответствующего макроса, т. е. ключевые слова, которые могут быть использованы при вызове макроса без последующего значения, например, ключевое слово OPTIONAL команды install().

Аргумент <one_value_keywords> содержит все ключевые слова для данного макроса, за которыми следует одно значение, например, ключевое слово DESTINATION команды install().

Аргумент <multi_value_keywords> содержит все ключевые слова для этого макроса, за которыми может следовать более одного значения, например, ключевые слова TARGETS или FILES команды install().

По окончании cmake_parse_arguments рассмотрит для каждого из ключевых слов, перечисленных в <options>, <one_value_keywords> и <multi_value_keywords>, переменную, составленную из указанного <prefix> и "_", а также имени соответствующего ключевого слова. Эти переменные будут содержать соответствующее значение из списка аргументов или будут неопределенными, если соответствующая опция не найдена. Для ключевых слов <options> они всегда будут определены, в TRUE или FALSE, независимо от того, присутствует ли опция в списке аргументов или нет.

Все оставшиеся аргументы собираются в переменной <prefix>_UNPARSED_ARGUMENTS, которая будет неопределенной, если все аргументы были распознаны. Это можно проверить позднее, чтобы увидеть, был ли ваш макрос вызван с нераспознанными параметрами.

Ключевые слова <one_value_keywords> и <multi_value_keywords>, которым не были заданы значения, собираются в переменную <prefix>_KEYWORDS_MISSING_VALUES, которая будет неопределенной, если все ключевые слова получили значения. Это можно проверить, чтобы увидеть, были ли какие-то ключевые слова без заданных значений.

Рассмотрим следующий пример макроса, my_install(), который принимает аргументы, аналогичные реальной команде install():

macro(my_install)
    set(options OPTIONAL FAST)
    set(oneValueArgs DESTINATION RENAME)
    set(multiValueArgs TARGETS CONFIGURATIONS)
    cmake_parse_arguments(MY_INSTALL "${options}" "${oneValueArgs}"
                          "${multiValueArgs}" ${ARGN} )

    # ...

Предположим, что my_install() был вызван так:

my_install(TARGETS foo bar DESTINATION bin OPTIONAL blub CONFIGURATIONS)

После вызова cmake_parse_arguments макрос установит или сделает неопределенными следующие переменные:

MY_INSTALL_OPTIONAL = TRUE
MY_INSTALL_FAST = FALSE # was not used in call to my_install
MY_INSTALL_DESTINATION = "bin"
MY_INSTALL_RENAME <UNDEFINED> # was not used
MY_INSTALL_TARGETS = "foo;bar"
MY_INSTALL_CONFIGURATIONS <UNDEFINED> # was not used
MY_INSTALL_UNPARSED_ARGUMENTS = "blub" # nothing expected after "OPTIONAL"
MY_INSTALL_KEYWORDS_MISSING_VALUES = "CONFIGURATIONS"
         # No value for "CONFIGURATIONS" given

Затем вы можете продолжить и обработать эти переменные.

Ключевые слова завершают списки значений, например, если сразу после one_value_keyword следует другое распознанное ключевое слово, это интерпретируется как начало новой опции. Например, my_install(TARGETS foo DESTINATION OPTIONAL) приведет к тому, что MY_INSTALL_DESTINATION будет установлено в "OPTIONAL", но так как OPTIONAL само является ключевым словом, MY_INSTALL_DESTINATION будет пустым (но добавленным в MY_INSTALL_KEYWORDS_MISSING_VALUES), а поэтому MY_INSTALL_OPTIONAL будет установлено в TRUE.