ctest_submit

Выполнить шаг отправки CTest в качестве клиента панели мониторинга.

ctest_submit([PARTS <part>...] [FILES <file>...]
             [SUBMIT_URL <url>]
             [BUILD_ID <result-var>]
             [HTTPHEADER <header>]
             [RETRY_COUNT <count>]
             [RETRY_DELAY <delay>]
             [RETURN_VALUE <result-var>]
             [CAPTURE_CMAKE_ERROR <result-var>]
             [QUIET]
             )

Отправить результаты на сервер панели мониторинга. По умолчанию отправляются все доступные части.

Доступные параметры:

PARTS <part>...

Указать подмножество частей для отправки. Допустимые имена частей:

Start      = nothing
Update     = ctest_update results, in Update.xml
Configure  = ctest_configure results, in Configure.xml
Build      = ctest_build results, in Build.xml
Test       = ctest_test results, in Test.xml
Coverage   = ctest_coverage results, in Coverage.xml
MemCheck   = ctest_memcheck results, in DynamicAnalysis.xml and
             DynamicAnalysis-Test.xml
Notes      = Files listed by CTEST_NOTES_FILES, in Notes.xml
ExtraFiles = Files listed by CTEST_EXTRA_SUBMIT_FILES
Upload     = Files prepared for upload by ctest_upload(), in Upload.xml
Submit     = nothing
Done       = Build is complete, in Done.xml

FILES <file>...

Указать явный список конкретных файлов для отправки. Каждый отдельный файл должен существовать на момент вызова.

SUBMIT_URL <url>

Новое в версии 3.14.

URL сервера панели мониторинга http или https для отправки данных. Если не указано, используется переменная CTEST_SUBMIT_URL.

BUILD_ID <result-var>

Новое в версии 3.15.

Сохранить в переменной <result-var> идентификатор, присвоенный этой сборке CDash.

HTTPHEADER <HTTP-header>

Новое в версии 3.9.

Указать HTTP-заголовок, который нужно включить в запрос к CDash при отправке. Например, CDash может быть настроен на прием данных только от авторизованных клиентов. В этом случае вам нужно предоставить токен доступа в заголовке:

ctest_submit(HTTPHEADER "Authorization: Bearer <auth-token>")

Этот подпараметр можно повторять несколько раз для нескольких заголовков.

RETRY_COUNT <count>

Указать, сколько раз нужно повторить попытку отправки, если она завершилась ошибкой из-за таймаута.

RETRY_DELAY <delay>

Указать, сколько секунд нужно ждать после завершения отправки с ошибкой таймаута, прежде чем пытаться отправить данные повторно.

RETURN_VALUE <result-var>

Сохранить в переменной <result-var> значение 0 при успешном выполнении и ненулевое значение при ошибке.

CAPTURE_CMAKE_ERROR <result-var>

Новое в версии 3.13.

Сохранить в переменной <result-var> значение -1, если при выполнении команды возникли ошибки, и предотвратить возвращение ненулевого значения ctest при возникновении ошибки.

QUIET

Новое в версии 3.3.

Запретить вывод всех сообщений, не являющихся ошибками, которые в противном случае были бы выведены в консоль.

Отправка на CDash Upload API

ctest_submit(CDASH_UPLOAD <file> [CDASH_UPLOAD_TYPE <type>]
             [SUBMIT_URL <url>]
             [BUILD_ID <result-var>]
             [HTTPHEADER <header>]
             [RETRY_COUNT <count>]
             [RETRY_DELAY <delay>]
             [RETURN_VALUE <result-var>]
             [QUIET])

Эта вторая сигнатура используется для загрузки файлов в CDash через API загрузки файлов CDash. API сначала отправляет запрос на загрузку в CDash вместе с хэшем содержимого файла. Если файла ещё нет в CDash, он загружается. Вместе с файлом указывается строка типа CDash, чтобы сообщить CDash, какой обработчик использовать для обработки данных.

Эта сигнатура интерпретирует параметры так же, как и первая.