FindBoost

Поиск каталогов заголовков и библиотек Boost

Используйте этот модуль, вызвав find_package() в следующем формате:

find_package(Boost
  [version] [EXACT]      # Minimum or EXACT version e.g. 1.67.0
  [REQUIRED]             # Fail with error if Boost is not found
  [COMPONENTS <libs>...] # Boost libraries by their canonical name
                         # e.g. "date_time" for "libboost_date_time"
  [OPTIONAL_COMPONENTS <libs>...]
                         # Optional Boost libraries by their canonical name)
  )                      # e.g. "date_time" for "libboost_date_time"

Этот модуль находит заголовки и запрошенные библиотеки компонентов ИЛИ файл конфигурации пакета CMake, предоставленный сборкой "Boost CMake". В последнем случае перейдите к разделу Boost CMake ниже.

Переменные результатов

Этот модуль определяет следующие переменные:

Boost_FOUND

Истина, если были найдены заголовки и запрошенные библиотеки.

Boost_INCLUDE_DIRS

Каталоги заголовков Boost.

Boost_LIBRARY_DIRS

Каталоги подключения для библиотек Boost.

Boost_LIBRARIES

Библиотеки компонентов Boost для подключения.

Boost_<COMPONENT>_FOUND

Истина, если компонент <COMPONENT> был найден (имя <COMPONENT> заглавными буквами).

Boost_<COMPONENT>_LIBRARY

Библиотеки для подключения к компоненту <COMPONENT> (может включать target_link_libraries() ключевые слова debug/optimized).

Boost_VERSION_MACRO

Значение BOOST_VERSION из boost/version.hpp.

Boost_VERSION_STRING

Номер версии Boost в формате X.Y.Z.

Boost_VERSION

Номер версии Boost в формате X.Y.Z (такой же, как Boost_VERSION_STRING).

Изменено в версии 3.15: В предыдущих версиях CMake эта переменная использовала строку версии из заголовка Boost (такую же, как Boost_VERSION_MACRO). См. политику CMP0093.

Boost_LIB_VERSION

Строка версии, добавленная к именам файлов библиотек.

Boost_VERSION_MAJOR, Boost_MAJOR_VERSION

Главный номер версии Boost (X в X.Y.Z).

Boost_VERSION_MINOR, Boost_MINOR_VERSION

Дополнительный номер версии Boost (Y в X.Y.Z).

Boost_VERSION_PATCH, Boost_SUBMINOR_VERSION

Поддополнительный номер версии Boost (Z в X.Y.Z).

Boost_VERSION_COUNT

Количество компонентов версии (3).

Boost_LIB_DIAGNOSTIC_DEFINITIONS (Windows-specific)

Передайте в add_definitions(), чтобы отобразить диагностическую информацию о автоматическом подключении Boost во время компиляции.

Переменные кэша

Результаты поиска сохраняются в записях кэша CMake:

Boost_INCLUDE_DIR

Каталог, содержащий заголовки Boost.

Boost_LIBRARY_DIR_RELEASE

Каталог, содержащий релизные библиотеки Boost.

Boost_LIBRARY_DIR_DEBUG

Каталог, содержащий отладочные библиотеки Boost.

Boost_<COMPONENT>_LIBRARY_DEBUG

Библиотека компонента <COMPONENT> в варианте отладки.

Boost_<COMPONENT>_LIBRARY_RELEASE

Библиотека компонента <COMPONENT> в релизной модификации.

Подсказки

Этот модуль считывает подсказки о расположениях поиска из переменных:

BOOST_ROOT, BOOSTROOT

Предпочитаемый префикс установки.

BOOST_INCLUDEDIR

Предпочитаемый каталог заголовков, например <prefix>/include.

BOOST_LIBRARYDIR

Предпочитаемый каталог библиотек, например <prefix>/lib.

Boost_NO_SYSTEM_PATHS

Установите в ON, чтобы отключить поиск в расположениях, не указанных этими переменными подсказок. По умолчанию OFF.

Boost_ADDITIONAL_VERSIONS

Список версий Boost, неизвестных этому модулю. (Расположения установки Boost могут содержать версию).

Пользователи могут установить эти подсказки или результаты как записи CACHE. Проекты не должны считывать эти записи напрямую, а вместо этого использовать перечисленные выше переменные результатов. Обратите внимание, что некоторые имена подсказок начинаются с заглавной буквы BOOST. Можно указать их как переменные среды, если они не указаны как переменные CMake или записи кэша.

Этот модуль сначала ищет файлы заголовков Boost с использованием перечисленных выше переменных подсказок (исключая BOOST_LIBRARYDIR) и сохраняет результат в Boost_INCLUDE_DIR . Затем он ищет запрошенные библиотеки компонентов, используя перечисленные выше подсказки (исключая BOOST_INCLUDEDIR и Boost_ADDITIONAL_VERSIONS), каталоги "lib" рядом с Boost_INCLUDE_DIR, и настройки конфигурации имен библиотек ниже. Он сохраняет каталоги библиотек в Boost_LIBRARY_DIR_DEBUG и Boost_LIBRARY_DIR_RELEASE, а отдельные расположения библиотек в Boost_<COMPONENT>_LIBRARY_DEBUG и Boost_<COMPONENT>_LIBRARY_RELEASE . Если вы изменяете параметры, используемые предыдущими поисками в том же дереве построения (за исключением переменных среды), этот модуль отбрасывает предыдущие результаты поиска, затронутые изменениями, и выполняет поиск снова.

Импортированные цели

Этот модуль определяет следующие цели IMPORTED:

Boost::boost

Целевой объект для зависимостей только заголовков. (Каталог заголовков Boost).

Boost::headers

Новое в версии 3.15: Псевдоним для Boost::boost.

Boost::<component>

Целевой объект для зависимости от конкретного компонента (динамическая или статическая библиотека); имя <component> в нижнем регистре.

Boost::diagnostic_definitions

Интерфейсная цель для отображения диагностической информации об автоматическом подключении Boost во время компиляции (добавляет -DBOOST_LIB_DIAGNOSTIC).

Boost::disable_autolinking

Интерфейсная цель для отключения автоматического подключения с MSVC (добавляет -DBOOST_ALL_NO_LIB).

Boost::dynamic_linking

Интерфейсная цель для включения динамического подключения с MSVC (добавляет -DBOOST_ALL_DYN_LINK).

Неявные зависимости, такие как Boost::filesystem требующие Boost::system , будут автоматически обнаружены и удовлетворены, даже если система не указана при использовании find_package() и если Boost::system не добавлено в target_link_libraries(). При использовании Boost::thread, то Threads::Threads также будет добавлено автоматически.

Важно отметить, что импортированные цели ведут себя иначе, чем переменные, созданные этим модулем: несколько вызовов find_package(Boost) в одном каталоге или подкаталогах с разными параметрами (например, статические или динамические) не перезапишут значения целей, созданные первым вызовом.

Другие переменные

Библиотеки Boost предоставляются в различных вариантах, закодированных в их имени файла. Пользователи или проекты могут указать модулю, какой вариант искать, задав переменные:

Boost_USE_DEBUG_LIBS

Новое в версии 3.10.

Установлено в ON или OFF для указания, нужно ли искать и использовать библиотеки отладки. По умолчанию ON.

Boost_USE_RELEASE_LIBS

Новое в версии 3.10.

Установлено в ON или OFF для указания, нужно ли искать и использовать релизные библиотеки. По умолчанию ON.

Boost_USE_MULTITHREADED

Установлено в OFF для использования библиотек без многопоточности ("mt" тег). По умолчанию ON.

Boost_USE_STATIC_LIBS

Установлено в ON для принудительного использования статических библиотек. По умолчанию OFF.

Boost_USE_STATIC_RUNTIME

Установлено в ON или OFF для указания, использовать ли библиотеки, статически связанные с C++ runtime ("s" тег). По умолчанию зависит от платформы.

Boost_USE_DEBUG_RUNTIME

Установлено в ON или OFF для указания, использовать ли библиотеки, связанные с отладочной C++ runtime MS ("g" тег). По умолчанию ON.

Boost_USE_DEBUG_PYTHON

Установлено в ON для использования библиотек, скомпилированных с отладочной сборкой Python ("y" тег). По умолчанию OFF.

Boost_USE_STLPORT

Установлено в ON для использования библиотек, скомпилированных с STLPort ("p" тег). По умолчанию OFF.

Boost_USE_STLPORT_DEPRECATED_NATIVE_IOSTREAMS

Установлено в ON для использования библиотек, скомпилированных с устаревшими "родными iostreams" STLPort ("n" тег). По умолчанию OFF.

Boost_COMPILER

Установлено в суффикс библиотеки, специфичный для компилятора (например, -gcc43). По умолчанию вычисляется автоматически для используемого C++ компилятора.

Изменено в версии 3.9: Может использоваться список, если нужно проверить несколько совместимых суффиксов, в порядке убывания предпочтения.

Boost_LIB_PREFIX

Новое в версии 3.18.

Установлено в префикс имени платформенно-специфичной библиотеки (например, lib ), используемый Boost статическими библиотеками. Необходимо только на платформах, где CMake по умолчанию не знает префикс.

Boost_ARCHITECTURE

Новое в версии 3.13.

Установлено в суффикс библиотеки, специфичный для архитектуры (например, -x64). По умолчанию вычисляется автоматически для используемого C++ компилятора.

Boost_THREADAPI

Суффикс для имени библиотеки компонента thread, например pthread или win32. Будут проверены имена с и без этого суффикса.

Boost_NAMESPACE

Альтернативное пространство имен, используемое для построения Boost, например, если установлено в myboost, будет поиск myboost_thread вместо boost_thread.

Другие переменные, которые можно установить для управления этим модулем:

Boost_DEBUG

Установлено в ON для включения отладочного вывода из FindBoost. Пожалуйста, включите это перед подачей отчета об ошибке.

Boost_REALPATH

Установлено в ON для разрешения символических ссылок для обнаруженных библиотек для помощи в упаковке. Например, библиотека компонента "system" может быть разрешена в /usr/lib/libboost_system.so.1.67.0 вместо /usr/lib/libboost_system.so. Это не влияет на компоновку и не должно включаться, если пользователь не нуждается в этой информации.

Boost_LIBRARY_DIR

Значение по умолчанию для Boost_LIBRARY_DIR_RELEASE и Boost_LIBRARY_DIR_DEBUG.

Boost_NO_WARN_NEW_VERSIONS

Новое в версии 3.20.

Установлено в ON для подавления предупреждения об неизвестных зависимостях для новых версий Boost.

В Visual Studio и Borland компиляторах заголовки Boost запрашивают автоматическое связывание с соответствующими библиотеками. Это требует явного связывания соответсвующих библиотек или доступности их в пути поиска библиотек. В этом случае установка Boost_USE_STATIC_LIBS в OFF может не обеспечить динамическую компоновку. Автоматическая компоновка Boost обычно запрашивает статические библиотеки, за исключением некоторых случаев (например, Boost.Python). Используйте:

add_definitions(${Boost_LIB_DIAGNOSTIC_DEFINITIONS})

чтобы попросить Boost сообщить информацию о запросах автоматической компоновки.

Примеры

Найти только заголовки Boost:

find_package(Boost 1.36.0)
if(Boost_FOUND)
  include_directories(${Boost_INCLUDE_DIRS})
  add_executable(foo foo.cc)
endif()

Найти библиотеки Boost и использовать импортированные целевые объекты:

find_package(Boost 1.56 REQUIRED COMPONENTS
             date_time filesystem iostreams)
add_executable(foo foo.cc)
target_link_libraries(foo Boost::date_time Boost::filesystem
                          Boost::iostreams)

Найти библиотеки Boost Python 3.6 и использовать импортированные целевые объекты:

find_package(Boost 1.67 REQUIRED COMPONENTS
             python36 numpy36)
add_executable(foo foo.cc)
target_link_libraries(foo Boost::python36 Boost::numpy36)

Найти заголовки Boost и некоторые статические (только релиз) библиотеки:

set(Boost_USE_STATIC_LIBS        ON)  # only find static libs
set(Boost_USE_DEBUG_LIBS        OFF)  # ignore debug libs and
set(Boost_USE_RELEASE_LIBS       ON)  # only find release libs
set(Boost_USE_MULTITHREADED      ON)
set(Boost_USE_STATIC_RUNTIME    OFF)
find_package(Boost 1.66.0 COMPONENTS date_time filesystem system ...)
if(Boost_FOUND)
  include_directories(${Boost_INCLUDE_DIRS})
  add_executable(foo foo.cc)
  target_link_libraries(foo ${Boost_LIBRARIES})
endif()

Boost CMake

Если Boost был построен с помощью проекта boost-cmake или с Boost 1.70.0, он предоставляет файл конфигурации пакета для использования с режимом конфигурации find_package. Этот модуль ищет файл конфигурации пакета, называемый BoostConfig.cmake или boost-config.cmake и сохраняет результат в записи CACHE Boost_DIR. Если найден, файл конфигурации пакета загружается, и этот модуль возвращается без дальнейших действий. Подробности о том, что он предоставляет, см. в документации по конфигурации пакета Boost CMake.

Установите Boost_NO_BOOST_CMAKE в ON, чтобы отключить поиск boost-cmake.