try_compile

• Попытка скомпилировать целые проекты
• Попытка скомпилировать исходные файлы
• Параметры
• Другие параметры поведения
• См. также

Попробуйте собрать какой-то код.

Попытка скомпилировать целые проекты

try_compile(<compileResultVar> PROJECT <projectName>
            SOURCE_DIR <srcdir>
            [BINARY_DIR <bindir>]
            [TARGET <targetName>]
            [LOG_DESCRIPTION <text>]
            [NO_CACHE]
            [NO_LOG]
            [CMAKE_FLAGS <flags>...]
            [OUTPUT_VARIABLE <var>])

Попробуйте собрать проект. Успешное завершение сборки возвращает TRUE , а неудачное - FALSE в <compileResultVar>.

В этом формате <srcdir> должен содержать полный проект CMake с файлом CMakeLists.txt и всеми исходными файлами. Файлы <bindir> и <srcdir> не будут удалены после выполнения этой команды. Укажите <targetName> для сборки определённого целевого объекта вместо целевого объекта all или ALL_BUILD. Значение других параметров см. ниже.

Эта команда поддерживает альтернативную сигнатуру для CMake, более ранней версии 3.25. Рекомендуется использовать сигнатуру выше для ясности.

try_compile(<compileResultVar> <bindir> <srcdir>
            <projectName> [<targetName>]
            [CMAKE_FLAGS <flags>...]
            [OUTPUT_VARIABLE <var>])

Попытка скомпилировать исходные файлы

try_compile(<compileResultVar>
            [SOURCES_TYPE <type>]
            <SOURCES <srcfile...>                 |
             SOURCE_FROM_CONTENT <name> <content> |
             SOURCE_FROM_VAR <name> <var>         |
             SOURCE_FROM_FILE <name> <path>       >...
            [LOG_DESCRIPTION <text>]
            [NO_CACHE]
            [NO_LOG]
            [CMAKE_FLAGS <flags>...]
            [COMPILE_DEFINITIONS <defs>...]
            [LINK_OPTIONS <options>...]
            [LINK_LIBRARIES <libs>...]
            [OUTPUT_VARIABLE <var>]
            [COPY_FILE <fileName> [COPY_FILE_ERROR <var>]]
            [<LANG>_STANDARD <std>]
            [<LANG>_STANDARD_REQUIRED <bool>]
            [<LANG>_EXTENSIONS <bool>]
            )

Попытка собрать исполняемый файл или статическую библиотеку из одного или нескольких исходных файлов (который определяется переменной CMAKE_TRY_COMPILE_TARGET_TYPE). Успешное завершение сборки возвращает TRUE , а неудачное - FALSE в <compileResultVar>.

В этом формате должен быть указан один или несколько исходных файлов. Кроме того, один из SOURCES и/или SOURCE_FROM_* должен предшествовать другим ключевым словам.

Если CMAKE_TRY_COMPILE_TARGET_TYPE не задано или установлено в значение EXECUTABLE, исходные файлы должны содержать определение для main, и CMake создаст файл CMakeLists.txt для сборки исходных файлов как исполняемого файла. Если CMAKE_TRY_COMPILE_TARGET_TYPE установлено в значение STATIC_LIBRARY, вместо этого будет построена статическая библиотека, и определение для main не требуется. Для исполняемого файла сгенерированный файл CMakeLists.txt будет содержать что-то вроде следующего:

add_definitions(<expanded COMPILE_DEFINITIONS from caller>)
include_directories(${INCLUDE_DIRECTORIES})
link_directories(${LINK_DIRECTORIES})
add_executable(cmTryCompileExec <srcfile>...)
target_link_options(cmTryCompileExec PRIVATE <LINK_OPTIONS from caller>)
target_link_libraries(cmTryCompileExec ${LINK_LIBRARIES})

CMake автоматически генерирует для каждой операции try_compile уникальную директорию в ${CMAKE_BINARY_DIR}/CMakeFiles/CMakeScratch с неопределённым именем. Эти директории очищаются автоматически, если --debug-trycompile не передано в cmake. Такие директории из предыдущих запусков также безусловно очищаются в начале любого выполнения cmake.

Эта команда поддерживает альтернативную сигнатуру для CMake, более ранней версии 3.25. Рекомендуется использовать сигнатуру выше для ясности.

try_compile(<compileResultVar> <bindir> <srcfile|SOURCES srcfile...>
            [CMAKE_FLAGS <flags>...]
            [COMPILE_DEFINITIONS <defs>...]
            [LINK_OPTIONS <options>...]
            [LINK_LIBRARIES <libs>...]
            [OUTPUT_VARIABLE <var>]
            [COPY_FILE <fileName> [COPY_FILE_ERROR <var>]]
            [<LANG>_STANDARD <std>]
            [<LANG>_STANDARD_REQUIRED <bool>]
            [<LANG>_EXTENSIONS <bool>]
            )

В этой версии try_compile будет использовать <bindir>/CMakeFiles/CMakeTmp для своей работы, и все такие файлы будут очищены автоматически. Для отладки, --debug-trycompile можно передать в cmake, чтобы избежать этой очистки. Однако несколько последовательных операций try_compile с одинаковым значением <bindir> будут повторно использовать одну выходную директорию, так что вы можете отладить только одно такое вызов try_compile одновременно. Рекомендуется использовать новую сигнатуру для упрощения отладки нескольких операций try_compile.

Параметры

Параметры для вышеуказанных сигнатур:

CMAKE_FLAGS <flags>...

Укажите флаги в формате -DVAR:TYPE=VALUE, которые должны быть переданы команде cmake(1) командной строки, используемой для управления сборкой теста. Приведенный выше пример демонстрирует, как используются значения для переменных INCLUDE_DIRECTORIES, LINK_DIRECTORIES, и LINK_LIBRARIES.

COMPILE_DEFINITIONS <defs>...

Укажите аргументы -Ddefinition для передачи в add_definitions() в сгенерированном проекте теста.

COPY_FILE <fileName>

Скопировать созданный исполняемый файл или статическую библиотеку в указанную <fileName>.

COPY_FILE_ERROR <var>

Используется после COPY_FILE для записи в переменную <var> любого сообщения об ошибке, возникшей при попытке копирования файла.

LINK_LIBRARIES <libs>...

Укажите библиотеки, которые необходимо подключить в сгенерированный проект. Список библиотек может ссылаться на системные библиотеки и на Импортированные целевые объекты из вызывающего проекта.

Если этот параметр указан, любое значение -DLINK_LIBRARIES=... для параметра CMAKE_FLAGS будет проигнорировано.

LINK_OPTIONS <options>...

Новое в версии 3.14.

Укажите параметры шага линковки для передачи в target_link_options() или для установки свойства целевого объекта STATIC_LIBRARY_OPTIONS в сгенерированном проекте, в зависимости от переменной CMAKE_TRY_COMPILE_TARGET_TYPE.

LOG_DESCRIPTION <text>

Новое в версии 3.26.

Укажите непустое текстовое описание цели проверки. Это записывается в запись cmake-configure-log(7).

NO_CACHE

Новое в версии 3.25.

Результат будет сохранён в обычной переменной, а не в записи кэша.

Переменная результата обычно кэшируется, чтобы можно было использовать простой шаблон для избежания повторения теста при последующих запусках CMake:

if(NOT DEFINED RESULTVAR)
  # ...(check-specific setup code)...
  try_compile(RESULTVAR ...)
  # ...(check-specific logging and cleanup code)...
endif()

Если переменная защиты и переменная результата не совпадают (например, если тест является частью более крупного анализа), NO_CACHE может быть полезным для предотвращения утечки промежуточной переменной результата в кэш.

NO_LOG

Новое в версии 3.26.

Не записывать запись cmake-configure-log(7) для этого вызова.

OUTPUT_VARIABLE <var>

Сохранить вывод из процесса сборки в указанной переменной.

SOURCE_FROM_CONTENT <name> <content>

Новое в версии 3.25.

Записать <content> в файл с именем <name> в каталоге операции. Это может использоваться для исключения необходимости отдельного записи файла, когда содержимое файла динамически задается. Указанный <name> не должен содержать компонентов пути.

SOURCE_FROM_CONTENT может быть указан несколько раз.

SOURCE_FROM_FILE <name> <path>

Новое в версии 3.25.

Скопировать <path> в файл с именем <name> в каталоге операции. Это может быть использовано для консолидации файлов в каталог операции, что может быть полезно, если исходный файл, который уже существует (т.е. как отдельный файл в репозитории исходных кодов проекта), должен ссылаться на другие файл(ы), созданные SOURCE_FROM_*. (В противном случае, SOURCES обычно более удобно.) Указанный <name> не должен содержать компонентов пути.

SOURCE_FROM_VAR <name> <var>

Новое в версии 3.25.

Записать содержимое <var> в файл с именем <name> в каталоге операции. Это то же самое, что и SOURCE_FROM_CONTENT, но берет содержимое из указанной переменной CMake, а не непосредственно, что может быть полезно при передаче аргументов через функцию, которая оборачивает try_compile. Указанный <name> не должен содержать компонентов пути.

SOURCE_FROM_VAR может быть указан несколько раз.

SOURCES_TYPE <type>

Новое в версии 3.28.

Источники могут быть классифицированы с помощью аргумента SOURCES_TYPE. После указания все последующие указанные источники будут обрабатываться как того типа, пока не будет задан другой SOURCES_TYPE. Доступные типы:

NORMAL

Источники не добавляются ни к одному FILE_SET в сгенерированном проекте.

CXX_MODULE

Новое в версии 3.28.

Источники добавляются в FILE_SET типа CXX_MODULES в сгенерированном проекте.

По умолчанию тип источников — NORMAL.

<LANG>_STANDARD <std>

Новое в версии 3.8.

Укажите свойство целевого объекта C_STANDARD, CXX_STANDARD, OBJC_STANDARD, OBJCXX_STANDARD, или CUDA_STANDARD сгенерированного проекта.

<LANG>_STANDARD_REQUIRED <bool>

Новое в версии 3.8.

Укажите свойство целевого объекта C_STANDARD_REQUIRED, CXX_STANDARD_REQUIRED, OBJC_STANDARD_REQUIRED, OBJCXX_STANDARD_REQUIRED, или CUDA_STANDARD_REQUIRED сгенерированного проекта.

<LANG>_EXTENSIONS <bool>

Новое в версии 3.8.

Укажите свойство целевого объекта C_EXTENSIONS, CXX_EXTENSIONS, OBJC_EXTENSIONS, OBJCXX_EXTENSIONS, или CUDA_EXTENSIONS сгенерированного проекта.

Другие настройки поведения

Текущие настройки CMP0065 и CMP0083 передаются сгенерированному тестовому проекту.

Установите переменную CMAKE_TRY_COMPILE_CONFIGURATION, чтобы выбрать конфигурацию сборки:

• Для генераторов с несколькими конфигурациями, это выбирает конфигурацию для сборки.
• Для генераторов с одной конфигурацией, это устанавливает CMAKE_BUILD_TYPE в тестовом проекте.

См. также

• try_run()