Руководство по импорту и экспорту

• Введение

• Импорт целевых объектов

  • Импорт исполняемых файлов
  • Импорт библиотек

• Экспорт целевых объектов

  • Создание пакетов

    • Создание файла конфигурации пакета
    • Создание файла версии пакета
  • Экспорт целевых объектов из дерева сборки
  • Сборка и установка пакета
• Создание переносимых пакетов
• Использование файла конфигурации пакета
• Добавление компонентов

Введение

В этом руководстве мы представим концепцию целевых объектов IMPORTED и продемонстрируем, как импортировать существующие исполняемые файлы или библиотеки с диска в проект CMake. Затем мы покажем, как CMake поддерживает экспорт целевых объектов из одного проекта, основанного на CMake, и их импорт в другой. Наконец, мы продемонстрируем, как упаковать проект с файлом конфигурации для простоты интеграции в другие проекты CMake. Это руководство и полный пример исходного кода можно найти в каталоге Help/guide/importing-exporting дерева исходного кода CMake.

Импорт целевых объектов

Целевые объекты IMPORTED используются для преобразования файлов за пределами проекта CMake в логические целевые объекты внутри проекта. Целевые объекты IMPORTED создаются с помощью параметра IMPORTED команд add_executable() и add_library(). Для целевых объектов IMPORTED файлы сборки не генерируются. После импорта целевые объекты IMPORTED могут быть использованы как любые другие целевые объекты в проекте и предоставляют удобную и гибкую ссылку на внешние исполняемые файлы и библиотеки.

По умолчанию имя целевого объекта IMPORTED имеет область действия в каталоге, в котором он создан, и ниже. Мы можем использовать параметр GLOBAL для расширения области видимости, чтобы целевой объект был доступен глобально в системе сборки.

Подробности о целевом объекте IMPORTED задаются установкой свойств, имена которых начинаются с IMPORTED_ и INTERFACE_. Например, IMPORTED_LOCATION содержит полный путь к целевому объекту на диске.

Импорт исполняемых файлов

Для начала мы рассмотрим простой пример, который создаёт целевой объект IMPORTED исполняемого файла, а затем ссылается на него из команды add_custom_command().

Для начала нам нужно выполнить некоторую настройку. Мы хотим создать исполняемый файл, который при запуске создаёт базовый файл main.cc в текущем каталоге. Подробности этого проекта не важны. Перейдите в Help/guide/importing-exporting/MyExe, создайте каталог сборки, запустите cmake и выполните сборку и установку проекта.

$ cd Help/guide/importing-exporting/MyExe
$ mkdir build
$ cd build
$ cmake ..
$ cmake --build .
$ cmake --install . --prefix <install location>
$ <install location>/myexe
$ ls
[...] main.cc [...]

Теперь мы можем импортировать этот исполняемый файл в другой проект CMake. Исходный код этого раздела доступен в Help/guide/importing-exporting/Importing. В файле CMakeLists используйте команду add_executable() для создания нового целевого объекта, называемого myexe. Используйте параметр IMPORTED чтобы указать CMake, что этот целевой объект ссылается на исполняемый файл, расположенный за пределами проекта. Правила построения не будут генерироваться, и свойство целевого объекта IMPORTED будет установлено в значение true.

add_executable(myexe IMPORTED)

Далее, установите свойство IMPORTED_LOCATION целевого объекта, используя команду set_property(). Это укажет CMake на расположение целевого объекта на диске. Расположение может потребовать корректировки до <install location> указанного на предыдущем шаге.

set_property(TARGET myexe PROPERTY
             IMPORTED_LOCATION "../InstallMyExe/bin/myexe")

Теперь мы можем использовать этот целевой объект IMPORTED так же, как и любой другой целевой объект, созданный в рамках проекта. В данном случае предположим, что мы хотим использовать сгенерированный файл исходного кода в нашем проекте. Используйте целевой объект IMPORTED в команде add_custom_command():

add_custom_command(OUTPUT main.cc COMMAND myexe)

Поскольку COMMAND указывает имя целевого объекта исполняемого файла, оно будет автоматически заменено расположением исполняемого файла, указанным свойством IMPORTED_LOCATION выше.

Наконец, используйте результат из add_custom_command():

add_executable(mynewexe main.cc)

Импорт библиотек

Аналогичным образом, к библиотекам из других проектов можно получить доступ через целевые объекты IMPORTED.

Примечание: Полный исходный код для примеров в этом разделе не предоставляется и оставляется в качестве упражнения для читателя.

В файле CMakeLists добавьте библиотеку IMPORTED и укажите её расположение на диске:

add_library(foo STATIC IMPORTED)
set_property(TARGET foo PROPERTY
             IMPORTED_LOCATION "/path/to/libfoo.a")

Затем используйте библиотеку IMPORTED в нашем проекте:

add_executable(myexe src1.c src2.c)
target_link_libraries(myexe PRIVATE foo)

В Windows .dll и её .lib импортная библиотека могут быть импортированы вместе:

add_library(bar SHARED IMPORTED)
set_property(TARGET bar PROPERTY
             IMPORTED_LOCATION "c:/path/to/bar.dll")
set_property(TARGET bar PROPERTY
             IMPORTED_IMPLIB "c:/path/to/bar.lib")
add_executable(myexe src1.c src2.c)
target_link_libraries(myexe PRIVATE bar)

Библиотека с несколькими конфигурациями может быть импортирована с помощью одного целевого объекта:

find_library(math_REL NAMES m)
find_library(math_DBG NAMES md)
add_library(math STATIC IMPORTED GLOBAL)
set_target_properties(math PROPERTIES
  IMPORTED_LOCATION "${math_REL}"
  IMPORTED_LOCATION_DEBUG "${math_DBG}"
  IMPORTED_CONFIGURATIONS "RELEASE;DEBUG"
)
add_executable(myexe src1.c src2.c)
target_link_libraries(myexe PRIVATE math)

Сгенерированная система сборки будет связывать myexe с m.lib при сборке в конфигурации release и md.lib при сборке в конфигурации debug.

Экспорт целевых объектов

Хотя целевые объекты IMPORTED сами по себе полезны, они всё ещё требуют, чтобы проект, который их импортирует, знал расположение файлов целевых объектов на диске. Настоящая сила целевых объектов IMPORTED заключается в том, что проект, предоставляющий файлы целевых объектов, также предоставляет файл CMake, помогающий их импортировать. Проект может быть настроен на производство необходимой информации, чтобы его легко могли использовать другие проекты CMake, будь то из каталога сборки, локальной установки или при упаковке.

В оставшихся разделах мы пройдём по ряду примеров проектов поэтапно. Первый проект создаст и установит библиотеку и соответствующие файлы конфигурации и пакета. Второй проект будет использовать сгенерированный пакет.

Давайте начнём с проекта MathFunctions в каталоге Help/guide/importing-exporting/MathFunctions. Здесь у нас есть заголовочный файл MathFunctions.h, который объявляет функцию sqrt.

#pragma once

namespace MathFunctions {
double sqrt(double x);
}

И соответствующий файл исходного кода MathFunctions.cxx:

#include "MathFunctions.h"

#include <cmath>

namespace MathFunctions {
double sqrt(double x)
{
  return std::sqrt(x);
}
}

Не стоит слишком подробно рассматривать особенности файлов C++, они предназначены только для того, чтобы быть простым примером, который будет компилироваться и выполняться на многих системах сборки.

Теперь мы можем создать файл CMakeLists.txt для проекта CMakeLists.txt проекта MathFunctions. Начните с указания версии cmake_minimum_required() и имени проекта project():

cmake_minimum_required(VERSION 3.15)
project(MathFunctions)

# make cache variables for install destinations
include(GNUInstallDirs)

# specify the C++ standard
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED True)

Модуль GNUInstallDirs включён для предоставления проекту гибкости при установке в различные макеты платформ, сделав каталоги доступными в качестве переменных кэша.

Создайте библиотеку, названную MathFunctions с помощью команды add_library():

add_library(MathFunctions STATIC MathFunctions.cxx)

Затем используйте команду target_include_directories() для указания каталогов заголовочных файлов для целевого объекта:

target_include_directories(MathFunctions
                           PUBLIC
                           "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
                           "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
)

Мы должны сообщить CMake, что хотим использовать разные каталоги заголовочных файлов в зависимости от того, собираем ли мы библиотеку или используем её из установленного места. Если этого не сделать, при создании информации об экспорте CMake экспортирует путь, специфичный для текущей директории сборки, и он не будет действительным для других проектов. Мы можем использовать generator expressions, чтобы указать, что при сборке библиотеки следует использовать текущую директорию исходных кодов. В противном случае, при установке, используйте каталог include. Более подробную информацию см. в разделе «Создание переносимых пакетов».

Команды install(TARGETS) и install(EXPORT) работают вместе, чтобы установить как целевые объекты (в нашем случае библиотеку), так и файл CMake, предназначенный для облегчения импорта целевых объектов в другой проект CMake.

Сначала в команде install(TARGETS) мы укажем целевой объект, имя EXPORT и место назначения, указывающие CMake, где установить целевые объекты.

install(TARGETS MathFunctions
        EXPORT MathFunctionsTargets
        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
        INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)

Здесь опция EXPORT сообщает CMake о создании экспорта под названием MathFunctionsTargets. Сгенерированные целевые объекты IMPORTED имеют соответствующие свойства, определяющие их требования к использованию, такие как INTERFACE_INCLUDE_DIRECTORIES, INTERFACE_COMPILE_DEFINITIONS и другие релевантные встроенные свойства INTERFACE_. Вариант INTERFACE пользовательских свойств, перечисленных в COMPATIBLE_INTERFACE_STRING и других Свойства совместимого интерфейса, также передаются сгенерированным целевым объектам IMPORTED. Например, в данном случае целевой объект IMPORTED будет иметь свойство INTERFACE_INCLUDE_DIRECTORIES, заполненное директорией, указанной свойством INCLUDES DESTINATION. Поскольку был указан относительный путь, он рассматривается как относительный к CMAKE_INSTALL_PREFIX.

Обратите внимание, что мы не попросили CMake установить экспорт.

Мы не должны забыть установить заголовочный файл MathFunctions.h с помощью команды install(FILES). Заголовочный файл должен быть установлен в каталог include, как указано в команде target_include_directories() выше.

install(FILES MathFunctions.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

Теперь, когда библиотека MathFunctions и заголовочный файл установлены, нам также нужно явно установить детали экспорта MathFunctionsTargets. Используйте команду install(EXPORT) для экспорта целевых объектов в MathFunctionsTargets, как определено командой install(TARGETS).

install(EXPORT MathFunctionsTargets
        FILE MathFunctionsTargets.cmake
        NAMESPACE MathFunctions::
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/MathFunctions
)

Эта команда генерирует файл MathFunctionsTargets.cmake и организует его установку в lib/cmake. Файл содержит код, пригодный для использования последующими этапами, для импорта всех целевых объектов, перечисленных в команде установки, из дерева установки.

Опция NAMESPACE добавит префикс MathFunctions:: к именам целевых объектов при их записи в файл экспорта. Эта конвенция с двойными двоеточиями даёт CMake подсказку, что имя является целевым объектом IMPORTED, когда он используется проектами-последователями. Таким образом, CMake может выдать сообщение об ошибке, если пакет, его предоставляющий, не найден.

Сгенерированный файл экспорта содержит код, создающий библиотеку IMPORTED.

# Create imported target MathFunctions::MathFunctions
add_library(MathFunctions::MathFunctions STATIC IMPORTED)

set_target_properties(MathFunctions::MathFunctions PROPERTIES
  INTERFACE_INCLUDE_DIRECTORIES "${_IMPORT_PREFIX}/include"
)

Этот код очень похож на пример, который мы создали вручную в разделе «Импорт библиотек». Обратите внимание, что ${_IMPORT_PREFIX} вычисляется относительно расположения файла.

Внешний проект может загрузить этот файл с помощью команды include() и использовать библиотеку MathFunctions из дерева установки, как будто она была скомпилирована в своём собственном дереве. Например:

1 include(${INSTALL_PREFIX}/lib/cmake/MathFunctionTargets.cmake)
2 add_executable(myexe src1.c src2.c )
3 target_link_libraries(myexe PRIVATE MathFunctions::MathFunctions)

Строка 1 загружает целевой файл CMake. Хотя мы экспортировали только один целевой объект, этот файл может импортировать любое количество целевых объектов. Их расположение вычисляется относительно местоположения файла, чтобы дерево установки можно было легко перемещать. Строка 3 ссылается на импортированную библиотеку MathFunctions. Результирующая система сборки будет ссылаться на библиотеку из её установленного места.

Исполняемые файлы также могут быть экспортированы и импортированы с помощью того же процесса.

Любое количество установок целевых объектов может быть связано с одним и тем же именем экспорта. Имена экспорта считаются глобальными, поэтому любой каталог может внести вклад в установку целевого объекта. Команда install(EXPORT) должна быть вызвана только один раз для установки файла, который ссылается на все целевые объекты. Ниже приведён пример того, как несколько экспортов можно объединить в один файл экспорта, даже если они находятся в разных подкаталогах проекта.

# A/CMakeLists.txt
add_executable(myexe src1.c)
install(TARGETS myexe DESTINATION lib/myproj
        EXPORT myproj-targets)

# B/CMakeLists.txt
add_library(foo STATIC foo1.c)
install(TARGETS foo DESTINATION lib EXPORTS myproj-targets)

# Top CMakeLists.txt
add_subdirectory (A)
add_subdirectory (B)
install(EXPORT myproj-targets DESTINATION lib/myproj)

Создание пакетов

На данном этапе проект MathFunctions экспортирует информацию о целевых объектах, необходимую для использования другими проектами. Мы можем сделать этот проект ещё более удобным для использования другими проектами, сгенерировав файл конфигурации, чтобы команда CMake find_package() могла найти наш проект.

Для начала нам необходимо внести несколько дополнений в файл CMakeLists.txt. Во-первых, включите модуль CMakePackageConfigHelpers для доступа к некоторым вспомогательным функциям по созданию файлов конфигурации.

include(CMakePackageConfigHelpers)

Затем мы создадим файл конфигурации пакета и файл версии пакета.

Создание файла конфигурации пакета

Используйте команду configure_package_config_file(), предоставленную модулем CMakePackageConfigHelpers, для генерации файла конфигурации пакета. Обратите внимание, что эту команду следует использовать вместо простой команды configure_file(). Это помогает гарантировать, что полученный пакет будет переносимым, избегая жёстко закодированных путей в установленном файле конфигурации. Путь, заданный для INSTALL_DESTINATION, должен быть местом назначения, куда будет установлен файл MathFunctionsConfig.cmake. В следующем разделе мы рассмотрим содержимое файла конфигурации пакета.

configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/Config.cmake.in
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake"
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/MathFunctions
)

Установите сгенерированные файлы конфигурации с помощью команды INSTALL(files). Файлы MathFunctionsConfigVersion.cmake и MathFunctionsConfig.cmake устанавливаются в одно и то же место, завершая создание пакета.

install(FILES
          "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake"
          "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake"
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/MathFunctions
)

Теперь нам нужно создать сам файл конфигурации пакета. В этом случае файл Config.cmake.in очень простой, но достаточно для того, чтобы позволить последующим проектам использовать целевые объекты IMPORTED.

@PACKAGE_INIT@

include("${CMAKE_CURRENT_LIST_DIR}/MathFunctionsTargets.cmake")

check_required_components(MathFunctions)

Первая строка файла содержит только строку @PACKAGE_INIT@. Она расширяется при конфигурировании файла и позволяет использовать переносимые пути, предваряемые PACKAGE_. Она также предоставляет макросы set_and_check() и check_required_components().

Макрос check_required_components помогает убедиться, что все запрошенные, не-необязательные компоненты найдены, проверяя переменные <Package>_<Component>_FOUND для всех необходимых компонентов. Этот макрос следует вызывать в конце файла конфигурации пакета, даже если у пакета нет компонентов. Таким образом, CMake может убедиться, что проект ниже по иерархии не указал какие-либо несуществующие компоненты. Если check_required_components завершится неудачно, переменная <Package>_FOUND устанавливается в FALSE, и пакет считается не найденным.

Макрос set_and_check() следует использовать в файлах конфигурации вместо обычной команды set() для установки каталогов и расположения файлов. Если ссылаемый файл или каталог не существует, макрос завершится ошибкой.

Если пакет MathFunctions должен предоставлять какие-либо макросы, они должны быть в отдельном файле, установленным в том же месте, что и файл MathFunctionsConfig.cmake, и включаться оттуда.

Все необходимые зависимости пакета также должны быть найдены в файле конфигурации пакета. Предположим, что нам нужен библиотека Stats в нашем проекте. В файле CMakeLists мы добавим:

find_package(Stats 2.6.4 REQUIRED)
target_link_libraries(MathFunctions PUBLIC Stats::Types)

Так как целевой объект Stats::Types является зависимостью MathFunctions, проекты ниже по иерархии также должны найти пакет Stats и связаться с библиотекой Stats::Types. Пакет Stats должен быть найден в файле конфигурации для обеспечения этого.

include(CMakeFindDependencyMacro)
find_dependency(Stats 2.6.4)

Макрос find_dependency из модуля CMakeFindDependencyMacro помогает, распространяя информацию о том, является ли пакет REQUIRED, или QUIET, и т.д. Макрос find_dependency также устанавливает MathFunctions_FOUND в значение False, если зависимость не найдена, вместе с сообщением об ошибке, что пакет MathFunctions не может быть использован без пакета Stats.

Упражнение: Добавьте необходимую библиотеку в проект %%%CODE_BLOCK_163%%.

Создание файла версии пакета

Модуль CMakePackageConfigHelpers предоставляет команду write_basic_package_version_file() для создания простого файла версии пакета. Этот файл читается CMake при вызове find_package() для определения совместимости с запрошенной версией и установки некоторых версионно-зависимых переменных, таких как <PackageName>_VERSION, <PackageName>_VERSION_MAJOR, <PackageName>_VERSION_MINOR, и т.д. См. документацию cmake-packages для получения дополнительной информации.

set(version 3.4.1)

set_property(TARGET MathFunctions PROPERTY VERSION ${version})
set_property(TARGET MathFunctions PROPERTY SOVERSION 3)
set_property(TARGET MathFunctions PROPERTY
  INTERFACE_MathFunctions_MAJOR_VERSION 3)
set_property(TARGET MathFunctions APPEND PROPERTY
  COMPATIBLE_INTERFACE_STRING MathFunctions_MAJOR_VERSION
)

# generate the version file for the config file
write_basic_package_version_file(
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake"
  VERSION "${version}"
  COMPATIBILITY AnyNewerVersion
)

В нашем примере MathFunctions_MAJOR_VERSION определена как COMPATIBLE_INTERFACE_STRING, что означает, что она должна быть совместима среди зависимостей любого зависимого проекта. Установив эту пользовательскую собственность в данной версии и следующей версии MathFunctions, cmake выведет диагностическое сообщение, если будет попытка использования версии 3 вместе с версией 4. Пакеты могут выбрать использование такой схемы, если различные главные версии пакета разработаны для несовместимости.

Экспорт целевых объектов из дерева сборки

Обычно проекты собираются и устанавливаются перед использованием внешними проектами. Однако в некоторых случаях желательно экспортировать целевые объекты непосредственно из дерева сборки. Эти целевые объекты могут затем использоваться внешним проектом, ссылающимся на дерево сборки без участия установки. Команда export() используется для генерации файла, экспортирующего целевые объекты из дерева сборки проекта.

Если мы хотим, чтобы наш пример проекта также использовался из директории сборки, нам нужно только добавить следующее в CMakeLists.txt:

export(EXPORT MathFunctionsTargets
       FILE "${CMAKE_CURRENT_BINARY_DIR}/cmake/MathFunctionsTargets.cmake"
       NAMESPACE MathFunctions::
)

Здесь мы используем команду export() для генерации экспортируемых целевых объектов для дерева сборки. В этом случае мы создадим файл под названием MathFunctionsTargets.cmake в подкаталоге cmake директории сборки. Сгенерированный файл содержит необходимый код для импорта целевого объекта и может быть загружен внешним проектом, знающим о дереве сборки проекта. Этот файл специфичен для дерева сборки и не переносимый.

Можно создать подходящий файл конфигурации пакета и файл версии пакета для определения пакета для дерева сборки, который может использоваться без установки. Потребители дерева сборки могут просто убедиться, что CMAKE_PREFIX_PATH содержит директорию сборки или установить MathFunctions_DIR на <build_dir>/MathFunctions в кэше.

Пример применения этой функции — создание исполняемого файла на платформе хоста при кросс-компиляции. Проект, содержащий исполняемый файл, может быть собран на платформе хоста, а затем проект, который компилируется для другой платформы, может загрузить его.

Сборка и установка пакета

На этом этапе мы сгенерировали переносимую CMake конфигурацию для нашего проекта, которую можно использовать после установки проекта. Давайте попробуем собрать проект MathFunctions:

mkdir MathFunctions_build
cd MathFunctions_build
cmake ../MathFunctions
cmake --build .

В директории сборки обратите внимание, что файл MathFunctionsTargets.cmake был создан в подкаталоге cmake.

Теперь установим проект:

$ cmake --install . --prefix "/home/myuser/installdir"

Создание переносимых пакетов

Пакеты, созданные командой install(EXPORT), предназначены для переноса, используя пути, относительные к расположению самого пакета. Они не должны ссылаться на абсолютные пути к файлам на машине, где пакет был собран, которые не будут существовать на машинах, где пакет может быть установлен.

При определении интерфейса целевого объекта для EXPORT, помните, что каталоги включаемых файлов должны быть указаны как относительные пути к CMAKE_INSTALL_PREFIX, но не должны явно включать CMAKE_INSTALL_PREFIX:

target_include_directories(tgt INTERFACE
  # Wrong, not relocatable:
  $<INSTALL_INTERFACE:${CMAKE_INSTALL_PREFIX}/include/TgtName>
)

target_include_directories(tgt INTERFACE
  # Ok, relocatable:
  $<INSTALL_INTERFACE:include/TgtName>
)

Выражение генератора $<INSTALL_PREFIX> может использоваться в качестве заглушки для префикса установки без создания непереносимого пакета. Это необходимо, если используются сложные выражения генератора:

target_include_directories(tgt INTERFACE
  # Ok, relocatable:
  $<INSTALL_INTERFACE:$<INSTALL_PREFIX>/include/TgtName>
)

Это также относится к путям, ссылающимся на внешние зависимости. Не рекомендуется заполнять свойства, которые могут содержать пути, такие как INTERFACE_INCLUDE_DIRECTORIES или INTERFACE_LINK_LIBRARIES, путями, относящимися к зависимостям. Например, данный код может не работать корректно для переносимого пакета:

target_link_libraries(MathFunctions INTERFACE
  ${Foo_LIBRARIES} ${Bar_LIBRARIES}
  )
target_include_directories(MathFunctions INTERFACE
  "$<INSTALL_INTERFACE:${Foo_INCLUDE_DIRS};${Bar_INCLUDE_DIRS}>"
  )

Ссылка на переменные может содержать абсолютные пути к библиотекам и каталогам включенных файлов так, как они были найдены на машине, на которой был создан пакет. Это создаст пакет с жёстко запрограммированными путями к зависимостям, непригодными для переноса.

В идеале такие зависимости следует использовать через собственные IMPORTED целевые объекты, у которых есть свойство IMPORTED_LOCATION и свойства, определяющие требования к использованию, такие как INTERFACE_INCLUDE_DIRECTORIES, заполненные должным образом. Эти импортированные целевые объекты затем могут быть использованы с командой target_link_libraries() для MathFunctions:

target_link_libraries(MathFunctions INTERFACE Foo::Foo Bar::Bar)

С этим подходом пакет ссылается на свои внешние зависимости только по именам IMPORTED целевых объектов. Когда пользователь использует установленный пакет, пользователь выполнит соответствующие команды find_package() (через макрос find_dependency описанный выше), чтобы найти зависимости и заполнить импортированные целевые объекты соответствующими путями на своей собственной машине.

Использование файла конфигурации пакета

Теперь мы готовы создать проект для использования установленной библиотеки MathFunctions. В этом разделе мы будем использовать исходный код из Help\guide\importing-exporting\Downstream. В этой директории есть исходный файл main.cc, который использует библиотеку MathFunctions для вычисления квадратного корня заданного числа, а затем выводит результаты:

// A simple program that outputs the square root of a number
#include <iostream>
#include <string>

#include "MathFunctions.h"

int main(int argc, char* argv[])
{
  if (argc < 2) {
    std::cout << "Usage: " << argv[0] << " number" << std::endl;
    return 1;
  }

  // convert input to double
  const double inputValue = std::stod(argv[1]);

  // calculate square root
  const double sqrt = MathFunctions::sqrt(inputValue);
  std::cout << "The square root of " << inputValue << " is " << sqrt
            << std::endl;

  return 0;
}

Как и раньше, мы начнём с команд cmake_minimum_required() и project() в файле CMakeLists.txt. Для этого проекта мы также укажем стандарт C++.

cmake_minimum_required(VERSION 3.15)
project(Downstream)

# specify the C++ standard
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED True)

Мы можем использовать команду find_package():

find_package(MathFunctions 3.4.1 EXACT)

Создайте исполняемый файл:

add_executable(myexe main.cc)

И установите ссылку на библиотеку MathFunctions:

target_link_libraries(myexe PRIVATE MathFunctions::MathFunctions)

Всё готово! Теперь давайте попробуем собрать проект Downstream.

mkdir Downstream_build
cd Downstream_build
cmake ../Downstream
cmake --build .

Во время настройки CMake могла появиться ошибка:

CMake Warning at CMakeLists.txt:4 (find_package):
  By not providing "FindMathFunctions.cmake" in CMAKE_MODULE_PATH this
  project has asked CMake to find a package configuration file provided by
  "MathFunctions", but CMake did not find one.

  Could not find a package configuration file provided by "MathFunctions"
  with any of the following names:

    MathFunctionsConfig.cmake
    mathfunctions-config.cmake

  Add the installation prefix of "MathFunctions" to CMAKE_PREFIX_PATH or set
  "MathFunctions_DIR" to a directory containing one of the above files.  If
  "MathFunctions" provides a separate development package or SDK, be sure it
  has been installed.

Установите CMAKE_PREFIX_PATH в папку, где ранее была установлена MathFunctions, и попробуйте снова. Убедитесь, что созданный исполняемый файл работает как ожидается.

Добавление компонентов

Давайте изменим проект MathFunctions для использования компонентов. Исходный код для этого раздела находится в Help\guide\importing-exporting\MathFunctionsComponents. Файл CMakeLists для этого проекта добавляет две подпапки: Addition и SquareRoot.

cmake_minimum_required(VERSION 3.15)
project(MathFunctionsComponents)

# make cache variables for install destinations
include(GNUInstallDirs)

# specify the C++ standard
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED True)

add_subdirectory(Addition)
add_subdirectory(SquareRoot)

Сгенерируйте и установите файлы конфигурации пакета и версии пакета:

include(CMakePackageConfigHelpers)

# set version
set(version 3.4.1)

# generate the version file for the config file
write_basic_package_version_file(
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake"
  VERSION "${version}"
  COMPATIBILITY AnyNewerVersion
)

# create config file
configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/Config.cmake.in
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake"
  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/MathFunctions
  NO_CHECK_REQUIRED_COMPONENTS_MACRO
)

# install config files
install(FILES
          "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake"
          "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake"
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/MathFunctions
)

Если COMPONENTS указаны при использовании find_package() в зависимостях, они перечисляются в переменной <PackageName>_FIND_COMPONENTS. Мы можем использовать эту переменную для проверки, что все необходимые целевые компоненты включены в Config.cmake.in. В то же время, эта функция будет работать как пользовательская макрос check_required_components, чтобы убедиться, что зависимость пытается использовать только поддерживаемые компоненты.

@PACKAGE_INIT@

set(_MathFunctions_supported_components Addition SquareRoot)

foreach(_comp ${MathFunctions_FIND_COMPONENTS})
  if (NOT _comp IN_LIST _MathFunctions_supported_components)
    set(MathFunctions_FOUND False)
    set(MathFunctions_NOT_FOUND_MESSAGE "Unsupported component: ${_comp}")
  endif()
  include("${CMAKE_CURRENT_LIST_DIR}/MathFunctions${_comp}Targets.cmake")
endforeach()

Здесь MathFunctions_NOT_FOUND_MESSAGE установлено в значение, указывающее, что пакет не найден из-за указанного неверного компонента. Эта переменная сообщения может быть установлена для любого случая, когда переменная _FOUND установлена в False, и будет отображена пользователю.

Директории Addition и SquareRoot аналогичны. Давайте посмотрим на один из файлов CMakeLists:

# create library
add_library(SquareRoot STATIC SquareRoot.cxx)

add_library(MathFunctions::SquareRoot ALIAS SquareRoot)

# add include directories
target_include_directories(SquareRoot
                           PUBLIC
                           "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
                           "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"
)

# install the target and create export-set
install(TARGETS SquareRoot
        EXPORT SquareRootTargets
        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
        INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
)

# install header file
install(FILES SquareRoot.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})

# generate and install export file
install(EXPORT SquareRootTargets
        FILE MathFunctionsSquareRootTargets.cmake
        NAMESPACE MathFunctions::
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/MathFunctions
)

Теперь мы можем собрать проект, как описано в предыдущих разделах. Чтобы протестировать использование этого пакета, мы можем использовать проект в Help\guide\importing-exporting\DownstreamComponents. Есть два отличия от предыдущего проекта Downstream. Во-первых, нам нужно найти компоненты пакета. Измените строку find_package со:

find_package(MathFunctions 3.4.1 EXACT)

На:

find_package(MathFunctions 3.4 COMPONENTS Addition SquareRoot)

и строку target_link_libraries со:

target_link_libraries(myexe PRIVATE MathFunctions::MathFunctions)

На:

target_link_libraries(myexe PRIVATE MathFunctions::Addition MathFunctions::SquareRoot)

В main.cc, замените #include MathFunctions.h на:

#include "Addition.h"
#include "SquareRoot.h"

Наконец, используйте библиотеку Addition:

  const double sum = MathFunctions::add(inputValue, inputValue);
  std::cout << inputValue << " + " << inputValue << " = " << sum << std::endl;

Соберите проект Downstream и убедитесь, что он может найти и использовать компоненты пакета.