macro

Начало записи макроса для последующего вызова в качестве команды

macro(<name> [<arg1> ...])
  <commands>
endmacro()

Определяет макрос с именем <name>, принимающий аргументы с именами <arg1>, ... Команды, перечисленные после макроса, но перед соответствующим endmacro(), не выполняются, пока макрос не будет вызван.

В соответствии со старыми правилами команда endmacro() допускает необязательный <name> аргумент. Если он используется, он должен быть точным повторением аргумента открывающей команды macro.

См. документацию команды cmake_policy() для поведения политик внутри макросов.

См. раздел Макрос против функции ниже для различий между макросами CMake и functions.

Вызов

Вызов макроса нечувствителен к регистру. Макрос, определенный как

macro(foo)
  <commands>
endmacro()

может быть вызван с помощью любого из

foo()
Foo()
FOO()
cmake_language(CALL foo)

и так далее. Однако настоятельно рекомендуется придерживаться регистра, выбранного при определении макроса. Обычно макросы используют имена в нижнем регистре.

Аргументы

При вызове макроса команды, записанные в макросе, сначала модифицируются заменой формальных параметров (${arg1}, ...) на переданные аргументы, а затем вызываются как обычные команды.

В дополнение к ссылке на формальные параметры вы можете ссылаться на значения ${ARGC}, которые будут установлены в число переданных аргументов, а также ${ARGV0}, ${ARGV1}, ${ARGV2}, ... которые будут содержать фактические значения переданных аргументов. Это облегчает создание макросов с необязательными аргументами.

Кроме того, ${ARGV} содержит список всех аргументов, переданных макросу, а ${ARGN} содержит список аргументов, которые идут после последнего ожидаемого аргумента. Обращение к ${ARGV#} аргументам, выходящим за пределы ${ARGC}, имеет неопределенное поведение. Проверка того, что ${ARGC} больше #, является единственным способом гарантировать, что ${ARGV#} был передан функции в качестве дополнительного аргумента.

Макрос против функции

Команда macro очень похожа на команду function(). Тем не менее, есть несколько важных различий.

В функции ARGN, ARGC, ARGV и ARGV0, ARGV1, ... являются истинными переменными в обычном смысле CMake. В макросе они таковыми не являются, они представляют собой строковые замены, аналогичные тем, которые выполняет препроцессор C с макросом. Это имеет ряд последствий, как объясняется в разделе Особые случаи аргументов ниже.

Другое различие между макросами и функциями заключается в управлении потоком. Функция выполняется путем передачи управления от вызывающей инструкции к телу функции. Макрос выполняется так, как будто тело макроса вставлено вместо вызывающей инструкции. Это приводит к тому, что return() в теле макроса не просто завершает выполнение макроса; скорее, управление возвращается из области вызова макроса. Для избежания путаницы рекомендуется избегать использования return() в макросах вообще.

В отличие от функции, переменные CMAKE_CURRENT_FUNCTION, CMAKE_CURRENT_FUNCTION_LIST_DIR, CMAKE_CURRENT_FUNCTION_LIST_FILE, CMAKE_CURRENT_FUNCTION_LIST_LINE для макроса не устанавливаются.

Особые случаи аргументов

Поскольку ARGN, ARGC, ARGV, ARGV0 и т.д. не являются переменными, вы НЕ сможете использовать команды, такие как

if(ARGV1) # ARGV1 is not a variable
if(DEFINED ARGV2) # ARGV2 is not a variable
if(ARGC GREATER 2) # ARGC is not a variable
foreach(loop_var IN LISTS ARGN) # ARGN is not a variable

В первом случае вы можете использовать if(${ARGV1}). Во втором и третьем случае правильный способ проверки того, был ли необязательный аргумент передан макросу, - использовать if(${ARGC} GREATER 2). В последнем случае вы можете использовать foreach(loop_var ${ARGN}), но это пропустит пустые аргументы. Если вам нужно их включить, вы можете использовать

set(list_var "${ARGN}")
foreach(loop_var IN LISTS list_var)

Обратите внимание, что если у вас есть переменная с таким же именем в области видимости, из которой вызывается макрос, использование неиспользуемых имен приведет к использованию существующей переменной вместо аргументов. Например:

macro(bar)
  foreach(arg IN LISTS ARGN)
    <commands>
  endforeach()
endmacro()

function(foo)
  bar(x y z)
endfunction()

foo(a b c)

Будет перебирать a;b;c, а не x;y;z, как можно было ожидать. Если вам нужны истинные переменные CMake и/или лучшее управление областью видимости CMake, обратите внимание на команду function.

См. также

• cmake_parse_arguments()
• endmacro()