@spec absname(t()) :: binary()

Преобразует указанный путь в абсолютный.

В отличие от expand/1, попытки разрешить .., ., или ~ не предпринимается.

Примеры

Операционные системы семейства Unix

Path.absname("foo")
#=> "/usr/local/foo"

Path.absname("../x")
#=> "/usr/local/../x"

Windows

Path.absname("foo")
#=> "D:/usr/local/foo"

Path.absname("../x")
#=> "D:/usr/local/../x"

@spec absname(t(), t()) :: binary()

Создаёт путь от relative_to до path.

Если path уже является абсолютным путём, relative_to игнорируется. См. также relative_to/2.

В отличие от expand/2, попытки разрешить .., . или ~ не предпринимается.

Примеры

iex> Path.absname("foo", "bar")
"bar/foo"

iex> Path.absname("../x", "bar")
"bar/../x"

@spec basename(t()) :: binary()

Возвращает последнюю составляющую пути или сам путь, если он не содержит разделителей каталогов.

Примеры

iex> Path.basename("foo")
"foo"

iex> Path.basename("foo/bar")
"bar"

iex> Path.basename("lib/module/submodule.ex")
"submodule.ex"

iex> Path.basename("/")
""

@spec basename(t(), t()) :: binary()

Возвращает последнюю составляющую пути path с удалённым extension.

Эта функция должна использоваться для удаления конкретного расширения, которое может или не может быть.

Примеры

iex> Path.basename("~/foo/bar.ex", ".ex")
"bar"

iex> Path.basename("~/foo/bar.exs", ".ex")
"bar.exs"

iex> Path.basename("~/foo/bar.old.ex", ".ex")
"bar.old"

@spec dirname(t()) :: binary()

Возвращает компонент каталога пути path.

Примеры

iex> Path.dirname("/foo/bar.ex")
"/foo"

iex> Path.dirname("/foo/bar/baz.ex")
"/foo/bar"

iex> Path.dirname("/foo/bar/")
"/foo/bar"

iex> Path.dirname("bar.ex")
"."

@spec expand(t()) :: binary()

Преобразует путь в абсолютный, расширяя все . и .. компоненты и ведущий ~.

Примеры

Path.expand("/foo/bar/../baz")
#=> "/foo/baz"

@spec expand(t(), t()) :: binary()

Расширяет путь относительно пути, заданного в качестве второго аргумента, расширяя все . и .. символы.

Если путь уже является абсолютным, relative_to игнорируется.

Обратите внимание, что эта функция рассматривает path с ведущим ~ как абсолютный.

Второй аргумент сначала расширяется до абсолютного пути.

Примеры

# Assuming that the absolute path to baz is /quux/baz
Path.expand("foo/bar/../bar", "baz")
#=> "/quux/baz/foo/bar"

Path.expand("foo/bar/../bar", "/baz")
#=> "/baz/foo/bar"

Path.expand("/foo/bar/../bar", "/baz")
#=> "/foo/bar"

@spec extname(t()) :: binary()

Возвращает расширение последней составляющей пути path.

Поведение этой функции изменилось в Erlang/OTP 24 для имён файлов, начинающихся с точки и без расширения. Например, для файла с именем .gitignore, extname/1 теперь возвращает пустую строку, в то время как в предыдущих версиях Erlang/OTP возвращало бы ".gitignore". Это было сделано для соответствия поведению rootname/1, которое возвращает ".gitignore" в качестве имени (и поэтому оно также не может быть расширением).

См. basename/1 и rootname/1 для связанных функций извлечения информации из путей.

Примеры

iex> Path.extname("foo.erl")
".erl"

iex> Path.extname("~/foo/bar")
""

@spec join([t(), ...]) :: binary()

Объединяет список путей.

Эта функция должна использоваться для преобразования списка путей в один путь. Обратите внимание, что любые заключительные слэши удаляются при объединении.

Вызывает ошибку, если заданный список путей пустой.

Примеры

iex> Path.join(["~", "foo"])
"~/foo"

iex> Path.join(["foo"])
"foo"

iex> Path.join(["/", "foo", "bar/"])
"/foo/bar"

@spec join(t(), t()) :: binary()

Объединяет два пути.

Правый путь всегда будет преобразован в относительный формат, а любые заключительные слэши будут удалены при объединении.

Примеры

iex> Path.join("foo", "bar")
"foo/bar"

iex> Path.join("/foo", "/bar/")
"/foo/bar"

Функции в этом модуле поддерживают chardata, поэтому передача списка будет обрабатывать его как единое целое:

iex> Path.join("foo", ["bar", "fiz"])
"foo/barfiz"

iex> Path.join(["foo", "bar"], "fiz")
"foobar/fiz"

Используйте join/1, если вам нужно объединить список путей.

@spec relative(t()) :: binary()

Принудительно делает путь относительным.

Примеры

Операционные системы семейства Unix

Path.relative("/usr/local/bin")   #=> "usr/local/bin"
Path.relative("usr/local/bin")    #=> "usr/local/bin"
Path.relative("../usr/local/bin") #=> "../usr/local/bin"

Windows

Path.relative("D:/usr/local/bin") #=> "usr/local/bin"
Path.relative("usr/local/bin")    #=> "usr/local/bin"
Path.relative("D:bar.ex")         #=> "bar.ex"
Path.relative("/bar/foo.ex")      #=> "bar/foo.ex"

@spec relative_to(t(), t()) :: binary()

Возвращает данный path относительно заданного пути from.

Другими словами, эта функция пытается убрать префикс from из path.

Эта функция не запрашивает файловую систему, поэтому предполагает отсутствие символических ссылок между путями.

В случае, если прямой относительный путь не может быть найден, возвращает исходный путь.

Примеры

iex> Path.relative_to("/usr/local/foo", "/usr/local")
"foo"

iex> Path.relative_to("/usr/local/foo", "/")
"usr/local/foo"

iex> Path.relative_to("/usr/local/foo", "/etc")
"/usr/local/foo"

iex> Path.relative_to("/usr/local/foo", "/usr/local/foo")
"."

@spec relative_to_cwd(t()) :: binary()

Удобный способ получить путь, относительный к текущей рабочей директории.

Если по какой-то причине текущая рабочая директория не может быть получена, эта функция возвращает заданный path.

@spec rootname(t()) :: binary()

Возвращает path с удалённым extension.

Примеры

iex> Path.rootname("/foo/bar")
"/foo/bar"

iex> Path.rootname("/foo/bar.ex")
"/foo/bar"

@spec rootname(t(), t()) :: binary()

Возвращает path с удалённым extension.

Эта функция должна использоваться для удаления конкретного расширения, которое может или не может быть.

Примеры

iex> Path.rootname("/foo/bar.erl", ".erl")
"/foo/bar"

iex> Path.rootname("/foo/bar.erl", ".ex")
"/foo/bar.erl"

@spec safe_relative(t()) :: {:ok, binary()} | :error

Возвращает путь, относительный к текущей рабочей директории, защищённый от атак перебора каталогов.

То же, что и safe_relative_to/2 с текущей рабочей директорией в качестве второго аргумента. Если есть проблема с получением текущей рабочей директории, эта функция вызывает ошибку.

Примеры

iex> Path.safe_relative("foo")
{:ok, "foo"}

iex> Path.safe_relative("foo/../bar")
{:ok, "bar"}

iex> Path.safe_relative("foo/../..")
:error

iex> Path.safe_relative("/usr/local")
:error

@spec safe_relative_to(t(), t()) :: {:ok, binary()} | :error

Возвращает относительный путь, защищенный от атак перебора каталогов.

Указанный относительный путь очищается путём удаления .. и . компонентов.

Эта функция проверяет, что после расширения этих компонентов путь всё ещё «безопасен». Пути считаются небезопасными, если выполняется одно из следующих условий:

• Путь не является относительным, например "/foo/bar".

• Компонент .. мог бы привести к тому, что путь будет переходить выше корня relative_to.

• Символьная ссылка в пути указывает на элемент, расположенный выше корня relative_to.

Примеры

iex> Path.safe_relative_to("deps/my_dep/app.beam", "deps")
{:ok, "deps/my_dep/app.beam"}

iex> Path.safe_relative_to("deps/my_dep/./build/../app.beam", "deps")
{:ok, "deps/my_dep/app.beam"}

iex> Path.safe_relative_to("my_dep/../..", "deps")
:error

iex> Path.safe_relative_to("/usr/local", ".")
:error

@spec split(t()) :: [binary()]

Разделяет путь на список по разделителям пути.

Если задана пустая строка, возвращает пустой список.

В Windows путь разделяется на основе "\" и "/" разделителей, а буква диска, если она есть, всегда возвращается в нижнем регистре.

Примеры

iex> Path.split("")
[]

iex> Path.split("foo")
["foo"]

iex> Path.split("/foo/bar")
["/", "foo", "bar"]

@spec type(t()) :: :absolute | :relative | :volumerelative

Возвращает тип пути.

Примеры

Операционные системы семейства Unix

Path.type("/")                #=> :absolute
Path.type("/usr/local/bin")   #=> :absolute
Path.type("usr/local/bin")    #=> :relative
Path.type("../usr/local/bin") #=> :relative
Path.type("~/file")           #=> :relative

Windows

Path.type("D:/usr/local/bin") #=> :absolute
Path.type("usr/local/bin")    #=> :relative
Path.type("D:bar.ex")         #=> :volumerelative
Path.type("/bar/foo.ex")      #=> :volumerelative

@spec wildcard(
  t(),
  keyword()
) :: [binary()]

Проходит по путям в соответствии с заданным выражением glob и возвращает список совпадений.

Маска похожа на обычный путь, за исключением того, что следующие «символы подстановки» интерпретируются особым образом:

• ? - соответствует одному символу.

• * - соответствует любому количеству символов до конца имени файла, следующей точки или следующего слэша.

• ** - два смежных * в качестве одного шаблона будут соответствовать всем файлам и нулю или более каталогам и подкаталогам.

• [char1,char2,...] - соответствует любому из перечисленных символов; два символа, разделенные дефисом, соответствуют диапазону символов. Не добавляйте пробелы до и после запятой, так как в противном случае это будет соответствовать путям, содержащим сами пробелы.

• {item1,item2,...} - соответствует одному из вариантов. Не добавляйте пробелы до и после запятой, так как в противном случае это будет соответствовать путям, содержащим сами пробелы.

Другие символы представляют собой сами себя. Только пути с точным соответствием символов в той же позиции будут совпадать. Обратите внимание, что сопоставление регистрозависимое: "a" не будет соответствовать "A".

Разделители каталогов всегда должны быть записаны как /, даже в Windows. Вы можете вызвать Path.expand/1 для нормализации пути перед вызовом этой функции.

По умолчанию шаблоны * и ? не соответствуют файлам, начинающимся с точки .. См. опцию :match_dot в разделе «Параметры» ниже.

Параметры

• :match_dot - (boolean) если false, специальные символы подстановки * и ? не будут соответствовать файлам, начинающимся с точки (.). Если true, файлы, начинающиеся с . не будут обрабатываться специально. По умолчанию false.

Примеры

Представьте, что у вас есть каталог под названием projects с тремя проектами Elixir внутри: elixir, ex_doc, и plug. Вы можете найти все .beam файлы внутри каталога ebin каждого проекта следующим образом:

Path.wildcard("projects/*/ebin/**/*.beam")

Если вы хотите найти файлы как .beam так и .app , вы можете сделать это:

Path.wildcard("projects/*/ebin/**/*.{beam,app}")