cmake_parse_arguments

Парсинг аргументов функций или макросов.

cmake_parse_arguments(<prefix> <options> <one_value_keywords>
                      <multi_value_keywords> <args>...)

cmake_parse_arguments(PARSE_ARGV <N> <prefix> <options>
                      <one_value_keywords> <multi_value_keywords>)

Эта команда предназначена для использования в макросах или функциях. Она обрабатывает аргументы, переданные данному макросу или функции, и определяет набор переменных, содержащих значения соответствующих опций.

Первый вариант обрабатывает аргументы, переданные в <args>.... Это может быть использовано как в macro(), так и в function().

Аргумент <options> содержит все опции соответствующего макроса, то есть ключевые слова, которые могут быть использованы при вызове макроса без последующего значения, например, ключевое слово OPTIONAL команды install().

Аргумент <one_value_keywords> содержит все ключевые слова для этого макроса, за которыми следует одно значение, например, ключевое слово DESTINATION команды install().

Аргумент <multi_value_keywords> содержит все ключевые слова для этого макроса, за которыми может следовать более одного значения, например, ключевые слова TARGETS или FILES команды install().

После завершения работы, cmake_parse_arguments для каждого из ключевых слов, перечисленных в <options>, <one_value_keywords> и <multi_value_keywords>, создаст переменную, состоящую из заданного <prefix>, "_" и имени соответствующего ключевого слова. Эти переменные будут содержать соответствующее значение из списка аргументов или будут не определены, если соответствующая опция не была найдена. Для ключевых слов <options> они всегда будут определены, со значениями TRUE или FALSE, вне зависимости от того, присутствует ли опция в списке аргументов или нет.

Все оставшиеся аргументы собираются в переменную <prefix>_UNPARSED_ARGUMENTS, которая будет неопределённой, если все аргументы были распознаны. Это можно проверить после обработки, чтобы убедиться, что ваш макрос не был вызван с нераспознанными параметрами.

Рассмотрим следующий пример макроса, my_install(), который принимает аргументы, подобные команде install():

macro(my_install)
    set(options OPTIONAL FAST)
    set(oneValueArgs DESTINATION RENAME)
    set(multiValueArgs TARGETS CONFIGURATIONS)
    cmake_parse_arguments(MY_INSTALL "${options}" "${oneValueArgs}"
                          "${multiValueArgs}" ${ARGN} )

    # ...

Предположим, что my_install() был вызван так:

my_install(TARGETS foo bar DESTINATION bin OPTIONAL blub CONFIGURATIONS)

После вызова cmake_parse_arguments макрос установит или объявит неопределёнными следующие переменные:

MY_INSTALL_OPTIONAL = TRUE
MY_INSTALL_FAST = FALSE # was not used in call to my_install
MY_INSTALL_DESTINATION = "bin"
MY_INSTALL_RENAME <UNDEFINED> # was not used
MY_INSTALL_TARGETS = "foo;bar"
MY_INSTALL_CONFIGURATIONS <UNDEFINED> # was not used
MY_INSTALL_UNPARSED_ARGUMENTS = "blub" # nothing expected after "OPTIONAL"
MY_INSTALL_KEYWORDS_MISSING_VALUES = "CONFIGURATIONS"
         # No value for "CONFIGURATIONS" given

Затем вы можете продолжить и обработать эти переменные.

Ключевые слова завершают списки значений. Например, если сразу после one_value_keyword следует другое распознанное ключевое слово, это интерпретируется как начало новой опции. Например, my_install(TARGETS foo DESTINATION OPTIONAL) приведет к тому, что MY_INSTALL_DESTINATION будет установлено в значение "OPTIONAL", но так как OPTIONAL — это само по себе ключевое слово, MY_INSTALL_DESTINATION будет пустым (но добавленным в MY_INSTALL_KEYWORDS_MISSING_VALUES) и, следовательно, MY_INSTALL_OPTIONAL будет установлено в значение TRUE.

См. также

• function()
• macro()