макрос

Начать запись макроса для последующего вызова в качестве команды

macro(<name> [<arg1> ...])
  <commands>
endmacro()

Определяет макрос с именем <name>, который принимает аргументы с именами <arg1>, … Команды, перечисленные после макроса, но перед соответствующей командой endmacro(), не выполняются до тех пор, пока макрос не будет вызван.

В соответствии с наследием, команда endmacro() допускает необязательный <name> аргумент. При использовании он должен быть точным повторением аргумента открывающей команды macro.

См. документацию команды cmake_policy() для поведения политик внутри макросов.

См. раздел Макрос против функции ниже для различий между макросами CMake и командой functions.

Вызов

Вызов макроса нечувствителен к регистру. Макрос, определенный как

macro(foo)
  <commands>
endmacro()

можно вызвать любым из

foo()
Foo()
FOO()

и так далее. Однако настоятельно рекомендуется придерживаться регистра, выбранного при определении макроса. Обычно макросы используют имена со строчными буквами.

Аргументы

При вызове макроса команды, записанные в макросе, сначала изменяются путем замены формальных параметров (${arg1}, …) переданными аргументами, а затем вызываются как обычные команды.

В дополнение к ссылке на формальные параметры, вы можете ссылаться на значения ${ARGC}, которые будут установлены в количество переданных в функцию аргументов, а также ${ARGV0}, ${ARGV1}, ${ARGV2}, …, которые будут содержать фактические значения переданных аргументов. Это позволяет создавать макросы с необязательными аргументами.

Кроме того, ${ARGV} содержит список всех переданных макросу аргументов, а ${ARGN} содержит список аргументов, следующих за последним ожидаемым аргументом. Ссылка на аргументы ${ARGV#} за пределами ${ARGC} имеет неопределенное поведение. Проверка того, что ${ARGC} больше, чем #, является единственным способом гарантировать, что ${ARGV#} был передан функции как дополнительный аргумент.

Макрос против функции

Команда macro очень похожа на команду function(). Тем не менее, есть несколько важных различий.

В функции ARGN, ARGC, ARGV и ARGV0, ARGV1, … являются истинными переменными в обычном смысле CMake. В макросе они таковыми не являются, они являются строковыми заменами, подобно тому, как это делает препроцессор C с макросом. Это имеет ряд последствий, как объяснено в разделе Особенности аргументов ниже.

Другое различие между макросами и функциями заключается в потоке управления. Функция выполняется путем передачи управления от вызывающего оператора к телу функции. Макрос выполняется так, как будто тело макроса вставлено вместо вызывающего оператора. Это означает, что команда return() в теле макроса не просто завершает выполнение макроса; вместо этого управление возвращается из области вызова макроса. Чтобы избежать путаницы, рекомендуется вообще избегать return() в макросах.

В отличие от функции, переменные CMAKE_CURRENT_FUNCTION, CMAKE_CURRENT_FUNCTION_LIST_DIR, CMAKE_CURRENT_FUNCTION_LIST_FILE, CMAKE_CURRENT_FUNCTION_LIST_LINE для макроса не устанавливаются.

Особенности аргументов

Поскольку ARGN, ARGC, ARGV, ARGV0 и т.д. не являются переменными, вы НЕ сможете использовать команды, подобные

if(ARGV1) # ARGV1 is not a variable
if(DEFINED ARGV2) # ARGV2 is not a variable
if(ARGC GREATER 2) # ARGC is not a variable
foreach(loop_var IN LISTS ARGN) # ARGN is not a variable

В первом случае вы можете использовать if(${ARGV1}). Во втором и третьем случае правильный способ проверить, был ли передан макросу необязательный аргумент, — использовать if(${ARGC} GREATER 2). В последнем случае вы можете использовать foreach(loop_var ${ARGN}), но это пропустит пустые аргументы. Если вам нужно их включить, вы можете использовать

set(list_var "${ARGN}")
foreach(loop_var IN LISTS list_var)

Обратите внимание, что если у вас есть переменная с тем же именем в области, из которой вызывается макрос, использование неинициализированных имен будет использовать существующую переменную вместо аргументов. Например:

macro(bar)
  foreach(arg IN LISTS ARGN)
    <commands>
  endforeach()
endmacro()

function(foo)
  bar(x y z)
endfunction()

foo(a b c)

будет перебирать a;b;c, а не x;y;z, как можно было бы ожидать. Если вам нужны истинные переменные CMake и/или лучший контроль области CMake, вы должны обратиться к команде функции.