macro

Начало записи макроса для последующего вызова в качестве команды

macro(<name> [<arg1> ...])
  <commands>
endmacro()

Определяет макрос с именем <name> , принимающий аргументы с именами <arg1>, ... Команды, перечисленные после макроса, но перед соответствующей командой endmacro(), не выполняются, пока макрос не будет вызван.

Согласно старой версии, команда endmacro() допускает необязательный <name> аргумент. Если он используется, он должен быть точной копией аргумента открывающей команды macro.

См. документацию команды cmake_policy() для получения информации о поведении политик внутри макросов.

См. раздел Макрос против функции ниже для различий между макросами CMake и командой functions.

Вызов

Вызов макроса нечувствителен к регистру. Макрос, определённый как

macro(foo)
  <commands>
endmacro()

можно вызвать любым из вариантов

foo()
Foo()
FOO()
cmake_language(CALL foo)

и так далее. Однако настоятельно рекомендуется придерживаться регистра, выбранного при определении макроса. Обычно для макросов используются имена, написанные строчными буквами.

Аргументы

При вызове макроса команды, записанные в макросе, сначала модифицируются путём замены формальных параметров (${arg1}, ...) на переданные аргументы, а затем выполняются как обычные команды.

В дополнение к ссылке на формальные параметры вы можете ссылаться на значения ${ARGC}, которые будут установлены в число переданных аргументов, а также на ${ARGV0}, ${ARGV1}, ${ARGV2}, ... которые будут содержать фактические значения переданных аргументов. Это позволяет создавать макросы с необязательными аргументами.

Кроме того, ${ARGV} содержит список всех переданных аргументов, а ${ARGN} содержит список аргументов, следующих за последним ожидаемым аргументом. Ссылка на аргументы ${ARGV#} за пределами ${ARGC} имеет неопределённое поведение. Проверка того, что ${ARGC} больше, чем #, является единственным способом гарантировать, что ${ARGV#} был передан функции в качестве дополнительного аргумента.

Макрос против функции

Команда macro очень похожа на команду function(). Тем не менее, существуют некоторые важные различия.

В функции ARGN, ARGC, ARGV и ARGV0, ARGV1, ... являются истинными переменными в обычном смысле CMake. В макросе они таковыми не являются, они являются строковыми заменами, подобными тому, как это делает препроцессор C с макросом. Это имеет ряд последствий, как описано в разделе Особенности аргументов ниже.

Другое различие между макросами и функциями — это поток управления. Функция выполняется путём передачи управления от вызывающей инструкции к телу функции. Макрос выполняется так, как будто тело макроса вставлено вместо вызывающей инструкции. Это означает, что return() в теле макроса не просто завершает выполнение макроса; вместо этого управление возвращается из области вызова макроса. Чтобы избежать путаницы, рекомендуется вообще избегать return() в макросах.

В отличие от функции, переменные CMAKE_CURRENT_FUNCTION, CMAKE_CURRENT_FUNCTION_LIST_DIR, CMAKE_CURRENT_FUNCTION_LIST_FILE, CMAKE_CURRENT_FUNCTION_LIST_LINE не устанавливаются для макроса.

Особенности аргументов

Поскольку ARGN, ARGC, ARGV, ARGV0 и т.д. не являются переменными, вы НЕ сможете использовать команды, подобные

if(ARGV1) # ARGV1 is not a variable
if(DEFINED ARGV2) # ARGV2 is not a variable
if(ARGC GREATER 2) # ARGC is not a variable
foreach(loop_var IN LISTS ARGN) # ARGN is not a variable

В первом случае вы можете использовать if(${ARGV1}). Во втором и третьем случаях правильный способ проверки того, был ли необязательный аргумент передан макросу, — использовать if(${ARGC} GREATER 2). В последнем случае вы можете использовать foreach(loop_var ${ARGN}), но это пропустит пустые аргументы. Если вам нужно их включить, вы можете использовать

set(list_var "${ARGN}")
foreach(loop_var IN LISTS list_var)

Обратите внимание, что если в области, из которой вызывается макрос, есть переменная с тем же именем, использование неинициализированных имён будет использовать существующую переменную вместо аргументов. Например:

macro(bar)
  foreach(arg IN LISTS ARGN)
    <commands>
  endforeach()
endmacro()

function(foo)
  bar(x y z)
endfunction()

foo(a b c)

будет перебирать a;b;c , а не x;y;z, как можно было бы ожидать. Если вам нужны истинные переменные CMake и/или лучший контроль над областью CMake, обратитесь к команде функции.