макрос

Начать запись макроса для последующего вызова в качестве команды

macro(<name> [<arg1> ...])
  <commands>
endmacro()

Определяет макрос с именем <name>, который принимает аргументы с именами <arg1>, … Команды, перечисленные после макроса, но перед соответствующей командой endmacro(), не выполняются до тех пор, пока макрос не будет вызван.

По умолчанию команда endmacro() допускает необязательный <name> аргумент. Если он используется, он должен быть точной копией аргумента открывающей команды macro.

См. документацию команды cmake_policy() для поведения политик внутри макросов.

См. раздел Макрос против функции ниже для отличий между макросами CMake и командой functions.

Вызов

Вызов макроса нечувствителен к регистру. Макрос, определённый как

macro(foo)
  <commands>
endmacro()

можно вызвать любым из способов

foo()
Foo()
FOO()
cmake_language(CALL foo)

и так далее. Однако настоятельно рекомендуется придерживаться регистра, выбранного при определении макроса. Обычно макросы используют имена с маленькими буквами.

Команда cmake_language(CALL ...) также может использоваться для вызова макроса.

Аргументы

При вызове макроса команды, записанные в макросе, сначала изменяются путём замены формальных параметров (${arg1}, …) на переданные аргументы, а затем выполняются как обычные команды.

В дополнение к ссылке на формальные параметры можно ссылаться на значения ${ARGC}, которые будут установлены в количестве переданных аргументов, а также ${ARGV0}, ${ARGV1}, ${ARGV2}, …, которые будут содержать фактические значения переданных аргументов. Это упрощает создание макросов с необязательными аргументами.

Кроме того, ${ARGV} содержит список всех переданных аргументов макросу, а ${ARGN} содержит список аргументов, следующих за последним ожидаемым аргументом. Ссылка на ${ARGV#} аргументы, выходящие за пределы ${ARGC}, имеют неопределённое поведение. Проверка того, что ${ARGC} больше #, является единственным способом гарантировать, что ${ARGV#} был передан функции в качестве дополнительного аргумента.

Макрос против функции

Команда macro очень похожа на команду function(). Тем не менее, есть несколько важных отличий.

В функции ARGN, ARGC, ARGV и ARGV0, ARGV1, … являются истинными переменными в обычном смысле CMake. В макросе это не так; они являются строковыми заменами, аналогичными тому, как C препроцессор обрабатывает макросы. Это имеет ряд последствий, как объясняется в разделе Ограничения аргументов ниже.

Другое различие между макросами и функциями заключается в потоке управления. Функция выполняется путём передачи управления от вызывающего оператора к телу функции. Макрос выполняется так, как будто тело макроса вставлено вместо оператора вызова. Это означает, что оператор return() в теле макроса не просто прерывает выполнение макроса; вместо этого управление возвращается из области вызова макроса. Для избежания путаницы рекомендуется избегать return() в макросах вообще.

В отличие от функции, переменные CMAKE_CURRENT_FUNCTION, CMAKE_CURRENT_FUNCTION_LIST_DIR, CMAKE_CURRENT_FUNCTION_LIST_FILE, CMAKE_CURRENT_FUNCTION_LIST_LINE не устанавливаются для макроса.

Ограничения аргументов

Поскольку ARGN, ARGC, ARGV, ARGV0 и т.д. не являются переменными, вы не сможете использовать команды, такие как

if(ARGV1) # ARGV1 is not a variable
if(DEFINED ARGV2) # ARGV2 is not a variable
if(ARGC GREATER 2) # ARGC is not a variable
foreach(loop_var IN LISTS ARGN) # ARGN is not a variable

В первом случае можно использовать if(${ARGV1}). Во втором и третьем случае правильный способ проверки того, что необязательная переменная была передана макросу, — использовать if(${ARGC} GREATER 2). В последнем случае можно использовать foreach(loop_var ${ARGN}), но это пропустит пустые аргументы. Если вам нужно включить их, можно использовать

set(list_var "${ARGN}")
foreach(loop_var IN LISTS list_var)

Обратите внимание, что если в области, из которой вызывается макрос, есть переменная с тем же именем, использование неинициализированных имён будет использовать существующую переменную вместо аргументов. Например:

macro(bar)
  foreach(arg IN LISTS ARGN)
    <commands>
  endforeach()
endmacro()

function(foo)
  bar(x y z)
endfunction()

foo(a b c)

будет перебирать a;b;c, а не x;y;z, как можно было ожидать. Если вам нужны настоящие переменные CMake и/или лучшего управления областью CMake, обратите внимание на команду функции.