configure_file

Копирование файла в другое место с изменением его содержимого.

configure_file(<input> <output>
               [COPYONLY] [ESCAPE_QUOTES] [@ONLY]
               [NEWLINE_STYLE [UNIX|DOS|WIN32|LF|CRLF] ])

Копирует файл <input> в файл <output> и подставляет значения переменных, указанных как @VAR@ или ${VAR} в содержимом входного файла. Каждая ссылка на переменную будет заменена текущим значением переменной или пустой строкой, если переменная не определена. Кроме того, строки входного файла вида

#cmakedefine VAR ...

будут заменены либо

#define VAR ...

или

/* #undef VAR */

в зависимости от того, установлено ли значение VAR в CMake, отличное от значения, считаемого ложным константой командой if(). Содержимое «…», если оно есть в строке после имени переменной, обрабатывается аналогичным образом. Строки входного файла вида #cmakedefine01 VAR будут заменены либо #define VAR 1 или #define VAR 0 аналогичным образом. Результирующие строки (за исключением комментариев #undef) могут быть отступом с использованием пробелов и/или табуляции между символом # и словами cmakedefine или cmakedefine01. Этот отступ с пробелами сохранится в выходных строках:

#  cmakedefine VAR
#  cmakedefine01 VAR

будет заменено, если VAR определено, на

#  define VAR
#  define VAR 1

Если входной файл изменён, система сборки повторно запустит CMake, чтобы переконфигурировать файл и снова сгенерировать систему сборки. Сгенерированный файл изменяется и его метка времени обновляется при последующих запусках cmake только в том случае, если его содержимое изменено.

Аргументы:

<input>

Путь к входному файлу. Относительный путь учитывается относительно значения CMAKE_CURRENT_SOURCE_DIR. Путь к входному файлу должен указывать на файл, а не на директорию.

<output>

Путь к выходному файлу или директории. Относительный путь учитывается относительно значения CMAKE_CURRENT_BINARY_DIR. Если путь указывает на существующую директорию, выходной файл помещается в эту директорию с тем же именем, что и входной файл.

COPYONLY

Копировать файл без замены ссылок на переменные или другого содержимого. Этот параметр нельзя использовать с NEWLINE_STYLE.

ESCAPE_QUOTES

Экранировать любые подставленные кавычки обратными слешами (в стиле C).

@ONLY

Ограничить замену переменных ссылками вида @VAR@. Это полезно для конфигурирования скриптов, использующих синтаксис ${VAR}.

NEWLINE_STYLE <style>

Указать стиль новых строк для выходного файла. Укажите UNIX или LF для новых строк \n, или укажите DOS, WIN32, или CRLF для новых строк \r\n. Этот параметр нельзя использовать с COPYONLY.

Пример

Рассмотрим дерево исходных файлов, содержащее файл foo.h.in:

#cmakedefine FOO_ENABLE
#cmakedefine FOO_STRING "@FOO_STRING@"

Смежный файл CMakeLists.txt может использовать configure_file для конфигурирования заголовка:

option(FOO_ENABLE "Enable Foo" ON)
if(FOO_ENABLE)
  set(FOO_STRING "foo")
endif()
configure_file(foo.h.in foo.h @ONLY)

Это создаёт файл foo.h в каталоге сборки, соответствующем этому каталогу исходных файлов. Если опция FOO_ENABLE включена, сконфигурированный файл будет содержать:

#define FOO_ENABLE
#define FOO_STRING "foo"

В противном случае он будет содержать:

/* #undef FOO_ENABLE */
/* #undef FOO_STRING */

Затем можно использовать команду include_directories() для указания каталога вывода как каталога включения:

include_directories(${CMAKE_CURRENT_BINARY_DIR})

чтобы источники могли включать заголовок как #include <foo.h>.