Определяет API поставщика, который загружает конфигурацию во время запуска.

Поставщики конфигурации обычно используются во время релизов для загрузки внешней конфигурации во время запуска системы. Это делается путем запуска виртуальной машины с минимальным количеством запущенных приложений, затем вызова всех поставщиков и перезапуска системы. Это требует изменяемого конфигурационного файла на диске, так как результаты работы поставщиков записываются в файловую систему. Более подробную информацию о конфигурации во время выполнения см. в mix release.

Несколько конфигурационных файлов

Одно из распространенных применений поставщиков конфигурации — указание нескольких конфигурационных файлов в релизе. Elixir поставляется с одним поставщиком, называемым Config.Reader, который способен обрабатывать встроенные в Elixir конфигурационные файлы.

Например, предположим, что вы хотите перечислить некоторую базовую конфигурацию в встроенном файле config/runtime.exs Mix, но также хотите поддерживать дополнительные конфигурационные файлы. Для этого вы можете добавить это в часть def project вашего mix.exs.

releases: [
  demo: [
    config_providers: [
      {Config.Reader, {:system, "RELEASE_ROOT", "/extra_config.exs"}}
    ]
  ]
]

Вы можете разместить этот extra_config.exs файл в вашем релизе несколькими способами:

1. Если он доступен на хосте при сборке релиза, вы можете поместить его в «rel/overlays/extra_config.exs», и он будет автоматически скопирован в корень релиза.

2. Если он доступен на целевом компьютере во время развертывания, вы можете просто скопировать его в корень релиза как часть шага развертывания.

Теперь, после запуска системы, она загрузит как config/runtime.exs, так и extra_config.exs на ранней стадии процесса запуска. Вы можете узнать больше о вариантах на Config.Reader.

Настраиваемый поставщик конфигурации

Вы также можете реализовать настраиваемых поставщиков конфигурации, аналогично тому, как работает Config.Reader. Например, предположим, что вам нужно загрузить некоторую конфигурацию из файла JSON и загрузить ее в систему. Данный поставщик конфигурации будет выглядеть следующим образом:

defmodule JSONConfigProvider do
  @behaviour Config.Provider

  # Let's pass the path to the JSON file as config
  @impl true
  def init(path) when is_binary(path), do: path

  @impl true
  def load(config, path) do
    # We need to start any app we may depend on.
    {:ok, _} = Application.ensure_all_started(:jason)

    json = path |> File.read!() |> Jason.decode!()

    Config.Reader.merge(
      config,
      my_app: [
        some_value: json["my_app_some_value"],
        another_value: json["my_app_another_value"],
      ]
    )
  end
end

Затем, при указании релиза, вы можете указать поставщика в конфигурации релиза:

releases: [
  demo: [
    config_providers: [
      {JSONConfigProvider, "/etc/config.json"}
    ]
  ]
]