FindPackageHandleStandardArgs

Этот модуль предоставляет функции, предназначенные для использования в Поиске модулей, реализующие вызовы find_package(<PackageName>).

find_package_handle_standard_args

Эта команда обрабатывает REQUIRED, QUIET и аргументы, связанные с версиями, вызова find_package(). Она также устанавливает переменную <PackageName>_FOUND. Пакет считается найденным, если все перечисленные переменные содержат корректные результаты, например, корректные пути к файлам.

Существует две подписи:

find_package_handle_standard_args(<PackageName>
  (DEFAULT_MSG|<custom-failure-message>)
  <required-var>...
  )

find_package_handle_standard_args(<PackageName>
  [FOUND_VAR <result-var>]
  [REQUIRED_VARS <required-var>...]
  [VERSION_VAR <version-var>]
  [HANDLE_VERSION_RANGE]
  [HANDLE_COMPONENTS]
  [CONFIG_MODE]
  [NAME_MISMATCHED]
  [REASON_FAILURE_MESSAGE <reason-failure-message>]
  [FAIL_MESSAGE <custom-failure-message>]
  )

Переменная <PackageName>_FOUND будет установлена в TRUE, если все переменные <required-var>... являются корректными и выполняются все необходимые условия, и в FALSE в противном случае. Сообщение об успехе или ошибке может быть выведено на основе результатов и в зависимости от того, были ли переданы опции REQUIRED и/или QUIET вызову find_package().

Опции:

(DEFAULT_MSG|<custom-failure-message>)

В простой подписи это указывает сообщение об ошибке. Используйте DEFAULT_MSG для запроса вычисления стандартного сообщения (рекомендуется). Недействительно в полной подписи.

FOUND_VAR <result-var>

Устарело. Указывает либо <PackageName>_FOUND, либо <PACKAGENAME>_FOUND в качестве переменной результата. Эта опция существует только для совместимости со старыми версиями CMake и теперь игнорируется. Переменные результата с обоими именами всегда устанавливаются для совместимости.

REQUIRED_VARS <required-var>...

Укажите переменные, необходимые для этого пакета. Их имена могут быть указаны в сгенерированном сообщении об ошибке, предлагающем пользователю установить значения отсутствующих переменных. Поэтому обычно это должны быть записи кэша, такие как FOO_LIBRARY, а не переменные вывода, такие как FOO_LIBRARIES. Эта опция является обязательной, если не указана опция HANDLE_COMPONENTS.

VERSION_VAR <version-var>

Укажите имя переменной, содержащей версию найденного пакета. Эта версия будет проверена на соответствие (возможно, указанной) требуемой версии, заданной в вызове find_package(), включая опцию EXACT. Стандартные сообщения включают информацию о требуемой версии и фактически найденной версии, как если версия подходит, так и если не подходит.

HANDLE_VERSION_RANGE

Включить обработку диапазона версий, если он указан. Без этой опции будет отображено предупреждение разработчику, если указан диапазон версий.

HANDLE_COMPONENTS

Включить обработку компонентов пакета. В этом случае команда сообщит, какие компоненты найдены, а какие отсутствуют, и переменная <PackageName>_FOUND будет установлена в FALSE, если любой из необходимых компонентов (то есть, не те, которые перечислены после опции OPTIONAL_COMPONENTS вызова find_package()) отсутствует.

CONFIG_MODE

Указывает, что вызывающий модуль поиска является обёрткой вызова find_package(<PackageName> NO_MODULE). Это подразумевает значение VERSION_VAR в <PackageName>_VERSION. Команда автоматически проверит, был ли найден файл конфигурации пакета.

REASON_FAILURE_MESSAGE <reason-failure-message>

Укажите пользовательское сообщение о причине ошибки, которое будет добавлено к стандартному генерируемому сообщению.

FAIL_MESSAGE <custom-failure-message>

Укажите пользовательское сообщение об ошибке вместо использования стандартного сгенерированного сообщения. Не рекомендуется.

NAME_MISMATCHED

Укажите, что <PackageName> не совпадает с ${CMAKE_FIND_PACKAGE_NAME}. Обычно это ошибка и выводится предупреждение, но может быть намеренным для использования команды для компонентов большего пакета.

Пример для простой подписи:

find_package_handle_standard_args(LibXml2 DEFAULT_MSG
  LIBXML2_LIBRARY LIBXML2_INCLUDE_DIR)

Пакет LibXml2 считается найденным, если LIBXML2_LIBRARY и LIBXML2_INCLUDE_DIR являются корректными. Тогда также LibXml2_FOUND будет установлено в TRUE. Если он не найден и использовалась REQUIRED, то произойдет ошибка с message(FATAL_ERROR), независимо от того, использовалась QUIET или нет. Если он найден, то будет сообщено об успехе, включая содержимое первого <required-var>. При повторных запусках CMake это сообщение не будет выводиться повторно.

Пример для полной подписи:

find_package_handle_standard_args(LibArchive
  REQUIRED_VARS LibArchive_LIBRARY LibArchive_INCLUDE_DIR
  VERSION_VAR LibArchive_VERSION)

В этом случае, пакет LibArchive считается найденным, если LibArchive_LIBRARY и LibArchive_INCLUDE_DIR являются корректными. Также версия LibArchive будет проверена с использованием версии, содержащейся в LibArchive_VERSION. Так как опция FAIL_MESSAGE не передана, будут выведены стандартные сообщения.

Ещё один пример для полной подписи:

find_package(Automoc4 QUIET NO_MODULE HINTS /opt/automoc4)
find_package_handle_standard_args(Automoc4  CONFIG_MODE)

В этом случае, модуль FindAutmoc4.cmake выполняет вызов find_package(Automoc4 NO_MODULE) и добавляет дополнительную директорию поиска для automoc4. Затем вызов find_package_handle_standard_args генерирует корректное сообщение об успехе/ошибке.

find_package_check_version

Вспомогательная функция, которая может использоваться для проверки корректности <version> относительно аргументов, связанных с версиями, в вызове find_package().

find_package_check_version(<version> <result-var>
  [HANDLE_VERSION_RANGE]
  [RESULT_MESSAGE_VARIABLE <message-var>]
  )

Переменная <result-var> будет содержать булевое значение, отражающее результат проверки.

Опции:

HANDLE_VERSION_RANGE

Включить обработку диапазона версий, если он указан. Без этой опции будет отображено предупреждение разработчику, если указан диапазон версий.

RESULT_MESSAGE_VARIABLE <message-var>

Указать переменную для получения сообщения, описывающего результат проверки.

Пример использования:

find_package_check_version(1.2.3 result HANDLE_VERSION_RANGE
  RESULT_MESSAGE_VARIABLE reason)
if (result)
  message (STATUS "${reason}")
else()
  message (FATAL_ERROR "${reason}")
endif()