FindProtobuf

Расположение и настройка библиотеки Google Protocol Buffers.

Следующие переменные можно установить, и они являются необязательными:

Protobuf_SRC_ROOT_FOLDER

При компиляции с MSVC, если эта переменная кэша установлена, будут просматриваться расположения проектов protobuf-default VS (vsprojects/Debug и vsprojects/Release или vsprojects/x64/Debug и vsprojects/x64/Release) в поисках библиотек и двоичных файлов.

Protobuf_IMPORT_DIRS

Список дополнительных каталогов для поиска импортированных файлов .proto.

Protobuf_DEBUG

Новая в версии 3.6.

Показать сообщения отладки.

Protobuf_USE_STATIC_LIBS

Новая в версии 3.9.

Установите значение в ON, чтобы принудительно использовать статические библиотеки. По умолчанию значение OFF.

Определяет следующие переменные:

Protobuf_FOUND

Найдена библиотека Google Protocol Buffers (libprotobuf и заголовочные файлы)

Protobuf_VERSION

Новая в версии 3.6.

Найденная версия пакета.

Protobuf_INCLUDE_DIRS

Директории включения для Google Protocol Buffers

Protobuf_LIBRARIES

Библиотеки protobuf.

Protobuf_PROTOC_LIBRARIES

Библиотеки protoc.

Protobuf_LITE_LIBRARIES

Библиотеки protobuf-lite.

protobuf::libprotobuf

Библиотека protobuf.

protobuf::libprotobuf-lite

Библиотека protobuf lite.

protobuf::libprotoc

Библиотека protoc.

protobuf::protoc

Новая в версии 3.10: Компилятор protoc.

Также доступны следующие переменные кэша для установки или использования:

Protobuf_LIBRARY

Библиотека protobuf.

Protobuf_PROTOC_LIBRARY

Библиотека protoc.

Protobuf_INCLUDE_DIR

Директория включения для протоколов.

Protobuf_PROTOC_EXECUTABLE

Компилятор protoc.

Protobuf_LIBRARY_DEBUG

Библиотека protobuf (отладка).

Protobuf_PROTOC_LIBRARY_DEBUG

Библиотека protoc (отладка).

Protobuf_LITE_LIBRARY

Библиотека protobuf-lite.

Protobuf_LITE_LIBRARY_DEBUG

Библиотека protobuf-lite (отладка).

Пример:

find_package(Protobuf REQUIRED)
include_directories(${Protobuf_INCLUDE_DIRS})
include_directories(${CMAKE_CURRENT_BINARY_DIR})
protobuf_generate_cpp(PROTO_SRCS PROTO_HDRS foo.proto)
protobuf_generate_cpp(PROTO_SRCS PROTO_HDRS EXPORT_MACRO DLL_EXPORT foo.proto)
protobuf_generate_cpp(PROTO_SRCS PROTO_HDRS DESCRIPTORS PROTO_DESCS foo.proto)
protobuf_generate_python(PROTO_PY foo.proto)
add_executable(bar bar.cc ${PROTO_SRCS} ${PROTO_HDRS})
target_link_libraries(bar ${Protobuf_LIBRARIES})

protobuf_generate_cpp

Добавление пользовательских команд для обработки файлов .proto в C++:

protobuf_generate_cpp (<SRCS> <HDRS>
    [DESCRIPTORS <DESC>] [EXPORT_MACRO <MACRO>] [<ARGN>...])

SRCS

Переменная для определения файлов исходного кода с автоматическим генерированием.

HDRS

Переменная для определения заголовочных файлов с автоматическим генерированием.

DESCRIPTORS

Новая в версии 3.10: Переменная для определения файлов-описателей с автоматическим генерированием, если требуется.

EXPORT_MACRO

является макросом, который должен раскрываться как __declspec(dllexport) или __declspec(dllimport) в зависимости от того, что компилируется.

ARGN

Файлы .proto.

protobuf_generate_python

Новая в версии 3.4.

Добавление пользовательских команд для обработки файлов .proto в Python:

protobuf_generate_python (<PY> [<ARGN>...])

PY

Переменная для определения файлов Python с автоматическим генерированием.

ARGN

Файлы .proto.

protobuf_generate

Новая в версии 3.13.

Автоматическое генерирование файлов исходного кода из файлов схемы .proto во время сборки:

protobuf_generate (
    TARGET <target>
    [LANGUAGE <lang>]
    [OUT_VAR <out_var>]
    [EXPORT_MACRO <macro>]
    [PROTOC_OUT_DIR <dir>]
    [PLUGIN <plugin>]
    [PLUGIN_OPTIONS <plugin_options>]
    [DEPENDENCIES <depends]
    [PROTOS <protobuf_files>]
    [IMPORT_DIRS <dirs>]
    [GENERATE_EXTENSIONS <extensions>]
    [PROTOC_OPTIONS <protoc_options>]
    [APPEND_PATH])

APPEND_PATH

Флаг, который добавляет базовый путь всех файлов схемы proto в IMPORT_DIRS.

LANGUAGE

Одно значение: cpp или python. Определяет, какие типы файлов исходного кода генерируются. По умолчанию cpp.

OUT_VAR

Имя переменной CMake, которая будет заполнена путями к сгенерированным файлам исходного кода.

EXPORT_MACRO

Имя макроса, который применяется ко всем сгенерированным классам сообщений Protobuf и внешним переменным. Например, он может использоваться для объявления экспорта DLL.

PROTOC_OUT_DIR

Директория вывода сгенерированных файлов исходного кода. По умолчанию CMAKE_CURRENT_BINARY_DIR.

PLUGIN

Новая в версии 3.21.

Необязаемый исполняемый файл плагина. Например, это может быть путь к grpc_cpp_plugin.

PLUGIN_OPTIONS

Новая в версии 3.28.

Дополнительные параметры, предоставляемые плагину, например generate_mock_code=true для плагина gRPC cpp.

DEPENDENCIES

Новая в версии 3.28.

Аргументы, переданные в DEPENDS базового вызова add_custom_command.

TARGET

Целевой объект CMake, которому будут добавлены сгенерированные файлы в качестве исходных.

PROTOS

Список файлов схемы proto. Если опущено, то будут использоваться все файлы исходного кода, заканчивающиеся на proto в TARGET.

IMPORT_DIRS

Общий родительский каталог для файлов схемы. Например, если файл схемы proto/helloworld/helloworld.proto и директория импорта proto/, то сгенерированные файлы ${PROTOC_OUT_DIR}/helloworld/helloworld.pb.h и ${PROTOC_OUT_DIR}/helloworld/helloworld.pb.cc.

GENERATE_EXTENSIONS

Если LANGUAGE опущено, то это должно быть установлено в расширения, генерируемые protoc.

PROTOC_OPTIONS

Новая в версии 3.28.

Дополнительные аргументы, которые передаются в protoc.

Пример:

find_package(gRPC CONFIG REQUIRED)
find_package(Protobuf REQUIRED)
add_library(ProtoTest Test.proto)
target_link_libraries(ProtoTest PUBLIC gRPC::grpc++)
protobuf_generate(TARGET ProtoTest)
protobuf_generate(
    TARGET ProtoTest
    LANGUAGE grpc
    PLUGIN protoc-gen-grpc=$<TARGET_FILE:gRPC::grpc_cpp_plugin>
    PLUGIN_OPTIONS generate_mock_code=true
    GENERATE_EXTENSIONS .grpc.pb.h .grpc.pb.cc)