cmake-toolchains(7)

Введение
Языки
Переменные и свойства
Функции цепочки инструментов
Кросс-компиляция

Введение

CMake использует цепочку инструментов для компиляции, компоновки библиотек, создания архивов и других задач для управления сборкой. Доступные инструменты цепочки инструментов определяются активированными языками. В обычных сборках CMake автоматически определяет цепочку инструментов для хост-сборок на основе системного анализа и значений по умолчанию. В сценариях кросс-компиляции может быть указан файл цепочки инструментов с информацией о путях компилятора и утилит.

Языки

Языки активируются командой project(). Языковые встроенные переменные, такие как CMAKE_CXX_COMPILER, CMAKE_CXX_COMPILER_ID и т. д., устанавливаются с помощью команды project(). Если в файле CMakeLists верхнего уровня нет команды project, она будет сгенерирована неявно. По умолчанию активированными языками являются C и CXX:

project(C_Only C)

Также с командой project() можно использовать специальное значение NONE для отключения всех языков:

project(MyProject NONE)

Команда enable_language() может быть использована для активации языков после команды project():

enable_language(CXX)

Когда язык активирован, CMake находит компилятор для этого языка и определяет такую информацию, как поставщик и версия компилятора, целевая архитектура и разрядность, расположение соответствующих утилит и т. д.

Глобальное свойство ENABLED_LANGUAGES содержит языки, которые в настоящее время активированы.

Переменные и свойства

Несколько переменных относятся к языковым компонентам цепочки инструментов, которые активированы. CMAKE_<LANG>_COMPILER — это полный путь к компилятору, используемому для <LANG>. CMAKE_<LANG>_COMPILER_ID — это идентификатор, используемый CMake для компилятора, а CMAKE_<LANG>_COMPILER_VERSION — это версия компилятора.

Переменные CMAKE_<LANG>_FLAGS и их аналоги, специфичные для конфигурации, содержат флаги, которые будут добавлены к команде компиляции при компиляции файла определенного языка.

Поскольку компоновщик вызывается драйвером компилятора, CMake нуждается в способе определения компилятора, который нужно использовать для вызова компоновщика. Это вычисляется по типу LANGUAGE исходных файлов в целевом объекте и, в случае статических библиотек, по языку зависимых библиотек. Выбор, сделанный CMake, может быть переопределен свойством целевого объекта LINKER_LANGUAGE.

Функции цепочки инструментов

CMake предоставляет команду try_compile() и макросы-обертки, такие как CheckCXXSourceCompiles, CheckCXXSymbolExists и CheckIncludeFile, для проверки возможностей и доступности различных функций цепочки инструментов. Эти API проверяют цепочку инструментов каким-либо образом и кэшируют результат, чтобы проверка не выполнялась повторно при следующем запуске CMake.

Некоторые функции цепочки инструментов имеют встроенную обработку в CMake и не требуют проверки компиляцией. Например, POSITION_INDEPENDENT_CODE позволяет указать, что целевой объект должен быть скомпилирован как позиционно-независимый код, если компилятор поддерживает эту функцию. Свойства целевого объекта <LANG>_VISIBILITY_PRESET и VISIBILITY_INLINES_HIDDEN добавляют флаги для скрытой видимости, если это поддерживается компилятором.

Кросс-компиляция

Если cmake(1) вызывается с параметром командной строки -DCMAKE_TOOLCHAIN_FILE=path/to/file, файл будет загружен предварительно для установки значений компиляторов. Переменная CMAKE_CROSSCOMPILING устанавливается в значение true, когда CMake выполняет кросс-компиляцию.

Обратите внимание, что использование переменных CMAKE_SOURCE_DIR или CMAKE_BINARY_DIR внутри файла цепочки инструментов обычно нежелательно. Файл цепочки инструментов используется в контекстах, где эти переменные имеют разные значения при использовании в различных местах (например, в качестве части вызова try_compile()). В большинстве случаев, когда необходимо оценить пути внутри файла цепочки инструментов, более подходящей переменной для использования является CMAKE_CURRENT_LIST_DIR, так как она всегда имеет однозначное, предсказуемое значение.

Кросс-компиляция для Linux

Типичная цепочка инструментов для кросс-компиляции для Linux содержит такие данные:

set(CMAKE_SYSTEM_NAME Linux)
set(CMAKE_SYSTEM_PROCESSOR arm)

set(CMAKE_SYSROOT /home/devel/rasp-pi-rootfs)
set(CMAKE_STAGING_PREFIX /home/devel/stage)

set(tools /home/devel/gcc-4.7-linaro-rpi-gnueabihf)
set(CMAKE_C_COMPILER ${tools}/bin/arm-linux-gnueabihf-gcc)
set(CMAKE_CXX_COMPILER ${tools}/bin/arm-linux-gnueabihf-g++)

set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE ONLY)

Переменная CMAKE_SYSTEM_NAME — это идентификатор CMake целевой платформы для сборки.

Переменная CMAKE_SYSTEM_PROCESSOR — это идентификатор CMake целевой архитектуры для сборки.

Переменная CMAKE_SYSROOT является необязательной и может быть указана, если доступен sysroot.

Переменная CMAKE_STAGING_PREFIX также является необязательной. Она может быть использована для указания пути на хост-системе для установки. Переменная CMAKE_INSTALL_PREFIX всегда указывает на место установки исполняемого файла, даже при кросс-компиляции.

Переменные CMAKE_<LANG>_COMPILER могут быть заданы полными путями или именами компиляторов для поиска в стандартных местах. Для инструментальных цепочек, которые не поддерживают компоновку библиотек без пользовательских флагов или скриптов, можно установить переменную CMAKE_TRY_COMPILE_TARGET_TYPE в значение STATIC_LIBRARY, чтобы указать CMake не пытаться компоновать исполняемые файлы во время проверок.

Команды CMake find_* по умолчанию будут искать в sysroot и в значениях CMAKE_FIND_ROOT_PATH, а также в корневом префиксе хост-системы. Хотя это можно контролировать на индивидуальной основе, при кросс-компиляции может быть полезно исключить поиск в хост-системе или целевой системе для определенных артефактов. Обычно, заголовки, библиотеки и пакеты должны быть найдены в префиксах целевой системы, в то время как исполняемые файлы, которые должны быть запущены в рамках сборки, должны быть найдены только на хост-системе, а не на целевой. Для этого служат переменные CMAKE_FIND_ROOT_PATH_MODE_*.

Кросс-компиляция для среды Cray Linux

Кросс-компиляция для вычислительных узлов в среде Cray Linux может быть выполнена без отдельного файла инструментальной цепочки. Указание -DCMAKE_SYSTEM_NAME=CrayLinuxEnvironment в командной строке CMake гарантирует, что соответствующие настройки сборки и пути поиска будут сконфигурированы. Платформа получит свою конфигурацию из текущих переменных окружения и сконфигурирует проект для использования обёртки компилятора из модулей PrgEnv-* среды Cray Programming Environment, если они присутствуют и загружены.

По умолчанию среда Cray Programming Environment поддерживает только статические библиотеки. Это можно изменить и включить динамические библиотеки, установив переменную среды CRAYPE_LINK_TYPE в значение dynamic.

Запуск CMake без указания CMAKE_SYSTEM_NAME выполнит этап конфигурации в режиме хоста, предполагая стандартную среду Linux. Если не переопределено, будут использоваться обёртки компилятора PrgEnv-*, что, если целью является узел входа или вычислительный узел, скорее всего, не является желаемым поведением. Исключением из этого правила является случай, когда вы собираете непосредственно на узле NID вместо кросс-компиляции с узла входа. Если вы пытаетесь собрать программное обеспечение для узла входа, вам необходимо либо сначала разгрузить загруженный модуль PrgEnv-* или явно указать CMake использовать системные компиляторы в /usr/bin вместо обёрток Cray. Если желательно настроить для вычислительного узла, просто укажите CMAKE_SYSTEM_NAME, как указано выше.

Кросс-компиляция с использованием Clang

Некоторые компиляторы, такие как Clang, являются по своей природе кросс-компиляторами. Переменная CMAKE_<LANG>_COMPILER_TARGET может быть установлена для передачи значения в эти поддерживаемые компиляторы при компиляции:

set(CMAKE_SYSTEM_NAME Linux)
set(CMAKE_SYSTEM_PROCESSOR arm)

set(triple arm-linux-gnueabihf)

set(CMAKE_C_COMPILER clang)
set(CMAKE_C_COMPILER_TARGET ${triple})
set(CMAKE_CXX_COMPILER clang++)
set(CMAKE_CXX_COMPILER_TARGET ${triple})

Аналогично, некоторые компиляторы не поставляют свои собственные вспомогательные утилиты, такие как компоновщики, но предоставляют способ указать расположение внешней инструментальной цепочки, которая будет использоваться драйвером компилятора. Переменная CMAKE_<LANG>_COMPILER_EXTERNAL_TOOLCHAIN может быть установлена в файле инструментальной цепочки для передачи пути к драйверу компилятора.

Кросс-компиляция для QNX

Как и компилятор Clang, компилятор QNX QCC является по своей природе кросс-компилятором. И CMAKE_<LANG>_COMPILER_TARGET может быть установлен для передачи значения в эти поддерживаемые компиляторы при компиляции:

set(CMAKE_SYSTEM_NAME QNX)

set(arch gcc_ntoarmv7le)

set(CMAKE_C_COMPILER qcc)
set(CMAKE_C_COMPILER_TARGET ${arch})
set(CMAKE_CXX_COMPILER QCC)
set(CMAKE_CXX_COMPILER_TARGET ${arch})

set(CMAKE_SYSROOT $ENV{QNX_TARGET})

Кросс-компиляция для Windows CE

Для кросс-компиляции для Windows CE требуется соответствующий SDK, установленный на вашей системе. Эти SDK обычно устанавливаются в C:/Program Files (x86)/Windows CE Tools/SDKs.

Файл инструментальной цепочки для настройки генератора Visual Studio для Windows CE может выглядеть следующим образом:

set(CMAKE_SYSTEM_NAME WindowsCE)

set(CMAKE_SYSTEM_VERSION 8.0)
set(CMAKE_SYSTEM_PROCESSOR arm)

set(CMAKE_GENERATOR_TOOLSET CE800) # Can be omitted for 8.0
set(CMAKE_GENERATOR_PLATFORM SDK_AM335X_SK_WEC2013_V310)

Переменная CMAKE_GENERATOR_PLATFORM сообщает генератору, какой SDK использовать. Далее переменная CMAKE_SYSTEM_VERSION сообщает генератору, какую версию Windows CE использовать. В настоящее время поддерживается версия 8.0 (Windows Embedded Compact 2013) из коробки. Для других версий может потребоваться установить CMAKE_GENERATOR_TOOLSET в соответствующее значение.

Кросс-компиляция для универсальных приложений Windows 10

Файл инструментальной цепочки для настройки генератора Visual Studio для универсального приложения Windows 10 может выглядеть следующим образом:

set(CMAKE_SYSTEM_NAME WindowsStore)
set(CMAKE_SYSTEM_VERSION 10.0)

Универсальное приложение Windows 10 предназначено для магазинов Windows и Windows Phone. Установите переменную CMAKE_SYSTEM_VERSION в значение 10.0, чтобы создать с помощью последней доступной Windows 10 SDK. Укажите более конкретную версию (например, 10.0.10240.0 для RTM), чтобы создать с соответствующим SDK.

Кросс-компиляция для Windows Phone

Файл инструментальной цепочки для настройки генератора Visual Studio для Windows Phone может выглядеть следующим образом:

set(CMAKE_SYSTEM_NAME WindowsPhone)
set(CMAKE_SYSTEM_VERSION 8.1)

Кросс-компиляция для Windows Store

Файл инструментальной цепочки для настройки генератора Visual Studio для Windows Store может выглядеть следующим образом:

set(CMAKE_SYSTEM_NAME WindowsStore)
set(CMAKE_SYSTEM_VERSION 8.1)

Кросс-компиляция для Android

Файл инструментальной цепочки может настроить кросс-компиляцию для Android, установив переменную CMAKE_SYSTEM_NAME в значение Android. Дальнейшая настройка зависит от используемой среды разработки Android.

Для генераторов Visual Studio, CMake ожидает установки NVIDIA Nsight Tegra Visual Studio Edition или Visual Studio tools for Android. Смотрите эти разделы для получения дополнительных данных о конфигурации.

Для генераторов Makefile и генератора Ninja, CMake ожидает установки одной из этих сред:

NDK
Инструментальная цепочка

CMake выполняет следующие шаги для выбора одной из этих сред:

Если переменная CMAKE_ANDROID_NDK установлена, будет использоваться NDK по указанному пути.
В противном случае, если установлена переменная CMAKE_ANDROID_STANDALONE_TOOLCHAIN, будет использоваться автономная цепочка инструментов по указанному пути.
В противном случае, если переменная CMAKE_SYSROOT установлена на директорию вида <ndk>/platforms/android-<api>/arch-<arch>, часть <ndk> будет использована в качестве значения для CMAKE_ANDROID_NDK, и будет использован NDK.
В противном случае, если переменная CMAKE_SYSROOT установлена на директорию вида <standalone-toolchain>/sysroot, часть <standalone-toolchain> будет использована в качестве значения для CMAKE_ANDROID_STANDALONE_TOOLCHAIN, и будет использована автономная цепочка инструментов.
В противном случае, если установлена переменная cmake ANDROID_NDK, она будет использована в качестве значения для CMAKE_ANDROID_NDK, и будет использован NDK.
В противном случае, если установлена переменная cmake ANDROID_STANDALONE_TOOLCHAIN, она будет использована в качестве значения для CMAKE_ANDROID_STANDALONE_TOOLCHAIN, и будет использована автономная цепочка инструментов.
В противном случае, если установлена переменная окружения ANDROID_NDK_ROOT или ANDROID_NDK, она будет использована в качестве значения для CMAKE_ANDROID_NDK, и будет использован NDK.
В противном случае, если установлена переменная окружения ANDROID_STANDALONE_TOOLCHAIN, она будет использована в качестве значения для CMAKE_ANDROID_STANDALONE_TOOLCHAIN, и будет использована автономная цепочка инструментов.
В противном случае будет выведено сообщение об ошибке, что ни NDK, ни автономная цепочка инструментов не найдены.

Компиляция для Android с помощью NDK

Файл цепочки инструментов может настроить Генераторы Makefile, Генераторы Ninja или Генераторы Visual Studio для компиляции Android.

Настройка использования Android NDK с помощью следующих переменных:

CMAKE_SYSTEM_NAME

Установите значение Android. Необходимо указать для включения кросс-компиляции для Android.

CMAKE_SYSTEM_VERSION

Установите уровень API Android. Если не указано, значение определяется следующим образом:

Если установлена переменная CMAKE_ANDROID_API, ее значение используется в качестве уровня API.
Если установлена переменная CMAKE_SYSROOT, уровень API определяется из структуры каталога NDK, содержащей sysroot.
В противном случае используется последний доступный уровень API в NDK.

CMAKE_ANDROID_ARCH_ABI

Установите Android ABI (архитектуру). Если не указано, эта переменная по умолчанию будет armeabi. Переменная CMAKE_ANDROID_ARCH будет вычислена автоматически из CMAKE_ANDROID_ARCH_ABI. Также см. переменные CMAKE_ANDROID_ARM_MODE и CMAKE_ANDROID_ARM_NEON.

CMAKE_ANDROID_NDK

Установите абсолютный путь к корневому каталогу Android NDK. Должен существовать каталог ${CMAKE_ANDROID_NDK}/platforms. Если не указано, значение этой переменной будет выбрано по умолчанию, как указано выше.

CMAKE_ANDROID_NDK_DEPRECATED_HEADERS

Установите значение в истинное значение, чтобы использовать устаревшие заголовки по уровням API вместо унифицированных заголовков. Если не указано, значение по умолчанию будет ложным, за исключением случаев использования NDK, не предоставляющего унифицированные заголовки.

CMAKE_ANDROID_NDK_TOOLCHAIN_VERSION

В NDK r19 или выше, эта переменная должна быть не установлена или установлена в clang. В NDK r18 или ниже, установите это значение в версию NDK цепочки инструментов для выбора компилятора. Если не указано, значение по умолчанию будет последняя доступная цепочка инструментов GCC.

CMAKE_ANDROID_STL_TYPE

Установите, чтобы указать, какую библиотеку стандартного C++ использовать. Если не указано, по умолчанию будет выбрано значение, как описано в документации по переменной.

Следующие переменные будут вычислены и предоставлены автоматически:

CMAKE_<LANG>_ANDROID_TOOLCHAIN_PREFIX: Абсолютный префикс пути к binutils в цепочке инструментов NDK.
CMAKE_<LANG>_ANDROID_TOOLCHAIN_SUFFIX: Суффикс платформы хоста binutils в цепочке инструментов NDK.

Например, файл цепочки инструментов может содержать:

set(CMAKE_SYSTEM_NAME Android)
set(CMAKE_SYSTEM_VERSION 21) # API level
set(CMAKE_ANDROID_ARCH_ABI arm64-v8a)
set(CMAKE_ANDROID_NDK /path/to/android-ndk)
set(CMAKE_ANDROID_STL_TYPE gnustl_static)

В качестве альтернативы можно указать значения без файла цепочки инструментов:

$ cmake ../src \
  -DCMAKE_SYSTEM_NAME=Android \
  -DCMAKE_SYSTEM_VERSION=21 \
  -DCMAKE_ANDROID_ARCH_ABI=arm64-v8a \
  -DCMAKE_ANDROID_NDK=/path/to/android-ndk \
  -DCMAKE_ANDROID_STL_TYPE=gnustl_static

Компиляция для Android с автономной цепочкой инструментов

Файл цепочки инструментов может настроить Генераторы Makefile или Ninja генератор для компиляции Android с помощью автономной цепочки инструментов.

Настройка использования автономной цепочки инструментов Android с помощью следующих переменных:

CMAKE_SYSTEM_NAME: Установите значение Android. Необходимо указать для включения кросс-компиляции для Android.
CMAKE_ANDROID_STANDALONE_TOOLCHAIN: Установите абсолютный путь к корневому каталогу автономной цепочки инструментов. Должен существовать каталог ${CMAKE_ANDROID_STANDALONE_TOOLCHAIN}/sysroot. Если не указано, значение этой переменной будет выбрано по умолчанию, как указано выше.
CMAKE_ANDROID_ARM_MODE: Когда автономная цепочка инструментов ориентирована на ARM, необязательно установите это значение в ON, чтобы нацеливаться на 32-разрядный ARM вместо 16-разрядного Thumb. Подробности см. в документации по переменной.
CMAKE_ANDROID_ARM_NEON: Когда автономная цепочка инструментов ориентирована на ARM v7, необязательно установите это значение в ON, чтобы нацеливаться на устройства ARM NEON. Подробности см. в документации по переменной.

Следующие переменные будут вычислены и предоставлены автоматически:

CMAKE_SYSTEM_VERSION: Уровень API Android, обнаруженный автономной цепочкой инструментов.
CMAKE_ANDROID_ARCH_ABI: ABI Android, обнаруженный автономной цепочкой инструментов.
CMAKE_<LANG>_ANDROID_TOOLCHAIN_PREFIX: Префикс абсолютного пути к binutils в автономной цепочке инструментов.
CMAKE_<LANG>_ANDROID_TOOLCHAIN_SUFFIX: Суффикс платформы хоста binutils в автономной цепочке инструментов.

Например, файл цепочки инструментов может содержать:

set(CMAKE_SYSTEM_NAME Android)
set(CMAKE_ANDROID_STANDALONE_TOOLCHAIN /path/to/android-toolchain)

В качестве альтернативы можно указать значения без файла цепочки инструментов:

$ cmake ../src \
  -DCMAKE_SYSTEM_NAME=Android \
  -DCMAKE_ANDROID_STANDALONE_TOOLCHAIN=/path/to/android-toolchain

Компиляция для Android с NVIDIA Nsight Tegra Visual Studio Edition

Файл цепочки инструментов для настройки одного из генераторов Visual Studio для сборки с использованием NVIDIA Nsight Tegra, нацеленного на Android, может выглядеть так:

set(CMAKE_SYSTEM_NAME Android)

Переменная CMAKE_GENERATOR_TOOLSET может быть установлена для выбора значения «Версии цепочки инструментов» Nsight Tegra.

См. также свойства целевых объектов:

Компиляция для iOS, tvOS или watchOS

Для кросс-компиляции в iOS, tvOS или watchOS рекомендуется генератор Xcode. Генераторы Unix Makefiles или Ninja также могут быть использованы, но они требуют от проекта обработки таких областей, как выбор целевого процессора и подписи кода.

Любая из трех систем может быть целевой, установив переменную CMAKE_SYSTEM_NAME на значение из таблицы ниже. По умолчанию выбирается последняя версия SDK устройства. Как и для всех платформ Apple, другой SDK (например, симулятора) можно выбрать, установив переменную CMAKE_OSX_SYSROOT, хотя это редко необходимо (см. Переключение между устройством и симулятором ниже). Список доступных SDK можно получить, выполнив xcodebuild -showsdks.

ОС	CMAKE_SYSTEM_NAME	SDK устройства (по умолчанию)	SDK симулятора
iOS	iOS	iphoneos	iphonesimulator
tvOS	tvOS	appletvos	appletvsimulator
watchOS	watchOS	watchos	watchsimulator

Например, для создания конфигурации CMake для iOS достаточно следующей команды:

cmake .. -GXcode -DCMAKE_SYSTEM_NAME=iOS

Переменная CMAKE_OSX_ARCHITECTURES может быть использована для установки архитектур как для устройства, так и для симулятора. Переменная CMAKE_OSX_DEPLOYMENT_TARGET может быть использована для установки целевого значения iOS/tvOS/watchOS.

Следующая конфигурация установит библиотеку iOS с 5 архитектурами и добавит флаги -miphoneos-version-min=9.3/-mios-simulator-version-min=9.3 в компилятор:

$ cmake -S. -B_builds -GXcode \
    -DCMAKE_SYSTEM_NAME=iOS \
    "-DCMAKE_OSX_ARCHITECTURES=armv7;armv7s;arm64;i386;x86_64" \
    -DCMAKE_OSX_DEPLOYMENT_TARGET=9.3 \
    -DCMAKE_INSTALL_PREFIX=`pwd`/_install \
    -DCMAKE_XCODE_ATTRIBUTE_ONLY_ACTIVE_ARCH=NO \
    -DCMAKE_IOS_INSTALL_COMBINED=YES

Пример:

# CMakeLists.txt
cmake_minimum_required(VERSION 3.14)
project(foo)
add_library(foo foo.cpp)
install(TARGETS foo DESTINATION lib)

Установка:

$ cmake --build _builds --config Release --target install

Проверка библиотеки:

$ lipo -info _install/lib/libfoo.a
Architectures in the fat file: _install/lib/libfoo.a are: i386 armv7 armv7s x86_64 arm64

$ otool -l _install/lib/libfoo.a | grep -A2 LC_VERSION_MIN_IPHONEOS
      cmd LC_VERSION_MIN_IPHONEOS
  cmdsize 16
  version 9.3

Подпись кода

Некоторые артефакты сборки для встроенных платформ Apple требуют обязательной подписи кода. Если используется генератор Xcode, а подпись кода требуется или желательна, идентификатор разработчика можно указать через переменную CMake CMAKE_XCODE_ATTRIBUTE_DEVELOPMENT_TEAM. Этот идентификатор команды затем будет включен в сгенерированный проект Xcode. По умолчанию CMake избегает необходимости подписи кода во время внутренней фазы настройки (т. е. идентификатор компилятора и обнаружение функций).

Переключение между устройством и симулятором

При настройке для любой из встроенных платформ можно нацеливаться либо на реальные устройства, либо на симулятор. У них оба есть свои отдельные SDK, но CMake поддерживает только указание одного SDK для фазы настройки. Это означает, что разработчик должен выбрать один из них во время настройки. При использовании генератора Xcode, это ограничение менее критично, так как Xcode все равно позволяет собирать как для устройства, так и для симулятора, даже если настройка была выполнена только для одного из двух. Внутри IDE Xcode сборка выполняется для выбранной платформы «назначения». При сборке из командной строки желаемый sdk можно указать непосредственно, передав опцию -sdk основному инструменту сборки (xcodebuild). Например:

$ cmake --build ... -- -sdk iphonesimulator

Обратите внимание, что проверки, выполненные во время настройки, проводились с использованием SDK времени настройки и могут не выполняться для других SDK. Команды, такие как find_package(), find_library() и т. д. сохраняют и используют подробности только для настроенного SDK/платформы, поэтому они могут быть проблематичными при переключении между сборками устройства и симулятора. Вы можете следовать следующим правилам, чтобы работала настройка устройства + симулятор:

Используйте явное -l флаговое значение линкера, например target_link_libraries(foo PUBLIC "-lz")
Используйте явное -framework флаговое значение линкера, например target_link_libraries(foo PUBLIC "-framework CoreFoundation")
Используйте find_package() только для библиотек, установленных с помощью функции CMAKE_IOS_INSTALL_COMBINED

© 2000–2020 Kitware, Inc. and Contributors
Licensed under the BSD 3-clause License.
https://cmake.org/cmake/help/v3.19/manual/cmake-toolchains.7.html