cfloop

Цикл по структуре с использованием аргументов collection и item тега cfloop.

<!--- Define our struct ---> 
 <cfset myStruct = {name: "Tony", state: "Florida"}> 
 <!--- By struct ---> 
 <cfloop item="currentKey" collection="#myStruct#"> 
 <cfoutput><li>#currentKey# : #myStruct[currentKey]#</li></cfoutput> 
 </cfloop>

Lucee 4.5+ Цикл по структуре с использованием аргументов collection, index и item тега cfloop.

<!--- Define our struct --->
<cfset myStruct = {name: "Tony", state: "Florida"}>
<!--- By struct --->
<cfloop item="currentItem" collection="#myStruct#" index="currentKey">

<cfoutput><li>#currentKey# : #currentItem#</li></cfoutput>
</cfloop>

Цикл по списку

// Define our list 
 myList = "a, b, c"; 
 // By array 
 for (item in listToArray(myList, ",")) { 
 writeOutput(item); 
 } 
 // By listEach() 
 myList.each(function(element, index) { 
 writeOutput(element & " : " & index); 
 }, ",");

Цикл по списку

<!--- Define our list ---> 
 <cfset myList = "a, b, c"> 
 <!--- By list ---> 
 <cfloop index="item" list="#myList#"> 
 <cfoutput>#item#</cfoutput> 
 </cfloop> 
 <!--- By array ---> 
 <cfloop index="currentIndex" array="#listToArray(myList, ",")#"> 
 <cfoutput>#currentIndex#</cfoutput> 
 </cfloop>

Цикл по запросу

// Define our query 
 platform = ["Adobe ColdFusion", "Railo", "Lucee"]; 
 myQuery = queryNew(" "); 
 queryAddColumn(myQuery, "platform", "CF_SQL_VARCHAR", platform); 
 // By row index 
 for (i = 1; i <= myQuery.recordCount; i++) { 
 writeOutput("<li>#myQuery["platform"][i]#</li>"); 
 } 
 // By query 
 for (row in myQuery) { 
 writeOutput("<li>#row.platform#</li>"); 
 }

Цикл по запросу с группировкой

q = queryNew("pk,fk,data", "integer,integer,varchar",[ 
 [1, 10, "aa"], 
 [2, 20, "bb"], 
 [3, 20, "cc"], 
 [4, 30, "dd"], 
 [5, 30, "ee"], 
 [6, 30, "ff"] 
]); 
cfloop(query=q, group="fk"){ 
    writeOutput("<strong>#fk#</strong><br />"); 
    cfloop(){ 
        writeOutput("&emsp;#pk#:#data#<br />"); 
    } 
    writeOutput("<hr>"); 
}

Цикл по запросу

<!--- Define our query ---> 
 <cfset platform = ["Adobe ColdFusion", "Railo", "Lucee"]> 
 <cfset myQuery = queryNew(" ")> 
 <cfset queryAddColumn(myQuery, "platform", "CF_SQL_VARCHAR", platform)> 
 <!--- By row index ---> 
 <cfloop index="i" from="1" to="#myQuery.recordCount#"> 
 <cfoutput><li>#myQuery["platform"][i]#</li></cfoutput> 
 </cfloop> 
 <!--- By group ---> 
 <cfloop query="myQuery" group="platform"> 
 <cfoutput><li>#platform#</li></cfoutput> 
 </cfloop>

Цикл с предусловием. Эта форма цикла проверяет одно условие в начале каждой итерации и продолжает выполнение, пока условие истинно.

while (condition) { 
  // statements 
}

Цикл с постусловием. Эта форма цикла проверяет одно условие в начале каждой итерации и продолжает выполнение, пока условие истинно.

do { 
 // statements 
} while(condition);

Цикл по файлу. По 16 символов за раз.

filePath = getCurrentTemplatePath(); 
 cfloop(file=filePath, index="chars", characters=16, charset="UTF-8"){ 
 writeOutput(chars); // outputs the contents of this file 
 }

Цикл по диапазону дат и времени (обходной способ)

from = now(); 
 to   = dateAdd("d", 7, from); 
 for(date=from; dateCompare(date, to, "d") <= 0; date = dateAdd("d", 1, date)){ 
 writeOutput(dateTimeFormat(date, "yyyy-mm-dd HH:nn:sstt") & "<br>"); 
 }