Протокол для обхода структур данных.

Функция Enum.into/2 использует этот протокол для вставки перечисляемого объекта в коллекцию:

iex> Enum.into([a: 1, b: 2], %{})
%{a: 1, b: 2}

Почему Коллектируемый?

Протокол Enumerable полезен для извлечения значений из коллекции. Для поддержки широкого диапазона значений функции, предоставляемые протоколом Enumerable, не сохраняют форму. Например, передача карты в Enum.map/2 всегда возвращает список.

Такой дизайн преднамеренный. Enumerable был разработан для поддержки бесконечных коллекций, ресурсов и других структур с фиксированной формой. Например, не имеет смысла вставлять значения в диапазон, так как он имеет фиксированную форму, где хранятся только пределы диапазона.

Модуль Collectable был разработан для заполнения пробела, оставленного протоколом Enumerable. Collectable.into/1 можно рассматривать как противоположность Enumerable.reduce/3. Если функции в Enumerable предназначены для извлечения значений, то Collectable.into/1 предназначен для сбора этих значений в структуру.

Примеры

Чтобы показать, как вручную использовать протокол Collectable, давайте поработаем с его реализацией для MapSet.

iex> {initial_acc, collector_fun} = Collectable.into(MapSet.new())
iex> updated_acc = Enum.reduce([1, 2, 3], initial_acc, fn elem, acc ->
...>   collector_fun.(acc, {:cont, elem})
...> end)
iex> collector_fun.(updated_acc, :done)
#MapSet<[1, 2, 3]>

Чтобы показать, как может быть реализован протокол, мы можем снова обратиться к реализации для MapSet. В этой реализации "сбор" элементов просто означает их вставку в множество с помощью MapSet.put/2.

defimpl Collectable, for: MapSet do
  def into(original) do
    collector_fun = fn
      set, {:cont, elem} -> MapSet.put(set, elem)
      set, :done -> set
      _set, :halt -> :ok
    end

    {original, collector_fun}
  end
end