FindPkgConfig

Модуль pkg-config для CMake.

Находит исполняемый файл pkg-config и добавляет команды pkg_get_variable(), pkg_check_modules() и pkg_search_module(). Также будут установлены следующие переменные:

PKG_CONFIG_FOUND

если исполняемый файл pkg-config был найден

PKG_CONFIG_EXECUTABLE

путь к программе pkg-config

PKG_CONFIG_VERSION_STRING

версия pkg-config (с CMake 2.8.8)

pkg_check_modules

Проверяет наличие всех указанных модулей, устанавливая ряд переменных результата в области вызова.

pkg_check_modules(<prefix>
                  [REQUIRED] [QUIET]
                  [NO_CMAKE_PATH]
                  [NO_CMAKE_ENVIRONMENT_PATH]
                  [IMPORTED_TARGET [GLOBAL]]
                  <moduleSpec> [<moduleSpec>...])

Если задан аргумент REQUIRED, команда завершится ошибкой, если модуль(и) не найден(ы).

Если задан аргумент QUIET, сообщения об успехе не будут выводиться.

Добавлена в версии 3.1: Переменные кэша и среды CMAKE_PREFIX_PATH, CMAKE_FRAMEWORK_PATH и CMAKE_APPBUNDLE_PATH будут добавлены в путь поиска pkg-config. Аргументы NO_CMAKE_PATH и NO_CMAKE_ENVIRONMENT_PATH отключат это поведение для переменных кэша и переменных среды соответственно. Переменная PKG_CONFIG_USE_CMAKE_PREFIX_PATH со значением FALSE отключает это поведение глобально.

Добавлена в версии 3.6: Аргумент IMPORTED_TARGET создаст импортируемый целевой объект с именем PkgConfig::<prefix>, который можно передать непосредственно в качестве аргумента target_link_libraries().

Добавлена в версии 3.13: Аргумент GLOBAL сделает импортируемый целевой объект доступным в глобальной области видимости.

Добавлена в версии 3.15: Опции компоновщика, не относящиеся к библиотекам, которые сообщит pkg-config, хранятся в свойстве целевого объекта INTERFACE_LINK_OPTIONS.

Изменено в версии 3.18: Директории заголовков, указанные с помощью -isystem, сохраняются в свойстве целевого объекта INTERFACE_INCLUDE_DIRECTORIES. Предыдущие версии CMake сохраняли их в свойстве INTERFACE_COMPILE_OPTIONS.

Каждый <moduleSpec> может быть либо простым именем модуля, либо именем модуля с ограничением версии (поддерживаются операторы =, <, >, <= и >=). Ниже приведены примеры для модуля под названием foo с различными ограничениями:

• foo соответствует любой версии.
• foo<2 соответствует только версиям до 2.
• foo>=3.1 соответствует любой версии от 3.1 и выше.
• foo=1.2.3 требует, чтобы foo был ровно версии 1.2.3.

При возврате могут быть установлены следующие переменные. Существуют два набора значений: один для распространённого случая (<XXX> = <prefix>) и другой для информации, которую pkg-config предоставляет при вызове с параметром --static (<XXX> = <prefix>_STATIC).

<XXX>_FOUND

устанавливается в 1, если модуль(и) существует(ют)

<XXX>_LIBRARIES

только библиотеки (без '-l')

<XXX>_LINK_LIBRARIES

библиотеки и их абсолютные пути

<XXX>_LIBRARY_DIRS

пути к библиотекам (без '-L')

<XXX>_LDFLAGS

все необходимые флаги компоновщика

<XXX>_LDFLAGS_OTHER

все остальные флаги компоновщика

<XXX>_INCLUDE_DIRS

флаги препроцессора '-I' (без '-I')

<XXX>_CFLAGS

все необходимые флаги компилятора

<XXX>_CFLAGS_OTHER

другие флаги компилятора

Все, кроме <XXX>_FOUND, могут быть списком, если у соответствующей переменной, возвращаемой из pkg-config, несколько значений.

Изменено в версии 3.18: Директории заголовков, указанные с помощью -isystem, сохраняются в переменной <XXX>_INCLUDE_DIRS. Предыдущие версии CMake сохраняли их в <XXX>_CFLAGS_OTHER.

Существуют некоторые специальные переменные, префикс которых зависит от количества <moduleSpec>. Когда указан только один <moduleSpec>, <YYY> будет просто <prefix>, но если указано два или более <moduleSpec> элемента, <YYY> будет <prefix>_<moduleName>.

<YYY>_VERSION

версия модуля

<YYY>_PREFIX

директория префикса модуля

<YYY>_INCLUDEDIR

директория заголовков модуля

<YYY>_LIBDIR

директория библиотек модуля

Изменено в версии 3.8: Для каждого указанного <prefix>, pkg_check_modules() может быть вызвано несколько раз с разными параметрами. Предыдущие версии CMake кешировали и возвращали первый успешный результат.

Изменено в версии 3.16: Если полный путь к найденной библиотеке определить нельзя, но она всё ещё видна для компоновщика, передавайте её как -l<name>. Предыдущие версии CMake в этом случае завершались ошибкой.

Примеры:

pkg_check_modules (GLIB2 glib-2.0)

Ищет любую версию glib2. Если найдена, переменная результата GLIB2_VERSION будет содержать фактическую найденную версию.

pkg_check_modules (GLIB2 glib-2.0>=2.10)

Ищет версию glib2 не менее 2.10. Если найдена, переменная результата GLIB2_VERSION будет содержать фактическую найденную версию.

pkg_check_modules (FOO glib-2.0>=2.10 gtk+-2.0)

Ищет glib2-2.0 (не менее версии 2.10) и любую версию gtk2+-2.0. Только если оба найдены, FOO будет считаться найденным. Переменные FOO_glib-2.0_VERSION и FOO_gtk+-2.0_VERSION будут установлены соответственно в версии найденных модулей.

pkg_check_modules (XRENDER REQUIRED xrender)

Требует любую версию xrender. Пример переменных результатов, установленных при успешном вызове:

XRENDER_LIBRARIES=Xrender;X11
XRENDER_STATIC_LIBRARIES=Xrender;X11;pthread;Xau;Xdmcp

pkg_search_module

Поведение этой команды такое же, как у pkg_check_modules(), за исключением того, что вместо проверки всех указанных модулей она ищет только первое успешное совпадение.

pkg_search_module(<prefix>
                  [REQUIRED] [QUIET]
                  [NO_CMAKE_PATH]
                  [NO_CMAKE_ENVIRONMENT_PATH]
                  [IMPORTED_TARGET [GLOBAL]]
                  <moduleSpec> [<moduleSpec>...])

Добавлена в версии 3.16: Если модуль найден, переменная <prefix>_MODULE_NAME будет содержать имя соответствующего модуля. Эта переменная может быть использована, если вам необходимо вызвать pkg_get_variable().

Пример:

pkg_search_module (BAR libxml-2.0 libxml2 libxml>=2)

pkg_get_variable

Добавлена в версии 3.4.

Извлекает значение переменной pkg-config varName и сохраняет его в переменной результата resultVar в области вызова.

pkg_get_variable(<resultVar> <moduleName> <varName>)

Если pkg-config возвращает несколько значений для указанной переменной, resultVar будет содержать список.

Например:

pkg_get_variable(GI_GIRDIR gobject-introspection-1.0 girdir)

Переменные, влияющие на поведение

PKG_CONFIG_EXECUTABLE

Может быть установлена для указания пути к исполняемому файлу pkg-config. Если не указана, она будет установлена модулем в результате вызова find_program() внутри.

Добавлена в версии 3.1: Переменная среды PKG_CONFIG может быть использована в качестве подсказки.

PKG_CONFIG_USE_CMAKE_PREFIX_PATH

Добавлено в версии 3.1.

Определяет, должны ли pkg_check_modules() и pkg_search_module() добавлять пути из кэша CMAKE_PREFIX_PATH, CMAKE_FRAMEWORK_PATH и CMAKE_APPBUNDLE_PATH и переменных окружения в путь поиска pkg-config.

Если эта переменная не задана, данное поведение включено по умолчанию, если CMAKE_MINIMUM_REQUIRED_VERSION равно 3.1 или выше, в противном случае — отключено.