cmake-qt(7)

• Введение

• Инструменты сборки Qt

  • AUTOMOC
  • AUTOUIC
  • AUTORCC
• Цель <ORIGIN>_autogen
• Генераторы Visual Studio
• qtmain.lib в Windows

Введение

CMake может находить и использовать библиотеки Qt 4 и Qt 5. Библиотеки Qt 4 находятся с помощью модуля поиска FindQt4, поставляемого с CMake, а библиотеки Qt 5 находятся с помощью «пакетов файлов конфигурации», поставляемых с Qt 5. Подробнее о пакетах CMake см. cmake-packages(7), а руководство по CMake для Qt см. в руководстве Qt cmake для вашей версии Qt.

Qt 4 и Qt 5 можно использовать вместе в одной CMake buildsystem:

cmake_minimum_required(VERSION 3.8.0 FATAL_ERROR)

project(Qt4And5)

set(CMAKE_AUTOMOC ON)

find_package(Qt5 COMPONENTS Widgets DBus REQUIRED)
add_executable(publisher publisher.cpp)
target_link_libraries(publisher Qt5::Widgets Qt5::DBus)

find_package(Qt4 REQUIRED)
add_executable(subscriber subscriber.cpp)
target_link_libraries(subscriber Qt4::QtGui Qt4::QtDBus)

Цель CMake не может ссылаться одновременно на Qt 4 и Qt 5. При попытке этого или при выводе результата из оценки зависимости по цепочке целей выдается диагностическое сообщение.

Инструменты сборки Qt

Qt использует некоторые инструменты, входящие в комплект, для генерации кода, такие как moc для генерации метаобъектного кода, uic для макета виджетов и заполнения, и rcc для генерации содержимого виртуальной файловой системы. Эти инструменты могут быть автоматически вызваны cmake(1), если соблюдены соответствующие условия. Автоматическое вызов инструментов можно использовать как с Qt 4, так и с Qt 5.

AUTOMOC

Свойство цели AUTOMOC управляет тем, проверяет ли cmake(1) файлы C++ в целевой директории, чтобы определить, требуется ли запуск moc, и создаёт правила для выполнения moc в соответствующее время.

Если в заголовочном файле найден макрос из AUTOMOC_MACRO_NAMES, будет выполнено moc для файла. Результат будет помещён в файл, имя которого соответствует moc_<basename>.cpp. Если макрос найден в файле реализации C++, выходные данные moc будут помещены в файл, имя которого соответствует <basename>.moc, следуя соглашениям Qt. Пользователь должен включить <basename>.moc в файл реализации C++ с помощью препроцессора #include.

Включённые файлы moc_*.cpp и *.moc будут сгенерированы в каталоге <AUTOGEN_BUILD_DIR>/include, который автоматически добавляется в INCLUDE_DIRECTORIES цели.

• Это отличается от CMake 3.7 и ниже; см. документацию для подробностей.
• Для multi configuration generators, каталог включений — <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
• См. AUTOGEN_BUILD_DIR.

Не включённые файлы moc_<basename>.cpp будут сгенерированы в пользовательских папках, чтобы избежать коллизий имён, и включены в отдельный файл <AUTOGEN_BUILD_DIR>/mocs_compilation.cpp, который компилируется в целевой файл.

• См. AUTOGEN_BUILD_DIR.

Команда moc будет использовать свойства целей COMPILE_DEFINITIONS и INCLUDE_DIRECTORIES из целевой директории, а также соответствующую конфигурацию сборки.

Свойство цели AUTOMOC может быть предварительно установлено для всех последующих целей путём задания переменной CMAKE_AUTOMOC. Свойство цели AUTOMOC_MOC_OPTIONS можно заполнить, чтобы задать параметры, передаваемые moc. Переменная CMAKE_AUTOMOC_MOC_OPTIONS можно заполнить, чтобы предварительно задать параметры для всех последующих целей.

Дополнительные имена макросов для поиска можно добавить в AUTOMOC_MACRO_NAMES.

Дополнительные имена файлов зависимостей moc можно извлечь из исходного кода, используя AUTOMOC_DEPEND_FILTERS.

Файлы исходного кода C++ можно исключить из обработки AUTOMOC, включив SKIP_AUTOMOC или более широкое свойство SKIP_AUTOGEN.

AUTOUIC

Свойство цели AUTOUIC управляет тем, проверяет ли cmake(1) файлы C++ в целевой директории, чтобы определить, требуется ли запуск uic, и создаёт правила для выполнения uic в соответствующее время.

Если найден препроцессорная директива #include, соответствующая <path>ui_<basename>.h, и файл <basename>.ui существует, то uic будет выполнен для генерации соответствующего файла. Поиск файла <basename>.ui происходит в следующих местах:

1. <source_dir>/<basename>.ui
2. <source_dir>/<path><basename>.ui
3. <AUTOUIC_SEARCH_PATHS>/<basename>.ui
4. <AUTOUIC_SEARCH_PATHS>/<path><basename>.ui

где <source_dir> — каталог файла C++, а AUTOUIC_SEARCH_PATHS — список дополнительных путей поиска.

Сгенерированные файлы ui_*.h помещаются в каталог <AUTOGEN_BUILD_DIR>/include, который автоматически добавляется в INCLUDE_DIRECTORIES цели.

• Это отличается от CMake 3.7 и ниже; см. документацию для подробностей.
• Для multi configuration generators, каталог включений — <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
• См. AUTOGEN_BUILD_DIR.

Свойство цели AUTOUIC может быть предварительно установлено для всех последующих целей путём задания переменной CMAKE_AUTOUIC. Свойство цели AUTOUIC_OPTIONS можно заполнить, чтобы задать параметры, передаваемые uic. Переменная CMAKE_AUTOUIC_OPTIONS можно заполнить, чтобы предварительно задать параметры для всех последующих целей. Свойство файла исходного кода AUTOUIC_OPTIONS можно установить для файла <basename>.ui, чтобы задать определённые параметры для файла. Это переопределяет параметры из свойства цели AUTOUIC_OPTIONS.

Целевой объект может заполнить свойство цели INTERFACE_AUTOUIC_OPTIONS параметрами, которые должны использоваться при вызове uic. Это должно соответствовать содержимому свойства цели AUTOUIC_OPTIONS зависимой цели. Переменная CMAKE_DEBUG_TARGET_PROPERTIES может использоваться для отслеживания целевого объекта происхождения такого INTERFACE_AUTOUIC_OPTIONS. Это означает, что библиотека, предоставляющая альтернативную систему трансляции для Qt, может указать параметры, которые должны использоваться при выполнении uic:

add_library(KI18n klocalizedstring.cpp)
target_link_libraries(KI18n Qt5::Core)

# KI18n uses the tr2i18n() function instead of tr().  That function is
# declared in the klocalizedstring.h header.
set(autouic_options
  -tr tr2i18n
  -include klocalizedstring.h
)

set_property(TARGET KI18n APPEND PROPERTY
  INTERFACE_AUTOUIC_OPTIONS ${autouic_options}
)

Потребляющий проект, связанный с целевым объектом, экспортированным из источника, автоматически использует соответствующие параметры, когда uic выполняется с помощью AUTOUIC в результате связи с целевым объектом IMPORTED:

set(CMAKE_AUTOUIC ON)
# Uses a libwidget.ui file:
add_library(LibWidget libwidget.cpp)
target_link_libraries(LibWidget
  KF5::KI18n
  Qt5::Widgets
)

Файлы исходного кода могут быть исключены из обработки AUTOUIC путем включения SKIP_AUTOUIC или более широкого SKIP_AUTOGEN.

AUTORCC

Свойство целевого объекта AUTORCC управляет тем, создаёт ли cmake(1) правила для выполнения rcc в соответствующее время для файлов исходного кода с расширением .qrc.

add_executable(myexe main.cpp resource_file.qrc)

Свойство целевого объекта AUTORCC может быть предварительно установлено для всех последующих целевых объектов путем задания переменной CMAKE_AUTORCC. Свойство целевого объекта AUTORCC_OPTIONS может быть заполнено для установки параметров, которые необходимо передать rcc. Переменная CMAKE_AUTORCC_OPTIONS может быть заполнена для предварительной установки параметров для всех последующих целевых объектов. Свойство файла исходного кода AUTORCC_OPTIONS может быть установлено для файла <name>.qrc для установки определенных параметров для файла. Это переопределяет параметры из свойства целевого объекта AUTORCC_OPTIONS.

Файлы исходного кода могут быть исключены из обработки AUTORCC путем включения SKIP_AUTORCC или более широкого SKIP_AUTOGEN.

Целевой объект <ORIGIN>_autogen

Инструменты moc и uic выполняются как часть синтезированного целевого объекта <ORIGIN>_autogen custom target, сгенерированного CMake. По умолчанию целевой объект <ORIGIN>_autogen наследует зависимости целевого объекта <ORIGIN> (см. AUTOGEN_ORIGIN_DEPENDS). Зависимости целевых объектов могут быть добавлены к целевому объекту <ORIGIN>_autogen путем добавления их к свойству целевого объекта AUTOGEN_TARGET_DEPENDS.

Генераторы Visual Studio

При использовании Visual Studio generators, CMake генерирует PRE_BUILD custom command вместо <ORIGIN>_autogen custom target (для AUTOMOC и AUTOUIC). Однако это не всегда возможно, и используется <ORIGIN>_autogen custom target, если

• целевой объект <ORIGIN> зависит от файлов GENERATED, которые не исключены из AUTOMOC и AUTOUIC с помощью SKIP_AUTOMOC, SKIP_AUTOUIC, SKIP_AUTOGEN или CMP0071
• AUTOGEN_TARGET_DEPENDS перечисляет файл исходного кода
• CMAKE_GLOBAL_AUTOGEN_TARGET включен

qtmain.lib в Windows

Целевые объекты Qt 4 и 5 IMPORTED для библиотек QtGui указывают, что статическая библиотека qtmain.lib, поставляемая с Qt, будет подключена ко всем зависимым исполняемым файлам, у которых включено WIN32_EXECUTABLE.

Чтобы отключить это поведение, включите свойство целевого объекта Qt5_NO_LINK_QTMAIN для целевых объектов Qt 5 или свойство целевого объекта QT4_NO_LINK_QTMAIN для целевых объектов Qt 4.

add_executable(myexe WIN32 main.cpp)
target_link_libraries(myexe Qt4::QtGui)

add_executable(myexe_no_qtmain WIN32 main_no_qtmain.cpp)
set_property(TARGET main_no_qtmain PROPERTY QT4_NO_LINK_QTMAIN ON)
target_link_libraries(main_no_qtmain Qt4::QtGui)