macro

Начать запись макроса для последующего вызова в качестве команды

macro(<name> [<arg1> ...])
  <commands>
endmacro()

Определяет макрос с именем <name>, который принимает аргументы с именами <arg1>, ... Команды, перечисленные после макроса, но перед соответствующим endmacro(), не будут выполнены до тех пор, пока макрос не будет вызван.

Согласно старой версии, команда endmacro() допускает необязательный <name> аргумент. Если он используется, он должен быть точной копией аргумента открывающей команды macro.

См. документацию команды cmake_policy() для поведения политик внутри макросов.

См. раздел Макрос против функции ниже для различий между макросами CMake и functions.

Вызов

Вызов макроса нечувствителен к регистру. Макрос, определенный как

macro(foo)
  <commands>
endmacro()

может быть вызван любым из

foo()
Foo()
FOO()
cmake_language(CALL foo)

и так далее. Однако настоятельно рекомендуется придерживаться регистра, выбранного при определении макроса. Обычно макросы используют имена в нижнем регистре.

Аргументы

Когда макрос вызывается, команды, записанные в макросе, сначала изменяются путем замены формальных параметров (${arg1}, ...) переданными аргументами, а затем вызываются как обычные команды.

Помимо ссылки на формальные параметры, можно ссылаться на значения ${ARGC}, которые будут установлены в число переданных в функцию аргументов, а также на ${ARGV0}, ${ARGV1}, ${ARGV2}, ... которые будут содержать фактические значения переданных аргументов. Это позволяет создавать макросы с необязательными аргументами.

Кроме того, ${ARGV} содержит список всех аргументов, переданных макросу, а ${ARGN} содержит список аргументов, следующих за последним ожидаемым аргументом. Ссылка на ${ARGV#} аргументы за пределами ${ARGC} имеют неопределенное поведение. Проверка того, что ${ARGC} больше #, является единственным способом гарантировать, что ${ARGV#} был передан функции как дополнительный аргумент.

Макрос против функции

Команда macro очень похожа на команду function(). Тем не менее, существуют некоторые важные различия.

В функции ARGN, ARGC, ARGV и ARGV0, ARGV1, ... являются истинными переменными в обычном смысле CMake. В макросе они таковыми не являются, они представляют собой строковые подстановки, подобные тому, как это делал бы препроцессор C с макросом. Это влечёт за собой ряд последствий, как объясняется в разделе Особенности аргументов ниже.

Другое различие между макросами и функциями заключается в потоке управления. Функция выполняется путем передачи управления от вызывающей инструкции к телу функции. Макрос выполняется как будто тело макроса вставлено вместо вызывающей инструкции. Это означает, что return() в теле макроса не просто прерывает выполнение макроса; вместо этого управление возвращается из области вызова макроса. Чтобы избежать путаницы, рекомендуется вообще избегать return() в макросах.

В отличие от функции, переменные CMAKE_CURRENT_FUNCTION, CMAKE_CURRENT_FUNCTION_LIST_DIR, CMAKE_CURRENT_FUNCTION_LIST_FILE, CMAKE_CURRENT_FUNCTION_LIST_LINE не устанавливаются для макроса.

Особенности аргументов

Поскольку ARGN, ARGC, ARGV, ARGV0 и т. д. не являются переменными, вы НЕ сможете использовать команды, такие как

if(ARGV1) # ARGV1 is not a variable
if(DEFINED ARGV2) # ARGV2 is not a variable
if(ARGC GREATER 2) # ARGC is not a variable
foreach(loop_var IN LISTS ARGN) # ARGN is not a variable

В первом случае можно использовать if(${ARGV1}). Во втором и третьем случаях правильный способ проверить, был ли необязательный аргумент передан макросу, — использовать if(${ARGC} GREATER 2). В последнем случае можно использовать foreach(loop_var ${ARGN}), но это пропустит пустые аргументы. Если вам нужно их включить, вы можете использовать

set(list_var "${ARGN}")
foreach(loop_var IN LISTS list_var)

Обратите внимание, что если у вас есть переменная с тем же именем в области, из которой вызывается макрос, использование неиспользуемых имён будет использовать существующую переменную вместо аргументов. Например:

macro(bar)
  foreach(arg IN LISTS ARGN)
    <commands>
  endforeach()
endmacro()

function(foo)
  bar(x y z)
endfunction()

foo(a b c)

Будет перебирать a;b;c а не x;y;z, как можно было бы ожидать. Если вам нужны истинные переменные CMake и/или лучший контроль области CMake, обратитесь к команде функции.

См. также

• cmake_parse_arguments()
• endmacro()