cmake_host_system_information

Запрос информации о различных системах хоста.

Синтаксис

Query host system specific information
  cmake_host_system_information(RESULT <variable> QUERY <key> ...)

Query Windows registry
  cmake_host_system_information(RESULT <variable> QUERY WINDOWS_REGISTRY <key> ...)

Запрос информации о системе хоста

cmake_host_system_information(RESULT <variable> QUERY <key> ...)

Запрашивает информацию о системе хоста, на которой выполняется cmake. Один или несколько <key> могут быть предоставлены для выбора запрашиваемой информации. Список запрошенных значений хранится в <variable>.

<key> может быть одним из следующих значений:

NUMBER_OF_LOGICAL_CORES

Количество логических ядер

NUMBER_OF_PHYSICAL_CORES

Количество физических ядер

HOSTNAME

Имя хоста

FQDN

Полное доменное имя

TOTAL_VIRTUAL_MEMORY

Общий объём виртуальной памяти в MiB [1]

AVAILABLE_VIRTUAL_MEMORY

Доступный объём виртуальной памяти в MiB [1]

TOTAL_PHYSICAL_MEMORY

Общий объём физической памяти в MiB [1]

AVAILABLE_PHYSICAL_MEMORY

Доступный объём физической памяти в MiB [1]

IS_64BIT

Новая версия с 3.10.

Единица, если процессор 64-битный

HAS_FPU

Новая версия с 3.10.

Единица, если процессор имеет блок обработки с плавающей точкой

HAS_MMX

Новая версия с 3.10.

Единица, если процессор поддерживает инструкции MMX

HAS_MMX_PLUS

Новая версия с 3.10.

Единица, если процессор поддерживает расширенные инструкции MMX

HAS_SSE

Новая версия с 3.10.

Единица, если процессор поддерживает инструкции SSE

HAS_SSE2

Новая версия с 3.10.

Единица, если процессор поддерживает инструкции SSE2

HAS_SSE_FP

Новая версия с 3.10.

Единица, если процессор поддерживает инструкции SSE FP

HAS_SSE_MMX

Новая версия с 3.10.

Единица, если процессор поддерживает инструкции SSE MMX

HAS_AMD_3DNOW

Новая версия с 3.10.

Единица, если процессор поддерживает инструкции 3DNow

HAS_AMD_3DNOW_PLUS

Новая версия с 3.10.

Единица, если процессор поддерживает инструкции 3DNow+

HAS_IA64

Новая версия с 3.10.

Единица, если процессор IA64 эмулирует x86

HAS_SERIAL_NUMBER

Новая версия с 3.10.

Единица, если процессор имеет серийный номер

PROCESSOR_SERIAL_NUMBER

Новая версия с 3.10.

Серийный номер процессора

PROCESSOR_NAME

Новая версия с 3.10.

Название процессора, читаемое человеком

PROCESSOR_DESCRIPTION

Новая версия с 3.10.

Полное описание процессора, читаемое человеком

OS_NAME

Новая версия с 3.10.

См. CMAKE_HOST_SYSTEM_NAME

OS_RELEASE

Новая версия с 3.10.

Подтип ОС, например, в Windows Professional

OS_VERSION

Новая версия с 3.10.

Идентификатор сборки ОС

OS_PLATFORM

Новая версия с 3.10.

См. CMAKE_HOST_SYSTEM_PROCESSOR

MSYSTEM_PREFIX

Новая версия с 3.28.

Доступно только на хостах Windows. В среде разработки MSYS или MinGW, которая устанавливает переменную среды MSYSTEM, это её префикс установки. В противном случае, это пустая строка.

DISTRIB_INFO

Новая версия с 3.22.

Чтение файла /etc/os-release и определение заданных <variable> в список прочитанных переменных

DISTRIB_<name>

Новая версия с 3.22.

Получение переменной <name> (см. man 5 os-release), если она существует в файле /etc/os-release

Пример:

cmake_host_system_information(RESULT PRETTY_NAME QUERY DISTRIB_PRETTY_NAME)
message(STATUS "${PRETTY_NAME}")

cmake_host_system_information(RESULT DISTRO QUERY DISTRIB_INFO)

foreach(VAR IN LISTS DISTRO)
  message(STATUS "${VAR}=`${${VAR}}`")
endforeach()

Вывод:

-- Ubuntu 20.04.2 LTS
-- DISTRO_BUG_REPORT_URL=`https://bugs.launchpad.net/ubuntu/`
-- DISTRO_HOME_URL=`https://www.ubuntu.com/`
-- DISTRO_ID=`ubuntu`
-- DISTRO_ID_LIKE=`debian`
-- DISTRO_NAME=`Ubuntu`
-- DISTRO_PRETTY_NAME=`Ubuntu 20.04.2 LTS`
-- DISTRO_PRIVACY_POLICY_URL=`https://www.ubuntu.com/legal/terms-and-policies/privacy-policy`
-- DISTRO_SUPPORT_URL=`https://help.ubuntu.com/`
-- DISTRO_UBUNTU_CODENAME=`focal`
-- DISTRO_VERSION=`20.04.2 LTS (Focal Fossa)`
-- DISTRO_VERSION_CODENAME=`focal`
-- DISTRO_VERSION_ID=`20.04`

Если файл /etc/os-release не найден, команда пытается собрать идентификацию ОС с помощью скриптов по умолчанию. Скрипт по умолчанию может использовать различные файлы, специфичные для дистрибутива, для сбора данных об идентификации ОС и сопоставить их с переменными man 5 os-release.

Переменные интерфейса по умолчанию

CMAKE_GET_OS_RELEASE_FALLBACK_SCRIPTS

Помимо скриптов, поставляемых с CMake, пользователь может добавить полные пути к своим скриптам в этот список. Имя файла скрипта имеет следующий формат: NNN-<name>.cmake, где NNN - трёхзначные цифры, используемые для применения собранных скриптов в определённом порядке.

CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_<varname>

Переменные, собранные пользовательским скриптом по умолчанию, должны быть назначены переменным CMake с использованием этой конвенции именования. Например, переменная ID из руководства становится CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_ID.

CMAKE_GET_OS_RELEASE_FALLBACK_RESULT

Скрипт по умолчанию должен хранить имена всех назначенных переменных CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_<varname> в этом списке.

Пример:

# Try to detect some old distribution
# See also
# - http://linuxmafia.com/faq/Admin/release-files.html
#
if(NOT EXISTS "${CMAKE_SYSROOT}/etc/foobar-release")
  return()
endif()
# Get the first string only
file(
    STRINGS "${CMAKE_SYSROOT}/etc/foobar-release" CMAKE_GET_OS_RELEASE_FALLBACK_CONTENT
    LIMIT_COUNT 1
  )
#
# Example:
#
#   Foobar distribution release 1.2.3 (server)
#
if(CMAKE_GET_OS_RELEASE_FALLBACK_CONTENT MATCHES "Foobar distribution release ([0-9\.]+) .*")
  set(CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_NAME Foobar)
  set(CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_PRETTY_NAME "${CMAKE_GET_OS_RELEASE_FALLBACK_CONTENT}")
  set(CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_ID foobar)
  set(CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_VERSION ${CMAKE_MATCH_1})
  set(CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_VERSION_ID ${CMAKE_MATCH_1})
  list(
      APPEND CMAKE_GET_OS_RELEASE_FALLBACK_RESULT
      CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_NAME
      CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_PRETTY_NAME
      CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_ID
      CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_VERSION
      CMAKE_GET_OS_RELEASE_FALLBACK_RESULT_VERSION_ID
    )
endif()
unset(CMAKE_GET_OS_RELEASE_FALLBACK_CONTENT)

Примечания

Запрос реестра Windows

cmake_host_system_information(RESULT <variable>
                              QUERY WINDOWS_REGISTRY <key> [VALUE_NAMES|SUBKEYS|VALUE <name>]
                              [VIEW (64|32|64_32|32_64|HOST|TARGET|BOTH)]
                              [SEPARATOR <separator>]
                              [ERROR_VARIABLE <result>])

Выполняет операции запроса в подключаемом ключе локального реестра. Возвращает список подключаемых ключей или имён значений, которые находятся под указанным подключаемым ключом в реестре или данными указанного имени значения. Результат запрошенного объекта хранится в <variable>.

<key> указывает полный путь к подключаемому ключу на локальном компьютере. <key> должен содержать допустимый корневой ключ. Допустимыми корневыми ключами для локального компьютера являются:

• HKLM или HKEY_LOCAL_MACHINE
• HKCU или HKEY_CURRENT_USER
• HKCR или HKEY_CLASSES_ROOT
• HKU или HKEY_USERS
• HKCC или HKEY_CURRENT_CONFIG

И, необязательно, путь к подключаемому ключу под указанным корневым ключом. Разделитель пути может быть слэшем или обратной косой чертой. <key> нечувствителен к регистру. Например:

cmake_host_system_information(RESULT result QUERY WINDOWS_REGISTRY "HKLM")
cmake_host_system_information(RESULT result QUERY WINDOWS_REGISTRY "HKLM/SOFTWARE/Kitware")
cmake_host_system_information(RESULT result QUERY WINDOWS_REGISTRY "HKCU\\SOFTWARE\\Kitware")

VALUE_NAMES

Запросить список имён значений, определённых в <key>. Если значение по умолчанию определено, оно будет идентифицировано специальным именем (default).

SUBKEYS

Запросить список подключаемых ключей, определённых в <key>.

VALUE <name>

Запросить данные, хранящиеся в значении с именем <name>. Если VALUE не указано или аргумент является специальным именем (default), будет возвращено содержимое значения по умолчанию, если таковое имеется.

# query default value for HKLM/SOFTWARE/Kitware key
cmake_host_system_information(RESULT result
                              QUERY WINDOWS_REGISTRY "HKLM/SOFTWARE/Kitware")

# query default value for HKLM/SOFTWARE/Kitware key using special value name
cmake_host_system_information(RESULT result
                              QUERY WINDOWS_REGISTRY "HKLM/SOFTWARE/Kitware"
                              VALUE "(default)")

Поддерживаемые типы:

• REG_SZ.
• REG_EXPAND_SZ. Возвращаемые данные расширены.
• REG_MULTI_SZ. Возвращаемые данные представлены как список CMake. См. также подопцию SEPARATOR.
• REG_DWORD.
• REG_QWORD.

Для всех других типов возвращается пустая строка.

VIEW

Указать, какие представления реестра необходимо запросить. Если не указано, используется представление BOTH.

64

Запрос реестра 64-битной архитектуры. На 32bit Windows, всегда возвращает пустую строку.

32

Запрос реестра 32-битной архитектуры.

64_32

Для подопции VALUE или значения по умолчанию, запрос реестра производится с использованием представления 64, а при неудаче — с использованием представления 32. Для подопций VALUE_NAMES и SUBKEYS, запрос производится с использованием обоих представлений (64 и 32) и результаты объединяются (отсортированные и без дубликатов).

32_64

Для подопции VALUE или значения по умолчанию, запрос реестра производится с использованием представления 32, а при неудаче — с использованием представления 64. Для подопций VALUE_NAMES и SUBKEYS, запрос производится с использованием обоих представлений (32 и 64) и результаты объединяются (отсортированные и без дубликатов).

HOST

Запрос реестра, соответствующий архитектуре хоста: 64 на 64bit Windows и 32 на 32bit Windows.

TARGET

Запрос реестра, соответствующий архитектуре, указанной переменной CMAKE_SIZEOF_VOID_P. Если не определена, используется представление HOST.

BOTH

Запрос обоих представлений (32 и 64). Порядок зависит от следующих правил: Если переменная CMAKE_SIZEOF_VOID_P определена. Используется следующее представление в зависимости от содержимого этой переменной:

• 8: 64_32
• 4: 32_64

Если переменная CMAKE_SIZEOF_VOID_P не определена, используется архитектура хоста:

• 64bit: 64_32
• 32bit: 32

SEPARATOR

Указать разделитель символов для типа REG_MULTI_SZ . Если не указано, используется символ \0.

ERROR_VARIABLE <result>

Возвращает любые ошибки, возникшие во время запроса. В случае успеха переменная содержит пустую строку.