cmake_parse_arguments

Разбор аргументов функций или макросов.

cmake_parse_arguments(<prefix> <options> <one_value_keywords>
                      <multi_value_keywords> <args>...)

cmake_parse_arguments(PARSE_ARGV <N> <prefix> <options>
                      <one_value_keywords> <multi_value_keywords>)

Эта команда предназначена для использования в макросах или функциях. Она обрабатывает аргументы, переданные этому макросу или функции, и определяет набор переменных, которые хранят значения соответствующих опций.

Первый вариант обрабатывает аргументы, переданные в <args>.... Это может быть использовано как в macro(), так и в function().

Вариант PARSE_ARGV предназначен только для использования в теле function(). В этом случае аргументы, которые анализируются, берутся из переменных ARGV# вызывающей функции. Парсинг начинается с <N>-го аргумента, где <N> — целое беззнаковое число. Это позволяет значениям содержать специальные символы, например, ;.

Аргумент <options> содержит все опции для соответствующего макроса, т.е. ключевые слова, которые могут быть использованы при вызове макроса без последующего значения, например, ключевое слово OPTIONAL команды install().

Аргумент <one_value_keywords> содержит все ключевые слова для этого макроса, которые следуют за одним значением, например, ключевое слово DESTINATION команды install().

Аргумент <multi_value_keywords> содержит все ключевые слова для этого макроса, за которыми могут следовать более одного значения, например, ключевые слова TARGETS или FILES команды install().

По завершении cmake_parse_arguments рассмотрит для каждого из ключевых слов, перечисленных в <options>, <one_value_keywords> и <multi_value_keywords>, переменную, состоящую из данного <prefix> и имени соответствующего ключевого слова. Эти переменные будут содержать соответствующее значение из списка аргументов или не будут определены, если соответствующая опция не найдена. Для ключевых слов <options> они всегда будут определены, либо TRUE, либо FALSE, независимо от того, находится ли опция в списке аргументов или нет.

Все оставшиеся аргументы собираются в переменной <prefix>_UNPARSED_ARGUMENTS, которая не будет определена, если все аргументы были распознаны. Это можно проверить позже, чтобы узнать, был ли ваш макрос вызван с нераспознанными параметрами.

<one_value_keywords> и <multi_value_keywords> без значений собираются в переменную <prefix>_KEYWORDS_MISSING_VALUES, которая не будет определена, если все ключевые слова получили значения. Это можно проверить, чтобы увидеть, были ли какие-либо ключевые слова без значений.

Рассмотрим следующий пример макроса, my_install(), который принимает аргументы, аналогичные реальной команде install():

macro(my_install)
    set(options OPTIONAL FAST)
    set(oneValueArgs DESTINATION RENAME)
    set(multiValueArgs TARGETS CONFIGURATIONS)
    cmake_parse_arguments(MY_INSTALL "${options}" "${oneValueArgs}"
                          "${multiValueArgs}" ${ARGN} )

    # ...

Предположим, что my_install() был вызван так:

my_install(TARGETS foo bar DESTINATION bin OPTIONAL blub CONFIGURATIONS)

После вызова cmake_parse_arguments макрос будет устанавливать или оставлять неопределёнными следующие переменные:

MY_INSTALL_OPTIONAL = TRUE
MY_INSTALL_FAST = FALSE # was not used in call to my_install
MY_INSTALL_DESTINATION = "bin"
MY_INSTALL_RENAME <UNDEFINED> # was not used
MY_INSTALL_TARGETS = "foo;bar"
MY_INSTALL_CONFIGURATIONS <UNDEFINED> # was not used
MY_INSTALL_UNPARSED_ARGUMENTS = "blub" # nothing expected after "OPTIONAL"
MY_INSTALL_KEYWORDS_MISSING_VALUES = "CONFIGURATIONS"
         # No value for "CONFIGURATIONS" given

Вы можете продолжить и обработать эти переменные.

Ключевые слова завершают списки значений, например, если непосредственно после one_value_keyword следует другое распознанное ключевое слово, это интерпретируется как начало новой опции. Например, my_install(TARGETS foo DESTINATION OPTIONAL) приведет к тому, что MY_INSTALL_DESTINATION будет установлено в "OPTIONAL", но поскольку OPTIONAL само является ключевым словом, MY_INSTALL_DESTINATION будет пустым (но будет добавлено в MY_INSTALL_KEYWORDS_MISSING_VALUES) и, следовательно, MY_INSTALL_OPTIONAL будет установлено в TRUE.