Spec-Zone.ru › CMake 3.26

cmake-qt(7)

  • Введение

  • Инструменты построения Qt

    • AUTOMOC
    • AUTOUIC
    • AUTORCC
  • Целевой <ORIGIN>_autogen
  • Генераторы Visual Studio
  • qtmain.lib в Windows

Введение

CMake может находить и использовать библиотеки Qt 4 и Qt 5. Библиотеки Qt 4 находятся с помощью модуля поиска FindQt4, поставляемого с CMake, в то время как библиотеки Qt 5 находятся с помощью «Пакеты файлов конфигурации», поставляемого с Qt 5. Дополнительную информацию о пакетах CMake можно найти в cmake-packages(7), а руководство по CMake для Qt — в руководстве Qt по CMake для вашей версии Qt.

Qt 4 и Qt 5 можно использовать вместе в той же системе CMake buildsystem:

cmake_minimum_required(VERSION 3.8.0 FATAL_ERROR)

project(Qt4And5)

set(CMAKE_AUTOMOC ON)

find_package(Qt5 COMPONENTS Widgets DBus REQUIRED)
add_executable(publisher publisher.cpp)
target_link_libraries(publisher Qt5::Widgets Qt5::DBus)

find_package(Qt4 REQUIRED)
add_executable(subscriber subscriber.cpp)
target_link_libraries(subscriber Qt4::QtGui Qt4::QtDBus)

Целевой CMake не может связываться одновременно с Qt 4 и Qt 5. При попытке или в результате транзитивного анализа зависимостей целевых объектов выдается диагностическое сообщение.

Инструменты построения Qt

Qt использует некоторые инструменты, включенные в пакет, для генерации кода, например moc для генерации метаобъектного кода, uic для построения и заполнения макета виджетов и rcc для генерации содержимого виртуальной файловой системы. Эти инструменты могут быть автоматически вызваны cmake(1), если соблюдены соответствующие условия. Автоматическое вызов инструментов может использоваться как с Qt 4, так и с Qt 5.

AUTOMOC

Свойство целевого объекта AUTOMOC контролирует, проверяет ли cmake(1) файлы C++ в целевом объекте, чтобы определить, требуется ли запуск moc, и создаёт правила для выполнения moc в нужное время.

Если макрос из AUTOMOC_MACRO_NAMES обнаружен в файле заголовка, moc будет выполнено для файла. Результат помещается в файл с именем, соответствующим moc_<basename>.cpp. Если макрос обнаружен в файле реализации C++, вывод moc помещается в файл с именем, соответствующим <basename>.moc, следуя соглашениям Qt. Файл <basename>.moc должен быть включён пользователем в файл реализации C++ с препроцессорной #include.

Включённые moc_*.cpp и *.moc файлы будут сгенерированы в каталоге <AUTOGEN_BUILD_DIR>/include, который автоматически добавляется в директории включения целевого объекта INCLUDE_DIRECTORIES.

  • Это отличается от CMake 3.7 и ниже; см. документацию для получения подробностей.
  • Для multi configuration generators каталог включений — <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
  • См. AUTOGEN_BUILD_DIR.

Не включённые moc_<basename>.cpp файлы будут сгенерированы в пользовательских папках, чтобы избежать коллизий имён, и включены в отдельный файл, который компилируется в целевой объект, с именем либо <AUTOGEN_BUILD_DIR>/mocs_compilation.cpp, либо <AUTOGEN_BUILD_DIR>/mocs_compilation_$<CONFIG>.cpp.

  • См. AUTOGEN_BUILD_DIR.

Команда moc использует свойства целевого объекта COMPILE_DEFINITIONS и INCLUDE_DIRECTORIES из целевого объекта, а также соответствующей конфигурации сборки.

Свойство целевого объекта AUTOMOC может быть предварительно установлено для всех последующих целевых объектов путём установки переменной CMAKE_AUTOMOC. Свойство целевого объекта AUTOMOC_MOC_OPTIONS может быть заполнено, чтобы установить параметры, передаваемые moc. Переменная CMAKE_AUTOMOC_MOC_OPTIONS может быть заполнена, чтобы предварительно установить параметры для всех последующих целевых объектов.

Дополнительные имена макросов для поиска могут быть добавлены в AUTOMOC_MACRO_NAMES.

Дополнительные имена зависимостей moc файлов могут быть извлечены из исходного кода с использованием AUTOMOC_DEPEND_FILTERS.

Исходные файлы C++ можно исключить из обработки AUTOMOC путём включения SKIP_AUTOMOC или более широкого SKIP_AUTOGEN.

AUTOUIC

Свойство целевого объекта AUTOUIC контролирует, проверяет ли cmake(1) файлы C++ в целевом объекте, чтобы определить, требуется ли запуск uic, и создаёт правила для выполнения uic в нужное время.

Если обнаружена препроцессорная #include директива, которая соответствует <path>ui_<basename>.h, и существует файл <basename>.ui, тогда uic будет выполнено для генерации соответствующего файла. Файл <basename>.ui ищется в следующих местах:

  1. <source_dir>/<basename>.ui
  2. <source_dir>/<path><basename>.ui
  3. <AUTOUIC_SEARCH_PATHS>/<basename>.ui
  4. <AUTOUIC_SEARCH_PATHS>/<path><basename>.ui

где <source_dir> — директория файла C++ и AUTOUIC_SEARCH_PATHS — список дополнительных путей поиска.

Сгенерированные файлы ui_*.h размещаются в директории <AUTOGEN_BUILD_DIR>/include, которая автоматически добавляется в директории включения целевого объекта INCLUDE_DIRECTORIES.

  • Это отличается от CMake 3.7 и ниже; см. документацию для получения подробностей.
  • Для multi configuration generators каталог включений — <AUTOGEN_BUILD_DIR>/include_<CONFIG>.
  • См. AUTOGEN_BUILD_DIR.

Свойство целевого объекта AUTOUIC может быть предварительно установлено для всех последующих целевых объектов путём установки переменной CMAKE_AUTOUIC. Свойство целевого объекта AUTOUIC_OPTIONS может быть заполнено, чтобы установить параметры, передаваемые uic. Переменная CMAKE_AUTOUIC_OPTIONS может быть заполнена, чтобы предварительно установить параметры для всех последующих целевых объектов. Свойство файла исходного кода AUTOUIC_OPTIONS может быть установлено для файла <basename>.ui, чтобы установить определённые параметры для файла. Это переопределяет параметры из свойства целевого объекта AUTOUIC_OPTIONS.

Целевой объект может заполнить свойство целевого объекта INTERFACE_AUTOUIC_OPTIONS параметрами, которые должны использоваться при вызове uic. Это должно соответствовать содержимому свойства целевого объекта AUTOUIC_OPTIONS зависимого целевого объекта. Переменная CMAKE_DEBUG_TARGET_PROPERTIES может использоваться для отслеживания исходного целевого объекта такого INTERFACE_AUTOUIC_OPTIONS. Это означает, что библиотека, предоставляющая альтернативную систему перевода для Qt, может указать параметры, которые должны использоваться при запуске uic. 

add_library(KI18n klocalizedstring.cpp)
target_link_libraries(KI18n Qt5::Core)

# KI18n uses the tr2i18n() function instead of tr().  That function is
# declared in the klocalizedstring.h header.
set(autouic_options
  -tr tr2i18n
  -include klocalizedstring.h
)

set_property(TARGET KI18n APPEND PROPERTY
  INTERFACE_AUTOUIC_OPTIONS ${autouic_options}
)

Проект, использующий целевой объект, экспортированный из upstream, автоматически использует соответствующие параметры при запуске uic с помощью AUTOUIC, в результате связывания с целевым объектом IMPORTED.

set(CMAKE_AUTOUIC ON)
# Uses a libwidget.ui file:
add_library(LibWidget libwidget.cpp)
target_link_libraries(LibWidget
  KF5::KI18n
  Qt5::Widgets
)

Файлы исходного кода могут быть исключены из обработки AUTOUIC путем включения SKIP_AUTOUIC или более широкого SKIP_AUTOGEN.

AUTORCC

Свойство целевого объекта AUTORCC управляет тем, создает ли cmake(1) правила для выполнения rcc в нужное время для файлов исходного кода с расширением .qrc.

add_executable(myexe main.cpp resource_file.qrc)

Свойство целевого объекта AUTORCC может быть предварительно установлено для всех последующих целевых объектов путем установки переменной CMAKE_AUTORCC. Свойство целевого объекта AUTORCC_OPTIONS может быть заполнено для установки параметров, которые необходимо передать rcc. Переменная CMAKE_AUTORCC_OPTIONS может быть заполнена для предварительной установки параметров для всех последующих целевых объектов. Свойство файла исходного кода AUTORCC_OPTIONS может быть установлено для файла <name>.qrc для установки конкретных параметров для файла. Это переопределяет параметры из свойства целевого объекта AUTORCC_OPTIONS.

Файлы исходного кода могут быть исключены из обработки AUTORCC путем включения SKIP_AUTORCC или более широкого SKIP_AUTOGEN.

Целевой объект <ORIGIN>_autogen

Инструменты moc и uic выполняются как часть синтезированного целевого объекта <ORIGIN>_autogen custom target, сгенерированного CMake. По умолчанию этот целевой объект <ORIGIN>_autogen наследует зависимости от целевого объекта <ORIGIN> (см. AUTOGEN_ORIGIN_DEPENDS). Зависимости целевых объектов могут быть добавлены к целевому объекту <ORIGIN>_autogen путем добавления их в свойство целевого объекта AUTOGEN_TARGET_DEPENDS.

Генераторы Visual Studio

При использовании генераторов Visual Studio generators, CMake генерирует PRE_BUILD custom command вместо <ORIGIN>_autogen custom target (для AUTOMOC и AUTOUIC). Однако это не всегда возможно, и используется <ORIGIN>_autogen custom target, когда

  • целевой объект <ORIGIN> зависит от файлов GENERATED, которые не исключены из обработки AUTOMOC и AUTOUIC с помощью SKIP_AUTOMOC, SKIP_AUTOUIC, SKIP_AUTOGEN или CMP0071
  • AUTOGEN_TARGET_DEPENDS перечисляет файл исходного кода
  • CMAKE_GLOBAL_AUTOGEN_TARGET включен

qtmain.lib в Windows

Целевые объекты Qt 4 и 5 IMPORTED для библиотек QtGui указывают, что статическая библиотека qtmain.lib, поставляемая с Qt, будет подключена ко всем зависимым исполняемым файлам, у которых включено свойство WIN32_EXECUTABLE.

Чтобы отключить это поведение, включите свойство целевого объекта Qt5_NO_LINK_QTMAIN для целевых объектов Qt 5 или свойство целевого объекта QT4_NO_LINK_QTMAIN для целевых объектов Qt 4.

add_executable(myexe WIN32 main.cpp)
target_link_libraries(myexe Qt4::QtGui)

add_executable(myexe_no_qtmain WIN32 main_no_qtmain.cpp)
set_property(TARGET main_no_qtmain PROPERTY QT4_NO_LINK_QTMAIN ON)
target_link_libraries(main_no_qtmain Qt4::QtGui)

© 2000–2023 Kitware, Inc. and Contributors
Licensed under the BSD 3-clause License.
https://cmake.org/cmake/help/v3.26/manual/cmake-qt.7.html

Spec-Zone.ru

Настройки Оффлайн Что нового Помощь О нас
Spec-Zone .ru
спецификации, руководства, описания, API