configure_file

Копирование файла в другое место с модификацией содержимого.

configure_file(<input> <output>
               [NO_SOURCE_PERMISSIONS | USE_SOURCE_PERMISSIONS |
                FILE_PERMISSIONS <permissions>...]
               [COPYONLY] [ESCAPE_QUOTES] [@ONLY]
               [NEWLINE_STYLE [UNIX|DOS|WIN32|LF|CRLF] ])

Копирует файл <input> в файл <output> и подставляет значения переменных, указанных как @VAR@ или ${VAR} в содержимом входного файла. Каждая ссылка на переменную будет заменена текущим значением переменной или пустой строкой, если переменная не определена. Кроме того, строки входного файла вида

#cmakedefine VAR ...

будут заменены на

#define VAR ...

или

/* #undef VAR */

в зависимости от того, установлено ли значение VAR в CMake, отличное от значения, которое команда if() считает ложным.

Контент "..." после имени переменной, если он есть, обрабатывается аналогичным образом.

В отличие от строк вида #cmakedefine VAR ..., в строках вида #cmakedefine01 VAR, VAR само будет расширяться до VAR 0 или VAR 1, а не присваиваться значение .... Поэтому строки входного файла вида

#cmakedefine01 VAR

будут заменены на

#define VAR 0

или

#define VAR 1

Строки входного файла вида #cmakedefine01 VAR ... будут расширяться как #cmakedefine01 VAR ... 0 или #cmakedefine01 VAR ... 0, что может привести к неопределенному поведению.

#  cmakedefine VAR
#  cmakedefine01 VAR

#  define VAR
#  define VAR 1

Если входной файл модифицирован, система сборки повторно выполнит CMake для повторной настройки файла и повторного генерации системы сборки. Сгенерированный файл модифицируется и его метка времени обновляется при последующих запусках cmake только в случае изменения его содержимого.

Аргументы:

<input>

Путь к входному файлу. Относительный путь обрабатывается относительно значения CMAKE_CURRENT_SOURCE_DIR. Входной путь должен указывать на файл, а не на директорию.

<output>

Путь к выходному файлу или директории. Относительный путь обрабатывается относительно значения CMAKE_CURRENT_BINARY_DIR. Если путь указывает на существующую директорию, выходной файл размещается в этой директории с тем же именем файла, что и входной файл. Если путь содержит несуществующие директории, они создаются.

NO_SOURCE_PERMISSIONS

Новое в версии 3.19.

Не переносить права доступа входного файла на выходной файл. Права доступа копируемого файла по умолчанию устанавливаются в стандартное значение 644 (-rw-r--r--).

USE_SOURCE_PERMISSIONS

Новое в версии 3.20.

Переносить права доступа входного файла на выходной файл. Это уже поведение по умолчанию, если ни одно из трёх ключевых слов, связанных с правами доступа, не указано (NO_SOURCE_PERMISSIONS, USE_SOURCE_PERMISSIONS или FILE_PERMISSIONS). Ключевое слово USE_SOURCE_PERMISSIONS в основном служит для большей ясности намерений при вызове.

FILE_PERMISSIONS <permissions>...

Новое в версии 3.20.

Игнорировать права доступа входного файла и использовать указанные <permissions> для выходного файла вместо этого.

COPYONLY

Копировать файл без замены ссылок на переменные или другого содержимого. Этот параметр нельзя использовать с NEWLINE_STYLE.

ESCAPE_QUOTES

Экранировать любые подставленные кавычки обратными слешами (в стиле C).

@ONLY

Ограничить замену переменных ссылками вида @VAR@. Это полезно для настройки скриптов, использующих синтаксис ${VAR}.

NEWLINE_STYLE <style>

Указать стиль новой строки для выходного файла. Укажите UNIX или LF для \n новых строк, или укажите DOS, WIN32, или CRLF для \r\n новых строк. Этот параметр нельзя использовать с COPYONLY.

Пример

Рассмотрим дерево исходных файлов, содержащее файл foo.h.in:

#cmakedefine FOO_ENABLE
#cmakedefine FOO_STRING "@FOO_STRING@"

Соседний CMakeLists.txt может использовать configure_file для настройки заголовка:

option(FOO_ENABLE "Enable Foo" ON)
if(FOO_ENABLE)
  set(FOO_STRING "foo")
endif()
configure_file(foo.h.in foo.h @ONLY)

Это создаёт foo.h в директории сборки, соответствующей этой директории исходных файлов. Если включён параметр FOO_ENABLE, сконфигурированный файл будет содержать:

#define FOO_ENABLE
#define FOO_STRING "foo"

В противном случае он будет содержать:

/* #undef FOO_ENABLE */
/* #undef FOO_STRING */

Затем можно использовать команду include_directories() для указания выходной директории в качестве директории включения:

include_directories(${CMAKE_CURRENT_BINARY_DIR})

чтобы исходные файлы могли включать заголовок как #include <foo.h>.