FindPackageHandleStandardArgs

Этот модуль предоставляет функцию, предназначенную для использования в Поиске модулей, реализуя вызовы find_package(<PackageName>). Он обрабатывает REQUIRED, QUIET и аргументы, связанные с версией, find_package. Также он устанавливает переменную <PackageName>_FOUND. Пакет считается найденным, если все перечисленные переменные содержат корректные результаты, например, корректные пути к файлам.

find_package_handle_standard_args

Существует две сигнатуры:

find_package_handle_standard_args(<PackageName>
  (DEFAULT_MSG|<custom-failure-message>)
  <required-var>...
  )

find_package_handle_standard_args(<PackageName>
  [FOUND_VAR <result-var>]
  [REQUIRED_VARS <required-var>...]
  [VERSION_VAR <version-var>]
  [HANDLE_COMPONENTS]
  [CONFIG_MODE]
  [FAIL_MESSAGE <custom-failure-message>]
  )

Переменная <PackageName>_FOUND будет установлена в значение TRUE, если все переменные <required-var>... являются корректными и удовлетворяются все дополнительные ограничения, и в FALSE в противном случае. В зависимости от результатов и от того, был ли задан параметр REQUIRED и/или QUIET в вызове find_package(), может быть выведено сообщение об успехе или об ошибке.

Параметры:

(DEFAULT_MSG|<custom-failure-message>)

В простой сигнатуре это определяет сообщение об ошибке. Используйте DEFAULT_MSG для запроса вычисления стандартного сообщения (рекомендуется). Недопустимо в полной сигнатуре.

FOUND_VAR <result-var>

Устарело. Указывает <PackageName>_FOUND или <PACKAGENAME>_FOUND в качестве переменной результата. Это существует только для совместимости со старыми версиями CMake и сейчас игнорируется. Переменные результата с обоими именами всегда устанавливаются для совместимости.

REQUIRED_VARS <required-var>...

Указывают переменные, необходимые для этого пакета. Они могут быть указаны в сгенерированном сообщении об ошибке, предлагающем пользователю установить значения отсутствующих переменных. Поэтому обычно это должны быть записи кэша, такие как FOO_LIBRARY, а не переменные вывода, такие как FOO_LIBRARIES.

VERSION_VAR <version-var>

Указывает имя переменной, содержащей версию найденного пакета. Эта версия будет проверена на соответствие (возможно) указанной требуемой версии, заданной в вызове find_package(), включая опцию EXACT. В стандартных сообщениях содержится информация о требуемой версии и фактически найденной версии, как если версия подходит, так и нет.

HANDLE_COMPONENTS

Включить обработку компонентов пакета. В этом случае команда сообщит, какие компоненты были найдены и какие отсутствуют, и переменная <PackageName>_FOUND будет установлена в FALSE, если отсутствует любой из требуемых компонентов (то есть не те, которые перечислены после опции OPTIONAL_COMPONENTS вызова find_package()).

CONFIG_MODE

Указывает, что вызывающий модуль поиска является оболочкой вызова find_package(<PackageName> NO_MODULE). Это подразумевает значение VERSION_VAR в <PackageName>_VERSION. Команда автоматически проверит, был ли найден файл конфигурации пакета.

FAIL_MESSAGE <custom-failure-message>

Указывает пользовательское сообщение об ошибке вместо использования стандартного сгенерированного сообщения. Не рекомендуется.

Пример для простой сигнатуры:

find_package_handle_standard_args(LibXml2 DEFAULT_MSG
  LIBXML2_LIBRARY LIBXML2_INCLUDE_DIR)

Пакет LibXml2 считается найденным, если LIBXML2_LIBRARY и LIBXML2_INCLUDE_DIR являются корректными. Тогда также LibXml2_FOUND устанавливается в TRUE. Если он не найден и используется REQUIRED, происходит ошибка с message(FATAL_ERROR), независимо от того, использовался QUIET или нет. Если пакет найден, будет сообщено об успехе, включая содержимое первого <required-var>. При повторных запусках CMake данное сообщение не будет выведено повторно.

Пример для полной сигнатуры:

find_package_handle_standard_args(LibArchive
  REQUIRED_VARS LibArchive_LIBRARY LibArchive_INCLUDE_DIR
  VERSION_VAR LibArchive_VERSION)

В этом случае пакет LibArchive считается найденным, если LibArchive_LIBRARY и LibArchive_INCLUDE_DIR являются корректными. Также версия LibArchive будет проверена с использованием версии из LibArchive_VERSION. Поскольку параметр FAIL_MESSAGE не задан, будут напечатаны стандартные сообщения.

Другой пример для полной сигнатуры:

find_package(Automoc4 QUIET NO_MODULE HINTS /opt/automoc4)
find_package_handle_standard_args(Automoc4  CONFIG_MODE)

В этом случае модуль FindAutmoc4.cmake оборачивает вызов find_package(Automoc4 NO_MODULE) и добавляет дополнительный каталог поиска для automoc4. Тогда вызов find_package_handle_standard_args генерирует корректное сообщение об успехе/ошибке.