list

Операции со списками.

Резюме

Reading
  list(LENGTH <list> <out-var>)
  list(GET <list> <element index> [<index> ...] <out-var>)
  list(JOIN <list> <glue> <out-var>)
  list(SUBLIST <list> <begin> <length> <out-var>)

Search
  list(FIND <list> <value> <out-var>)

Modification
  list(APPEND <list> [<element>...])
  list(FILTER <list> {INCLUDE | EXCLUDE} REGEX <regex>)
  list(INSERT <list> <index> [<element>...])
  list(POP_BACK <list> [<out-var>...])
  list(POP_FRONT <list> [<out-var>...])
  list(PREPEND <list> [<element>...])
  list(REMOVE_ITEM <list> <value>...)
  list(REMOVE_AT <list> <index>...)
  list(REMOVE_DUPLICATES <list>)
  list(TRANSFORM <list> <ACTION> [...])

Ordering
  list(REVERSE <list>)
  list(SORT <list> [...])

Введение

Подкоманды списка APPEND, INSERT, FILTER, PREPEND, POP_BACK, POP_FRONT, REMOVE_AT, REMOVE_ITEM, REMOVE_DUPLICATES, REVERSE и SORT могут создавать новые значения для списка в текущей области видимости переменной CMake. Подобно команде set(), команда LIST создаёт новые значения переменных в текущей области видимости, даже если сам список фактически определён в области видимости родительского уровня. Чтобы распространить результаты этих операций вверх, используйте set() с PARENT_SCOPE, set() с CACHE INTERNAL, или другие средства распространения значений.

Чтение

list(LENGTH <list> <output variable>)

Возвращает длину списка.

list(GET <list> <element index> [<element index> ...] <output variable>)

Возвращает список элементов, указанных индексами из списка.

list(JOIN <list> <glue> <output variable>)

Возвращает строку, объединяющую все элементы списка с использованием разделительной строки. Для объединения нескольких строк, которые не являются частью списка, используйте оператор JOIN из команды string().

list(SUBLIST <list> <begin> <length> <output variable>)

Возвращает подсписок заданного списка. Если <length> равно 0, будет возвращён пустой список. Если <length> равно -1 или список меньше <begin>+<length>, будут возвращены оставшиеся элементы списка, начиная с <begin>.

Поиск

list(FIND <list> <value> <output variable>)

Возвращает индекс элемента, указанного в списке, или -1, если он не был найден.

Модификация

list(APPEND <list> [<element> ...])

Добавляет элементы в список.

list(FILTER <list> <INCLUDE|EXCLUDE> REGEX <regular_expression>)

Включает или удаляет элементы из списка, соответствующие шаблону режима. В режиме REGEX, элементы будут сопоставлены с заданным регулярным выражением.

Для получения дополнительной информации о регулярных выражениях, также см. команду string().

list(INSERT <list> <element_index> <element> [<element> ...])

Вставляет элементы в список в указанное место.

list(POP_BACK <list> [<out-var>...])

Если имя переменной не указано, удаляет ровно один элемент. В противном случае, присваивает значение последнего элемента заданной переменной и удаляет его, до последнего указанного имени переменной.

list(POP_FRONT <list> [<out-var>...])

Если имя переменной не указано, удаляет ровно один элемент. В противном случае, присваивает значение первого элемента заданной переменной и удаляет его, до последнего указанного имени переменной.

list(PREPEND <list> [<element> ...])

Вставляет элементы в 0-ю позицию списка.

list(REMOVE_ITEM <list> <value> [<value> ...])

Удаляет все вхождения заданных элементов из списка.

list(REMOVE_AT <list> <index> [<index> ...])

Удаляет элементы по заданным индексам из списка.

list(REMOVE_DUPLICATES <list>)

Удаляет дублирующиеся элементы в списке. Относительный порядок элементов сохраняется, но если встречаются дубликаты, сохраняется только первое вхождение.

list(TRANSFORM <list> <ACTION> [<SELECTOR>]
                      [OUTPUT_VARIABLE <output variable>])

Преобразует список, применяя действие ко всем или, указав <SELECTOR>, к выбранным элементам списка, сохраняя результат на месте или в указанной выходной переменной.

<ACTION> задаёт действие, которое необходимо применить к элементам списка. Действия имеют точно такие же семантику, как подкоманды команды string(). <ACTION> должно быть одним из следующих:

APPEND, PREPEND: Добавить, вставить указанное значение в каждый элемент списка.

list(TRANSFORM <list> <APPEND|PREPEND> <value> ...)

TOUPPER, TOLOWER: Преобразовать каждый элемент списка в верхний, нижний регистр.

list(TRANSFORM <list> <TOLOWER|TOUPPER> ...)

STRIP: Удалить начальные и конечные пробелы из каждого элемента списка.

list(TRANSFORM <list> STRIP ...)

GENEX_STRIP: Удалить все generator expressions из каждого элемента списка.

list(TRANSFORM <list> GENEX_STRIP ...)

REPLACE: Сопоставить регулярное выражение как можно больше раз и заменить выражение замены для совпадения для каждого элемента списка (такая же семантика, как REGEX REPLACE из команды string()).

list(TRANSFORM <list> REPLACE <regular_expression>
                              <replace_expression> ...)

<SELECTOR> определяет, какие элементы списка будут преобразованы. Одновременно можно указать только один тип селектора. При указании <SELECTOR> должно быть одним из следующих:

AT: Указать список индексов.

list(TRANSFORM <list> <ACTION> AT <index> [<index> ...] ...)

FOR: Указать диапазон с необязательным приращением, используемым для перебора диапазона.

list(TRANSFORM <list> <ACTION> FOR <start> <stop> [<step>] ...)

REGEX: Указать регулярное выражение. Будут преобразованы только элементы, соответствующие регулярному выражению.

list(TRANSFORM <list> <ACTION> REGEX <regular_expression> ...)

Сортировка

list(REVERSE <list>)

Инвертирует содержимое списка на месте.

list(SORT <list> [COMPARE <compare>] [CASE <case>] [ORDER <order>])

Сортирует список по алфавиту на месте. Используйте ключевое слово COMPARE для выбора метода сравнения для сортировки. Параметр <compare> должен быть одним из:

• STRING: Сортирует список строк по алфавиту. Это поведение по умолчанию, если параметр COMPARE не задан.
• FILE_BASENAME: Сортирует список путей к файлам по их именам файлов.
• NATURAL: Сортирует список строк в естественном порядке (см. руководство strverscmp(3)), т. е. так, что соприкасающиеся цифры сравниваются как целые числа. Например: следующий список 10.0 1.1 2.1 8.0 2.0 3.1 будет отсортирован как 1.1 2.0 2.1 3.1 8.0 10.0, если выбран параметр сравнения NATURAL, в то время как он будет отсортирован как 1.1 10.0 2.0 2.1 3.1 8.0 с использованием сравнения STRING.

Используйте ключевое слово CASE для выбора чувствительной или нечувствительной к регистру сортировки. Параметр <case> должен быть одним из:

• SENSITIVE: Элементы списка сортируются с учётом регистра. Это поведение по умолчанию, если параметр CASE не задан.
• INSENSITIVE: Элементы списка сортируются без учёта регистра. Порядок элементов, которые отличаются только верхним/нижним регистром, не определён.

Для управления порядком сортировки можно указать ключевое слово ORDER. Параметр <order> должен быть одним из:

• ASCENDING: Сортирует список по возрастанию. Это поведение по умолчанию, если параметр ORDER не задан.
• DESCENDING: Сортирует список по убыванию.