configure_file

Копирует файл в другое место и изменяет его содержимое.

configure_file(<input> <output>
               [NO_SOURCE_PERMISSIONS | USE_SOURCE_PERMISSIONS |
                FILE_PERMISSIONS <permissions>...]
               [COPYONLY] [ESCAPE_QUOTES] [@ONLY]
               [NEWLINE_STYLE [UNIX|DOS|WIN32|LF|CRLF] ])

Копирует файл <input> в файл <output> и заменяет значения переменных, на которые ссылаются @VAR@, ${VAR}, $CACHE{VAR} или $ENV{VAR} в содержимом входного файла. Каждая ссылка на переменную будет заменена текущим значением переменной или пустой строкой, если переменная не определена. Кроме того, строки входного файла вида

#cmakedefine VAR ...

будут заменены либо

#define VAR ...

либо

/* #undef VAR */

в зависимости от того, установлено ли значение VAR в CMake, отличное от ложного значения, которое считается константой командой if(). Содержимое "..." в строке после имени переменной, если оно есть, обрабатывается аналогично вышеописанному.

В отличие от строк вида #cmakedefine VAR ..., в строках вида #cmakedefine01 VAR, VAR само по себе будет расширено до VAR 0 или VAR 1, а не присвоено значение .... Таким образом, строки входного файла вида

#cmakedefine01 VAR

будут заменены либо

#define VAR 0

либо

#define VAR 1

Строки входного файла вида #cmakedefine01 VAR ... будут расширены как #cmakedefine01 VAR ... 0 или #cmakedefine01 VAR ... 1, что может привести к неопределённому поведению.

#  cmakedefine VAR
#  cmakedefine01 VAR

#  define VAR
#  define VAR 1

Если входной файл изменён, система сборки повторно выполнит CMake для переконфигурации файла и повторного создания системы сборки. Сгенерированный файл модифицируется и его метка времени обновляется при последующих запусках cmake только в случае изменения его содержимого.

Аргументы:

<input>

Путь к входному файлу. Относительный путь обрабатывается относительно значения CMAKE_CURRENT_SOURCE_DIR. Путь к входному файлу должен указывать на файл, а не на каталог.

<output>

Путь к выходному файлу или каталогу. Относительный путь обрабатывается относительно значения CMAKE_CURRENT_BINARY_DIR. Если путь указывает на существующий каталог, выходной файл размещается в этом каталоге с тем же именем файла, что и входной файл. Если путь содержит несуществующие каталоги, они создаются.

NO_SOURCE_PERMISSIONS

Введено в версии 3.19.

Не передавать разрешения входного файла выходному файлу. Разрешения скопированного файла по умолчанию — стандартное значение 644 (-rw-r--r--).

USE_SOURCE_PERMISSIONS

Введено в версии 3.20.

Передавать разрешения входного файла выходному файлу. Это уже стандартное поведение, если ни один из трёх ключей, связанных с разрешениями, не указан (NO_SOURCE_PERMISSIONS, USE_SOURCE_PERMISSIONS или FILE_PERMISSIONS). Ключевое слово USE_SOURCE_PERMISSIONS в основном служит для более ясного указания намеченного поведения в месте вызова.

FILE_PERMISSIONS <permissions>...

Введено в версии 3.20.

Игнорировать разрешения входного файла и использовать указанные <permissions> для выходного файла вместо них.

COPYONLY

Скопировать файл без замены любых ссылок на переменные или другого содержимого. Этот параметр нельзя использовать с NEWLINE_STYLE.

ESCAPE_QUOTES

Экранировать любые заменённые кавычки обратными слешами (в стиле C).

@ONLY

Ограничить замену переменных ссылками вида @VAR@. Это полезно для конфигурирования скриптов, использующих синтаксис ${VAR}.

NEWLINE_STYLE <style>

Указать стиль новой строки для выходного файла. Укажите UNIX или LF для \n новых строк, или укажите DOS, WIN32, или CRLF для \r\n новых строк. Этот параметр нельзя использовать с COPYONLY.

Пример

Рассмотрим дерево исходных файлов, содержащее файл foo.h.in:

#cmakedefine FOO_ENABLE
#cmakedefine FOO_STRING "@FOO_STRING@"

Смежный файл CMakeLists.txt может использовать configure_file для настройки заголовка:

option(FOO_ENABLE "Enable Foo" ON)
if(FOO_ENABLE)
  set(FOO_STRING "foo")
endif()
configure_file(foo.h.in foo.h @ONLY)

Это создаёт файл foo.h в каталоге сборки, соответствующем данному каталогу исходных файлов. Если параметр FOO_ENABLE включён, сконфигурированный файл будет содержать:

#define FOO_ENABLE
#define FOO_STRING "foo"

В противном случае он будет содержать:

/* #undef FOO_ENABLE */
/* #undef FOO_STRING */

Затем можно использовать команду target_include_directories() для указания выходного каталога как каталога включаемых файлов:

target_include_directories(<target> [SYSTEM] <INTERFACE|PUBLIC|PRIVATE> "${CMAKE_CURRENT_BINARY_DIR}")

так что исходные файлы могут включать заголовок как #include <foo.h>.

См. также

• file(GENERATE)