foreach

Оценить группу команд для каждого значения в списке.

foreach(<loop_var> <items>)
  <commands>
endforeach()

где <items> — это список элементов, разделенных точкой с запятой или пробелом. Все команды между foreach и соответствующей endforeach записываются без вызова. После оценки endforeach, записанный список команд вызывается один раз для каждого элемента в <items>. В начале каждой итерации переменная <loop_var> будет установлена в значение текущего элемента.

Область действия <loop_var> ограничена областью цикла. См. политику CMP0124 для получения подробностей.

Команды break() и continue() предоставляют возможность выхода из обычного потока управления.

По умолчанию, команда endforeach() допускает необязательный <loop_var> аргумент. Если он используется, он должен быть точной копией аргумента открывающей foreach команды.

foreach(<loop_var> RANGE <stop>)

В этом варианте foreach перебирает числа от 0, 1, ... до (включительно) неотрицательного целого числа <stop>.

foreach(<loop_var> RANGE <start> <stop> [<step>])

В этом варианте foreach перебирает числа от <start> до не более чем <stop> с шагом <step>. Если <step> не указан, шаг равен 1. Все три аргумента <start> <stop> <step> должны быть неотрицательными целыми числами, а <stop> не должно быть меньше <start>; в противном случае вы вступаете в зону недокументированного поведения, которое может измениться в будущих версиях.

foreach(<loop_var> IN [LISTS [<lists>]] [ITEMS [<items>]])

В этом варианте <lists> — это список переменных со значениями списков, разделенных пробелами или точками с запятой. Команда foreach перебирает каждый элемент в каждом заданном списке. Команды, следующие за ключевым словом <items>, обрабатываются так же, как и в первом варианте команды foreach. Форматы LISTS A и ITEMS ${A} эквивалентны.

Следующий пример демонстрирует обработку опции LISTS.

set(A 0;1)
set(B 2 3)
set(C "4 5")
set(D 6;7 8)
set(E "")
foreach(X IN LISTS A B C D E)
    message(STATUS "X=${X}")
endforeach()

выдает

-- X=0
-- X=1
-- X=2
-- X=3
-- X=4 5
-- X=6
-- X=7
-- X=8

foreach(<loop_var>... IN ZIP_LISTS <lists>)

В этом варианте <lists> — это список переменных со значениями списков, разделенных пробелами или точками с запятой. Команда foreach перебирает каждый список одновременно, устанавливая переменные итерации следующим образом:

• если указана только одна loop_var, она устанавливает ряд loop_var_N переменных в текущий элемент из соответствующего списка;
• если указано несколько имён переменных, их количество должно совпадать с количеством переменных в списках;
• если какой-либо из списков короче, соответствующая переменная итерации не определена для текущей итерации.

list(APPEND English one two three four)
list(APPEND Bahasa satu dua tiga)

foreach(num IN ZIP_LISTS English Bahasa)
    message(STATUS "num_0=${num_0}, num_1=${num_1}")
endforeach()

foreach(en ba IN ZIP_LISTS English Bahasa)
    message(STATUS "en=${en}, ba=${ba}")
endforeach()

выдает

-- num_0=one, num_1=satu
-- num_0=two, num_1=dua
-- num_0=three, num_1=tiga
-- num_0=four, num_1=
-- en=one, ba=satu
-- en=two, ba=dua
-- en=three, ba=tiga
-- en=four, ba=