INTERFACE_AUTOMOC_MACRO_NAMES

Список макросов, разделённых точкой с запятой, для списка, разделённого точкой с запятой AUTOMOC для передачи потребителям.

Когда целевой объект с включённым AUTOMOC ссылается на библиотеку, которая устанавливает INTERFACE_AUTOMOC_MACRO_NAMES, целевой объект наследует перечисленные имена макросов и объединяет их с именами, указанными в своём свойстве AUTOMOC_MACRO_NAMES. Целевой объект автоматически сгенерирует файлы MOC для исходных файлов, которые содержат унаследованные имена макросов, а не только имена макросов, указанные в его собственном свойстве AUTOMOC_MACRO_NAMES.

По умолчанию INTERFACE_AUTOMOC_MACRO_NAMES пустое.

См. руководство cmake-qt(7) для получения дополнительной информации о работе с CMake и Qt.

Пример 1

В этом примере, myapp наследует имена макросов STATIC_LIB_1 и STATIC_LIB_2 из static_lib. Инструмент moc будет автоматически запущен для любого из myapp источников, содержащих STATIC_LIB_1 или STATIC_LIB_2.

set(AUTOMOC ON)
add_executable(myapp main.cpp)
target_link_libraries(myapp PRIVATE static_lib)

add_library(static_lib STATIC static.cpp)
set_property(TARGET static_lib PROPERTY
  INTERFACE_AUTOMOC_MACRO_NAMES "STATIC_LIB_1;STATIC_LIB_2"
)

Пример 2

В этом примере свойство целевого объекта INTERFACE_AUTOMOC_MACRO_NAMES различных *_deep_lib библиотек будет распространяться на shared_lib, static_lib и interface_lib. Поскольку отношения связывания указаны как PUBLIC и INTERFACE, эти имена макросов также будут распространяться транзитивно на app.

set(AUTOMOC ON)

add_library(shared_deep_lib SHARED deep_lib.cpp)
add_library(static_deep_lib STATIC deep_lib.cpp)
add_library(interface_deep_lib INTERFACE)

set_property(TARGET shared_deep_lib PROPERTY
  INTERFACE_AUTOMOC_MACRO_NAMES "SHARED_LINK_LIB"
)
set_property(TARGET static_deep_lib PROPERTY
  INTERFACE_AUTOMOC_MACRO_NAMES "STATIC_LINK_LIB"
)
set_property(TARGET interface_deep_lib PROPERTY
  INTERFACE_AUTOMOC_MACRO_NAMES "INTERFACE_LINK_LIB"
)

add_library(shared_lib SHARED lib.cpp)
add_library(static_lib STATIC lib.cpp)
add_library(interface_lib INTERFACE)

# PUBLIC and INTERFACE here ensure the macro names propagate to any
# consumers of shared_lib, static_lib or interface_lib too
target_link_libraries(shared_lib PUBLIC shared_deep_lib)
target_link_libraries(static_lib PUBLIC static_deep_lib)
target_link_libraries(interface_lib INTERFACE interface_deep_lib)

# This consumer will receive all three of the above custom macro names as
# transitive usage requirements
add_executable(app main.cpp)
target_link_libraries(app PRIVATE shared_lib static_lib interface_lib)

В приведённом выше примере:

• shared_lib источники будут обработаны moc если они содержат SHARED_LINK_LIB.
• static_lib источники будут обработаны moc если они содержат STATIC_LINK_LIB.
• app источники будут обработаны moc если они содержат SHARED_LINK_LIB, STATIC_LINK_LIB или INTERFACE_LINK_LIB.