DynamicSupervisor поведение

Надзиратель, который запускает дочерние процессы динамически.

Модуль Supervisor был разработан для обработки в основном статических дочерних процессов, которые запускаются в заданном порядке при запуске надзирателя. DynamicSupervisor запускается без дочерних процессов. Вместо этого, дочерние процессы запускаются по требованию через start_child/2. При завершении работы динамического надзирателя все дочерние процессы завершаются одновременно, без гарантии порядка.

Примеры

Динамический надзиратель запускается без дочерних процессов, стратегией управления (в настоящее время поддерживается только стратегия :one_for_one) и именем:

children = [
  {DynamicSupervisor, strategy: :one_for_one, name: MyApp.DynamicSupervisor}
]

Supervisor.start_link(children, strategy: :one_for_one)

Параметры, указанные в спецификации дочернего процесса, описаны в start_link/1.

После запуска динамического надзирателя мы можем запустить дочерние процессы с помощью start_child/2, который получает спецификацию дочернего процесса:

{:ok, agent1} = DynamicSupervisor.start_child(MyApp.DynamicSupervisor, {Agent, fn -> %{} end})
Agent.update(agent1, &Map.put(&1, :key, "value"))
Agent.get(agent1, & &1)
#=> %{key: "value"}

{:ok, agent2} = DynamicSupervisor.start_child(MyApp.DynamicSupervisor, {Agent, fn -> %{} end})
Agent.get(agent2, & &1)
#=> %{}

DynamicSupervisor.count_children(MyApp.DynamicSupervisor)
#=> %{active: 2, specs: 2, supervisors: 0, workers: 2}

Надзиратели, основанные на модулях

Аналогично Supervisor, динамические надзиратели также поддерживают надзирателей, основанных на модулях.

defmodule MyApp.DynamicSupervisor do
  # Automatically defines child_spec/1
  use DynamicSupervisor

  def start_link(init_arg) do
    DynamicSupervisor.start_link(__MODULE__, init_arg, name: __MODULE__)
  end

  @impl true
  def init(_init_arg) do
    DynamicSupervisor.init(strategy: :one_for_one)
  end
end

См. документацию по Supervisor, чтобы узнать, когда следует использовать надзирателей, основанных на модулях. Аннотация @doc сразу перед use DynamicSupervisor будет добавлена к сгенерированной функции child_spec/1.

Регистрация имен

Надзиратель подчиняется тем же правилам регистрации имен, что и GenServer. Подробнее об этих правилах см. в документации по GenServer.

Переход от Supervisor's :simple_one_for_one

В случае использования устаревшей стратегии :simple_one_for_one из модуля Supervisor, вы можете перейти к DynamicSupervisor несколькими шагами.

Представьте данный "старый" код:

defmodule MySupervisor do
  use Supervisor

  def start_link(init_arg) do
    Supervisor.start_link(__MODULE__, init_arg, name: __MODULE__)
  end

  def start_child(foo, bar, baz) do
    # This will start child by calling MyWorker.start_link(init_arg, foo, bar, baz)
    Supervisor.start_child(__MODULE__, [foo, bar, baz])
  end

  @impl true
  def init(init_arg) do
    children = [
      # Or the deprecated: worker(MyWorker, [init_arg])
      %{id: MyWorker, start: {MyWorker, :start_link, [init_arg]}}
    ]

    Supervisor.init(children, strategy: :simple_one_for_one)
  end
end

Он может быть обновлен до DynamicSupervisor следующим образом:

defmodule MySupervisor do
  use DynamicSupervisor

  def start_link(init_arg) do
    DynamicSupervisor.start_link(__MODULE__, init_arg, name: __MODULE__)
  end

  def start_child(foo, bar, baz) do
    # If MyWorker is not using the new child specs, we need to pass a map:
    # spec = %{id: MyWorker, start: {MyWorker, :start_link, [foo, bar, baz]}}
    spec = {MyWorker, foo: foo, bar: bar, baz: baz}
    DynamicSupervisor.start_child(__MODULE__, spec)
  end

  @impl true
  def init(init_arg) do
    DynamicSupervisor.init(
      strategy: :one_for_one,
      extra_arguments: [init_arg]
    )
  end
end

Разница в том, что DynamicSupervisor ожидает спецификацию дочернего процесса в момент вызова start_child/2, а не во время обратного вызова init. Если при инициализации заданы какие-либо начальные аргументы, такие как [initial_arg], их можно указать в флаге :extra_arguments функции DynamicSupervisor.init/1.

Резюме

Типы

init_option(): Параметры, задаваемые для start_link/1 и init/1
on_start_child(): Возвращаемые значения функций start_child
option(): Значения параметров, используемые функциями start*
strategy(): Поддерживаемые стратегии
sup_flags(): Флаги надзирателя, возвращаемые в init

Функции

child_spec(opts): Возвращает спецификацию для запуска динамического надзирателя под надзирателем.
count_children(supervisor): Возвращает карту, содержащую значения количества для надзирателя.
init(options): Получает набор options, который инициализирует динамический надзиратель.
start_child(supervisor, child_spec): Динамически добавляет спецификацию дочернего процесса к supervisor и запускает этот дочерний процесс.
start_link(options): Запускает надзирателя с заданными параметрами.
start_link(mod, init_arg, opts \\ []): Запускает процесс надзирателя, основанного на модуле, с заданными module и arg.
stop(supervisor, reason \\ :normal, timeout \\ :infinity): Синхронно останавливает данный надзиратель с заданным reason.
terminate_child(supervisor, pid): Завершает данный дочерний процесс, идентифицированный по pid.
which_children(supervisor): Возвращает список с информацией обо всех дочерних процессах.

Обратные вызовы

init(init_arg): Обратный вызов, вызываемый для запуска надзирателя и во время горячих обновлений кода.

Типы

init_option()

Спецификации

init_option() ::
  {:strategy, strategy()}
  | {:max_restarts, non_neg_integer()}
  | {:max_seconds, pos_integer()}
  | {:max_children, non_neg_integer() | :infinity}
  | {:extra_arguments, [term()]}

Параметры, передаваемые start_link/1 и init/1

on_start_child()

Спецификации

on_start_child() ::
  {:ok, pid()}
  | {:ok, pid(), info :: term()}
  | :ignore
  | {:error, {:already_started, pid()} | :max_children | term()}

Возвращаемые значения функций start_child

option()

Спецификации

option() :: GenServer.option()

Значения параметров, используемые функциями start*

strategy()

Спецификации

strategy() :: :one_for_one

Поддерживаемые стратегии

sup_flags()

Спецификации

sup_flags() :: %{
  strategy: strategy(),
  intensity: non_neg_integer(),
  period: pos_integer(),
  max_children: non_neg_integer() | :infinity,
  extra_arguments: [term()]
}

Флаги надзирателя, возвращаемые в init

Функции

child_spec(opts)

Возвращает спецификацию для запуска динамического надзирателя под надзирателем.

См. Supervisor.

count_children(supervisor)

Спецификации

count_children(Supervisor.supervisor()) :: %{
  specs: non_neg_integer(),
  active: non_neg_integer(),
  supervisors: non_neg_integer(),
  workers: non_neg_integer()
}

Возвращает карту, содержащую значения счётчиков для надзирателя.

Карта содержит следующие ключи:

:specs - количество дочерних процессов
:active - количество всех активно работающих дочерних процессов, управляемых этим надзирателем
:supervisors - количество всех надзирателей, независимо от того, жив ли дочерний процесс
:workers - количество всех рабочих процессов, независимо от того, жив ли дочерний процесс

init(options)

Спецификации

init([init_option()]) :: {:ok, sup_flags()}

Принимает набор options для инициализации динамического надзирателя.

Обычно вызывается в конце обратного вызова init/1 надзирателей на основе модулей. Дополнительную информацию см. в разделе "Надзиратели на основе модулей" в документации модуля.

options, полученные этой функцией, также поддерживаются start_link/1.

Эта функция возвращает кортеж, содержащий параметры надзирателя.

Примеры

def init(_arg) do
  DynamicSupervisor.init(max_children: 1000, strategy: :one_for_one)
end

Параметры

:strategy - параметр стратегии перезапуска. Единственное поддерживаемое значение - :one_for_one, что означает, что при завершении дочернего процесса другие дочерние процессы не завершаются. Подробнее о стратегиях можно узнать в документации модуля Supervisor.
:max_restarts - максимальное количество перезапусков, разрешенных за определённый промежуток времени. По умолчанию 3.
:max_seconds - промежуток времени, в течение которого применяется :max_restarts. По умолчанию 5.
:max_children - максимальное количество дочерних процессов, которые могут одновременно работать под этим надзирателем. При превышении :max_children, start_child/2 возвращает {:error, :max_children}. По умолчанию :infinity.
:extra_arguments - аргументы, которые добавляются перед аргументами, указанными в спецификации дочернего процесса, переданной в start_child/2. По умолчанию пустой список.

start_child(supervisor, child_spec)

Спецификации

start_child(
  Supervisor.supervisor(),
  Supervisor.child_spec()
  | {module(), term()}
  | module()
  | (old_erlang_child_spec :: :supervisor.child_spec())
) :: on_start_child()

Динамически добавляет спецификацию дочернего процесса к supervisor и запускает этот дочерний процесс.

child_spec должна быть допустимой спецификацией дочернего процесса, как подробно описано в разделе "Спецификация дочернего процесса" документации для Supervisor. Дочерний процесс будет запущен в соответствии с указанной спецификацией.

Если функция запуска дочернего процесса возвращает {:ok, child} или {:ok, child, info}, то спецификация дочернего процесса и PID добавляются к надзирателю, и эта функция возвращает то же самое значение.

Если функция запуска дочернего процесса возвращает :ignore, то дочерний процесс не добавляется в дерево надзора, и эта функция также возвращает :ignore.

Если функция запуска дочернего процесса возвращает кортеж с ошибкой или ошибочное значение, или если она завершается ошибкой, спецификация дочернего процесса отбрасывается, и эта функция возвращает {:error, error}, где error — это ошибка или ошибочное значение, возвращённое функцией запуска дочернего процесса, или причина ошибки, если она произошла.

Если у надзирателя уже есть N дочерних процессов таким образом, что N превышает количество :max_children, установленное при инициализации надзирателя (см. init/1), то эта функция возвращает {:error, :max_children}.

start_link(options)

Спецификации

start_link([option() | init_option()]) :: Supervisor.on_start()

Запускает надзирателя с заданными параметрами.

:strategy — обязательный параметр, и в настоящее время поддерживается значение :one_for_one.

Остальные параметры можно найти в документации init/1.

Параметр :name также может использоваться для регистрации имени надзирателя. Поддерживаемые значения описаны в разделе "Регистрация имени" в документации модуля GenServer.

Если надзиратель успешно запущен, эта функция возвращает {:ok, pid}, где pid — PID надзирателя. Если надзирателю присвоено имя, а процесс с указанным именем уже существует, функция возвращает {:error, {:already_started, pid}}, где pid — PID этого процесса.

Обратите внимание, что надзиратель, запущенный с помощью этой функции, связан с родительским процессом и завершается не только при сбоях, но и при завершении родительского процесса с причиной :normal.

start_link(mod, init_arg, opts \\ [])

Спецификации

start_link(module(), term(), [option()]) :: Supervisor.on_start()

Запускает процесс надзирателя на основе модуля с заданными module и arg.

Для запуска надзирателя вызывается обратный вызов init/1 в заданном module, с arg в качестве аргумента. Обратный вызов init/1 должен вернуть спецификацию надзирателя, которую можно создать с помощью функции init/1.

Если обратный вызов init/1 возвращает :ignore, эта функция также возвращает :ignore и надзиратель завершается с причиной :normal. Если произошла ошибка или возвращено некорректное значение, эта функция возвращает {:error, term}, где term — термин с информацией об ошибке, и надзиратель завершается с причиной term.

Параметр :name также может быть задан для регистрации имени надзирателя. Поддерживаемые значения описаны в разделе "Регистрация имени" в документации модуля GenServer.

stop(supervisor, reason \\ :normal, timeout \\ :infinity)

Спецификации

stop(Supervisor.supervisor(), reason :: term(), timeout()) :: :ok

Синхронно останавливает заданный надзиратель с заданной reason.

Возвращает :ok , если надзиратель завершается с заданной причиной. Если он завершается по другой причине, вызов завершается.

Эта функция сохраняет семантику OTP относительно отчётов об ошибках. Если причина отличается от :normal, :shutdown или {:shutdown, _}, регистрируется отчёт об ошибке.

terminate_child(supervisor, pid)

Спецификации

terminate_child(Supervisor.supervisor(), pid()) :: :ok | {:error, :not_found}

Завершает указанного дочернего процесса, идентифицированного по pid.

При успешном выполнении эта функция возвращает :ok. Если процесса с заданным PID нет, функция возвращает {:error, :not_found}.

which_children(supervisor)

Спецификации

which_children(Supervisor.supervisor()) :: [
  {:undefined, pid() | :restarting, :worker | :supervisor,
   :supervisor.modules()}
]

Возвращает список с информацией обо всех дочерних процессах.

Обратите внимание, что вызов этой функции при наблюдении за большим количеством дочерних процессов в условиях низкой памяти может вызвать исключение из-за нехватки памяти.

Функция возвращает список кортежей, содержащих:

id - всегда :undefined для динамических надзирателей
child - PID соответствующего дочернего процесса или атом :restarting , если процесс собирается перезапускаться
type - :worker или :supervisor , как определено в спецификации дочернего процесса
modules - как определено в спецификации дочернего процесса

Обратные вызовы

init(init_arg)

Спецификации

init(init_arg :: term()) :: {:ok, sup_flags()} | :ignore

Обратный вызов, вызываемый для запуска надзирателя и во время горячих обновлений кода.

Разработчики обычно вызывают DynamicSupervisor.init/1 в конце своего обратного вызова init, чтобы вернуть соответствующие флаги надзора.

© 2012 Plataformatec
Licensed under the Apache License, Version 2.0.
https://hexdocs.pm/elixir/1.10.4/DynamicSupervisor.html