core.bitop

Этот модуль содержит набор операций на уровне битов.

Лицензия:

Boost License 1.0

Авторы:

Don Clugston, Sean Kelly, Walter Bright, Alex Rønne Petersen, Thomas Stuart Bockman

Исходный код

core/bitop.d

pure nothrow @nogc @safe int bsf(uint v);

pure nothrow @nogc @safe int bsf(ulong v);

Сканирует биты в v, начиная с бита 0, и ищет первый установленный бит.

Возвращает:

Номер бита первого установленного бита. Значение возврата не определено, если v равно нулю.

Примеры:

assert(bsf(0x21) == 0);
assert(bsf(ulong.max << 39) == 39);

pure nothrow @nogc @safe int bsr(uint v);

pure nothrow @nogc @safe int bsr(ulong v);

Сканирует биты в v от старшего бита к младшему, ищет первый установленный бит.

Возвращает:

Номер бита первого установленного бита. Значение возврата не определено, если v равно нулю.

Примеры:

assert(bsr(0x21) == 5);
assert(bsr((ulong.max >> 15) - 1) == 48);

pure nothrow @nogc @system int bt(scope const size_t* p, size_t bitnum);

Проверяет бит. (Больше не является внутренней функцией - компилятор распознаёт шаблоны в теле функции).

Примеры:

size_t[2] array;

array[0] = 2;
array[1] = 0x100;

assert(bt(array.ptr, 1));
assert(array[0] == 2);
assert(array[1] == 0x100);

pure nothrow @nogc @system int btc(size_t* p, size_t bitnum);

Проверяет и инвертирует бит.

pure nothrow @nogc @system int btr(size_t* p, size_t bitnum);

Проверяет и сбрасывает (устанавливает в 0) бит.

pure nothrow @nogc @system int bts(size_t* p, size_t bitnum);

Проверяет и устанавливает бит.

Параметры:

size_t* p	указатель на массив size_t, не равный NULL.
size_t bitnum	номер бита, начиная с бита 0 в p[0] и продолжая. Он адресовывает биты так же, как выражение: p[index / (size_t.sizeof*8)] & (1 << (index & ((size_t.sizeof*8) - 1)))

Возвращает:

Не нулевое значение, если бит был установлен, и ноль, если он был сброшен.

Примеры:

size_t[2] array;

array[0] = 2;
array[1] = 0x100;

assert(btc(array.ptr, 35) == 0);
if (size_t.sizeof == 8)
{
    assert(array[0] == 0x8_0000_0002);
    assert(array[1] == 0x100);
}
else
{
    assert(array[0] == 2);
    assert(array[1] == 0x108);
}

assert(btc(array.ptr, 35));
assert(array[0] == 2);
assert(array[1] == 0x100);

assert(bts(array.ptr, 35) == 0);
if (size_t.sizeof == 8)
{
    assert(array[0] == 0x8_0000_0002);
    assert(array[1] == 0x100);
}
else
{
    assert(array[0] == 2);
    assert(array[1] == 0x108);
}

assert(btr(array.ptr, 35));
assert(array[0] == 2);
assert(array[1] == 0x100);

struct BitRange;

Диапазон над набором битов. Каждый элемент — это номер бита, который установлен.

Это более эффективно, чем проверка каждого бита в разреженном наборе битов. Обратите внимание, что первый бит в наборе битов будет битом 0.

Примеры:

import core.stdc.stdlib : malloc, free;
import core.stdc.string : memset;

// initialize a bit array
enum nBytes = (100 + BitRange.bitsPerWord - 1) / 8;
size_t *bitArr = cast(size_t *)malloc(nBytes);
scope(exit) free(bitArr);
memset(bitArr, 0, nBytes);

// set some bits
bts(bitArr, 48);
bts(bitArr, 24);
bts(bitArr, 95);
bts(bitArr, 78);

enum sum = 48 + 24 + 95 + 78;

// iterate
size_t testSum;
size_t nBits;
foreach (b; BitRange(bitArr, 100))
{
    testSum += b;
    ++nBits;
}

assert(testSum == sum);
assert(nBits == 4);

enum ulong bitsPerWord;

Количество битов в каждом size_t

pure nothrow @nogc @system this(const(size_t)* bitarr, size_t numBits);

Создаёт BitRange.

Параметры:

const(size_t)* bitarr	Массив битов для итерации
size_t numBits	Общее количество допустимых битов в заданном массиве битов

pure nothrow @nogc @safe size_t front();

const pure nothrow @nogc @safe bool empty();

pure nothrow @nogc @system void popFront();

Функции диапазона

pure nothrow @nogc @safe ushort byteswap(ushort x);

Меняет байты в 2-байтовом ushort.

Параметры:

ushort x

значение

Возвращает:

x с переставленными байтами

Примеры:

assert(byteswap(cast(ushort)0xF234) == 0x34F2);
static ushort xx = 0xF234;
assert(byteswap(xx) == 0x34F2);

pure nothrow @nogc @safe uint bswap(uint v);

Меняет байты в 4-байтовом uint с конца в начало, т.е. байт 0 становится байтом 3, байт 1 становится байтом 2, байт 2 становится байтом 1, байт 3 становится байтом 0.

Примеры:

assert(bswap(0x01020304u) == 0x04030201u);
static uint xx = 0x10203040u;
assert(bswap(xx) == 0x40302010u);

pure nothrow @nogc @safe ulong bswap(ulong v);

Меняет байты в 8-байтовом ulong с конца в начало, т.е. байт 0 становится байтом 7, байт 1 становится байтом 6 и т.д. Это должно быть распознано компилятором как встроенная функция.

Примеры:

assert(bswap(0x01020304_05060708uL) == 0x08070605_04030201uL);
static ulong xx = 0x10203040_50607080uL;
assert(bswap(xx) == 0x80706050_40302010uL);

nothrow @nogc @system ubyte inp(uint port_address);

nothrow @nogc @system ushort inpw(uint port_address);

nothrow @nogc @system uint inpl(uint port_address);

Считывает порт ввода-вывода по адресу port_address.

nothrow @nogc @system ubyte outp(uint port_address, ubyte value);

nothrow @nogc @system ushort outpw(uint port_address, ushort value);

nothrow @nogc @system uint outpl(uint port_address, uint value);

Записывает значение в порт ввода-вывода по адресу port_address и возвращает его.

pure nothrow @nogc @safe int popcnt(uint x);

pure nothrow @nogc @safe int popcnt(ulong x);

Вычисляет количество установленных битов в целочисленном значении.

pure nothrow @nogc @safe ushort _popcnt(ushort x);

pure nothrow @nogc @safe int _popcnt(uint x);

pure nothrow @nogc @safe int _popcnt(ulong x);

Вычисляет количество установленных битов в целочисленном значении, используя инструкцию X86 SSE4 POPCNT. POPCNT не доступна на всех процессорах X86.

pure nothrow @nogc @safe uint bitswap(uint x);

Инвертирует порядок битов в 32-битном целочисленном значении.

pure nothrow @nogc @safe ulong bitswap(ulong x);

Инвертирует порядок битов в 64-битном целочисленном значении.

pure T rol(T)(const T value, const uint count)
Constraints: if (__traits(isIntegral, T) && __traits(isUnsigned, T));

pure T ror(T)(const T value, const uint count)
Constraints: if (__traits(isIntegral, T) && __traits(isUnsigned, T));

pure T rol(uint count, T)(const T value)
Constraints: if (__traits(isIntegral, T) && __traits(isUnsigned, T));

pure T ror(uint count, T)(const T value)
Constraints: if (__traits(isIntegral, T) && __traits(isUnsigned, T));

Битовое циклическое сдвиг влево (rol) или вправо (ror) на count позиций.

Примеры:

ubyte a = 0b11110000U;
ulong b = ~1UL;

assert(rol(a, 1) == 0b11100001);
assert(ror(a, 1) == 0b01111000);
assert(rol(a, 3) == 0b10000111);
assert(ror(a, 3) == 0b00011110);

assert(rol(a, 0) == a);
assert(ror(a, 0) == a);

assert(rol(b, 63) == ~(1UL << 63));
assert(ror(b, 63) == ~2UL);

assert(rol!3(a) == 0b10000111);
assert(ror!3(a) == 0b00011110);