configure_file

Копирует файл в другое место и изменяет его содержимое.

configure_file(<input> <output>
               [FILE_PERMISSIONS <permissions>...]
               [COPYONLY] [ESCAPE_QUOTES] [@ONLY]
               [NO_SOURCE_PERMISSIONS] [USE_SOURCE_PERMISSIONS]
               [NEWLINE_STYLE [UNIX|DOS|WIN32|LF|CRLF] ])

Копирует файл <input> в файл <output> и заменяет значения переменных, указанных как @VAR@ или ${VAR} в содержимом входного файла. Каждая ссылка на переменную будет заменена текущим значением переменной или пустой строкой, если переменная не определена. Кроме того, строки входного файла вида

#cmakedefine VAR ...

будут заменены на

#define VAR ...

или

/* #undef VAR */

в зависимости от того, установлено ли значение VAR в CMake, отличное от значения, считаемого ложным константой командой if(). Содержимое "..." в строке после имени переменной, если оно есть, обрабатывается аналогично вышеописанному.

Строки входного файла вида #cmakedefine01 VAR будут заменены на #define VAR 1 или #define VAR 0 аналогично.

#  cmakedefine VAR
#  cmakedefine01 VAR

#  define VAR
#  define VAR 1

Если входной файл изменён, система сборки повторно выполнит CMake, чтобы переконфигурировать файл и снова сгенерировать систему сборки. Сгенерированный файл изменяется и его метка времени обновляется при последующих запусках cmake только в случае изменения его содержимого.

Аргументы:

<input>

Путь к входному файлу. Относительный путь обрабатывается с учётом значения CMAKE_CURRENT_SOURCE_DIR. Путь к входному файлу должен указывать на файл, а не на директорию.

<output>

Путь к выходному файлу или директории. Относительный путь обрабатывается с учётом значения CMAKE_CURRENT_BINARY_DIR. Если путь указывает на существующую директорию, выходной файл помещается в эту директорию с тем же именем файла, что и входной файл.

FILE_PERMISSIONS <permissions>...

Использовать предоставленные пользователем разрешения для выходного файла.

COPYONLY

Копировать файл без замены ссылок на переменные или другого содержимого. Этот параметр нельзя использовать с NEWLINE_STYLE.

ESCAPE_QUOTES

Экранировать любые подставленные кавычки обратными слешами (стиль C).

@ONLY

Ограничить замену переменных ссылками вида @VAR@. Это полезно для конфигурирования скриптов, использующих синтаксис ${VAR}.

NO_SOURCE_PERMISSIONS

Новое в версии 3.19.

Не переносит разрешения файла оригинала на копию. Разрешения копируемого файла по умолчанию равны 644 (-rw-r--r--).

USE_SOURCE_PERMISSIONS

Новое в версии 3.20.

Переносит разрешения файла оригинала на выходной файл.

NEWLINE_STYLE <style>

Укажите стиль новой строки для выходного файла. Укажите UNIX или LF для \n новых строк или укажите DOS, WIN32, или CRLF для \r\n новых строк. Этот параметр нельзя использовать с COPYONLY.

Пример

Рассмотрим дерево исходных файлов, содержащее файл foo.h.in:

#cmakedefine FOO_ENABLE
#cmakedefine FOO_STRING "@FOO_STRING@"

Смежный файл CMakeLists.txt может использовать configure_file для конфигурирования заголовка:

option(FOO_ENABLE "Enable Foo" ON)
if(FOO_ENABLE)
  set(FOO_STRING "foo")
endif()
configure_file(foo.h.in foo.h @ONLY)

Это создаёт файл foo.h в каталоге сборки, соответствующем этому исходному каталогу. Если включён параметр FOO_ENABLE, сконфигурированный файл будет содержать:

#define FOO_ENABLE
#define FOO_STRING "foo"

В противном случае он будет содержать:

/* #undef FOO_ENABLE */
/* #undef FOO_STRING */

Затем можно использовать команду include_directories(), чтобы указать каталог вывода как каталог включения:

include_directories(${CMAKE_CURRENT_BINARY_DIR})

чтобы источники могли включать заголовок как #include <foo.h>.