Шаблоны и Гвардии

Elixir предоставляет сопоставление с образцом, которое позволяет нам утверждать форму или извлекать значения из структур данных. Шаблоны часто дополняются гвардиями, которые предоставляют разработчикам возможность выполнять более сложные проверки, хотя и ограниченные.

Эта страница описывает семантику шаблонов и гвардий, где они допускаются, и как их расширить.

Шаблоны

Шаблоны в Elixir состоят из переменных, литералов и синтаксиса, специфичного для структур данных. Одним из наиболее используемых конструкций для выполнения сопоставления с образцом является оператор совпадения (=):

iex> x = 1
1
iex> 1 = x
1

В примере выше, x начинается без значения и получает значение 1. Затем мы сравниваем значение x с литералом 1, что успешно выполняется, так как оба они 1.

Сопоставление x с 2 вызовет:

iex> 2 = x
** (MatchError) no match of right hand side value: 1

Шаблоны не являются двунаправленными. Если у вас есть переменная y, которая никогда не была присвоена (часто называется несвязанной переменной), и вы пишете 1 = y, будет выброшено сообщение об ошибке:

iex> 1 = y
** (CompileError) iex:2: undefined function y/0

Другими словами, шаблоны разрешены только в левой части =. Правая часть = следует стандартной семантике вычисления языка.

Теперь давайте рассмотрим правила сопоставления с образцом для каждой конструкции и для каждого соответствующего типа данных.

Переменные

Переменные в шаблонах всегда присваиваются:

iex> x = 1
1
iex> x = 2
2
iex> x
2

Другими словами, Elixir поддерживает перепривязку. В случае, если вы не хотите, чтобы значение переменной менялось, вы можете использовать оператор привязки (^):

iex> x = 1
1
iex> ^x = 2
** (MatchError) no match of right hand side value: 2

Если одна и та же переменная встречается дважды в одном и том же шаблоне, то они должны быть связаны с одним и тем же значением:

iex> {x, x} = {1, 1}
{1, 1}
iex> {x, x} = {1, 2}
** (MatchError) no match of right hand side value: {1, 2}

Переменная с подчеркиванием (_) имеет особое значение, так как она никогда не может быть связана ни с каким значением. Она особенно полезна, когда вам не нужно учитывать определенные значения в шаблоне:

iex> {_, integer} = {:not_important, 1}
{:not_important, 1}
iex> integer
1
iex> _
** (CompileError) iex:3: invalid use of _

Литералы (числа и атомы)

Атомы и числа (целые и вещественные) могут появляться в шаблонах и всегда представляются как есть. Например, атом будет совпадать только с атомом, если это один и тот же атом:

iex> :atom = :atom
:atom
iex> :atom = :another_atom
** (MatchError) no match of right hand side value: :another_atom

Аналогичное правило применяется к числам. Наконец, обратите внимание, что числа в шаблонах выполняют строгое сравнение. Другими словами, целые числа не совпадают с вещественными числами:

iex> 1 = 1.0
** (MatchError) no match of right hand side value: 1.0

Кортежи

Кортежи могут появляться в шаблонах с использованием синтаксиса фигурных скобок ({}). Кортеж в шаблоне будет соответствовать только кортежам того же размера, где каждый отдельный элемент кортежа также должен соответствовать:

iex> {:ok, integer} = {:ok, 13}
{:ok, 13}

# won't match due to different size
iex> {:ok, integer} = {:ok, 11, 13}
** (MatchError) no match of right hand side value: {:ok, 11, 13}

# won't match due to mismatch on first element
iex> {:ok, binary} = {:error, :enoent}
** (MatchError) no match of right hand side value: {:error, :enoent}

Списки

Списки могут появляться в шаблонах с использованием синтаксиса квадратных скобок ([]). Список в шаблоне будет соответствовать только спискам того же размера, где каждый отдельный элемент списка также должен соответствовать:

iex> [:ok, integer] = [:ok, 13]
[:ok, 13]

# won't match due to different size
iex> [:ok, integer] = [:ok, 11, 13]
** (MatchError) no match of right hand side value: [:ok, 11, 13]

# won't match due to mismatch on first element
iex> [:ok, binary] = [:error, :enoent]
** (MatchError) no match of right hand side value: [:error, :enoent]

В отличие от кортежей, списки также позволяют сопоставлять непустые списки, используя обозначение [head | tail], которое сопоставляется с head и tail списка:

iex> [head | tail] = [1, 2, 3]
[1, 2, 3]
iex> head
1
iex> tail
[2, 3]

Несколько элементов могут предшествовать конструкции | tail:

iex> [first, second | tail] = [1, 2, 3]
[1, 2, 3]
iex> tail
[3]

Обратите внимание, что [head | tail] не соответствует пустым спискам:

iex> [head | tail] = []
** (MatchError) no match of right hand side value: []

Так как списки символов представлены как список целых чисел, можно также выполнять сопоставление префиксов со списками символов с использованием оператора конкатенации списков (++):

iex> 'hello ' ++ world = 'hello world'
'hello world'
iex> world
'world'

Что эквивалентно сопоставлению с [?h, ?e, ?l, ?l, ?o, ?\s | world]. Сопоставления суффиксов (hello ++ ' world') не являются допустимыми шаблонами.

Карты

Карты могут появляться в шаблонах с использованием знака процента, за которым следуют фигурные скобки (%{}). В отличие от списков и кортежей, карты выполняют соответствие подмножеству. Это означает, что шаблон карты будет соответствовать любой другой карте, которая имеет по крайней мере все ключи в шаблоне.

Вот пример, где все ключи совпадают:

iex> %{name: name} = %{name: "meg"}
%{name: "meg"}
iex> name
"meg"

Вот пример, когда совпадает подмножество ключей:

iex> %{name: name} = %{name: "meg", age: 23}
%{age: 23, name: "meg"}
iex> name
"meg"

Если ключ в шаблоне недоступен в карте, то они не будут совпадать:

iex> %{name: name, age: age} = %{name: "meg"}
** (MatchError) no match of right hand side value: %{name: "meg"}

Обратите внимание, что пустая карта будет соответствовать всем картам, что контрастирует с кортежами и списками, где пустой кортеж или пустой список будут соответствовать только пустым кортежам и пустым спискам соответственно:

iex> %{} = %{name: "meg"}
%{name: "meg"}

Наконец, обратите внимание, что ключи карт в шаблонах всегда должны быть литералами или предварительно связанными переменными, сопоставленными с оператором привязки.

Структуры

Структуры могут появляться в шаблонах с использованием знака процента, имени модуля структуры или переменной, за которой следуют фигурные скобки (%{}).

Учитывая следующую структуру:

defmodule User do
  defstruct [:name]
end

Вот пример, где все ключи совпадают:

iex> %User{name: name} = %User{name: "meg"}
%User{name: "meg"}
iex> name
"meg"

Если неизвестный ключ указан, компилятор выбросит ошибку:

iex> %User{type: type} = %User{name: "meg"}
** (CompileError) iex: unknown key :type for struct User

Имя структуры можно извлечь, поместив переменную вместо имени модуля:

iex> %struct_name{} = %User{name: "meg"}
%User{name: "meg"}
iex> struct_name
User

Бинарные данные

Бинарные данные могут появляться в шаблонах с использованием синтаксиса двойного меньше-больше (<<>>). Бинарные данные в шаблоне могут соответствовать нескольким сегментам одновременно, каждый со своим типом, размером и единицей измерения:

iex> <<val::unit(8)-size(2)-integer>> = <<123, 56>>
"{8"
iex> val
31544

См. документацию для <<>> для полного определения сопоставления с образцом для бинарных данных.

Наконец, помните, что строки в Elixir закодированы в UTF-8 в виде бинарных данных. Это означает, что, подобно спискам символов, сопоставления префиксов со строками также возможны с использованием бинарного оператора конкатенации (<>):

iex> "hello " <> world = "hello world"
"hello world"
iex> world
"world"

Сопоставления суффиксов (hello <> " world") не являются допустимыми шаблонами.

Гвардии

Гвардии — это способ дополнения сопоставления с образцом более сложными проверками. Они допускаются в предопределенном наборе конструкций, где разрешено сопоставление с образцом, таких как определения функций, ветви case и другие.

Не все выражения разрешены в частях гвардии, а только некоторые из них. Это преднамеренное решение. Таким образом, Elixir (и Erlang) может убедиться, что во время выполнения гвардий ничего плохого не происходит и нигде не происходят мутации. Это также позволяет компилятору эффективно оптимизировать код, связанный с гвардиями.

Список разрешенных функций и операторов

Вы можете найти встроенный список гвардий в модуле Kernel. Вот обзор:

операторы сравнения (==, !=, ===, !==, <, <=, >, >=)
строго булевы операторы (and, or, not). Обратите внимание, что операторы &&, || и ! не разрешены, так как они не являются *строго* булевыми — то есть они не требуют, чтобы аргументы были булевыми
арифметические унарные операторы (+, -)
арифметические бинарные операторы +, -, *, /)
in и not in операторы (пока правая часть — список или диапазон)
функции "проверки типа" (is_list/1, is_number/1 и подобные)
функции, работающие со встроенными типами данных (abs/1, hd/1, map_size/1 и другие)
синтаксис map.field

Модуль Bitwise также включает несколько битовых операций Erlang как гвардий.

Макросы, построенные из любой комбинации вышеперечисленных гвардий, также являются допустимыми гвардиями — например, Integer.is_even/1. Дополнительная информация приведена в разделе «Пользовательские шаблоны и выражения гвардии», представленном ниже.

Зачем нужны гвардии

Давайте рассмотрим пример использования гвардии в предложении функции:

def empty_map?(map) when map_size(map) == 0, do: true
def empty_map?(map) when is_map(map), do: false

Гвардии начинаются с оператора when, за которым следует выражение гвардии. Предложение будет выполнено только в том случае, если выражение гвардии возвращает true. Несколько булевых условий могут быть объединены с помощью операторов and и or.

Написать функцию empty_map?/1 только с использованием сопоставления с образцом было бы невозможно (так как сопоставление с образцом на %{} соответствовало бы *любой* карте, а не только пустым).

Неуспешные гвардии

Предложение функции будет выполнено только в том случае, если его выражение гвардии оценивается как true. Если возвращается любое другое значение, предложение функции будет пропущено. В частности, гвардии не имеют понятия «истинное» или «ложное».

Например, представьте функцию, которая проверяет, что заголовок списка не является nil:

def not_nil_head?([head | _]) when head, do: true
def not_nil_head?(_), do: false

not_nil_head?(["some_value", "another_value"])
#=> false

Даже если заголовок списка не является nil , первое предложение для not_nil_head?/1 терпит неудачу, потому что выражение не оценивается как true, а как "some_value", поэтому выполняется второе предложение, которое возвращает false. Чтобы гвардия работала правильно, необходимо убедиться, что гвардия оценивается как true, как показано ниже:

def not_nil_head?([head | _]) when head != nil, do: true
def not_nil_head?(_), do: false

not_nil_head?(["some_value", "another_value"])
#=> true

Ошибки в гвардиях

В гвардиях, когда функции обычно вызывают исключения, они вместо этого заставляют гвардию потерпеть неудачу.

Например, функция tuple_size/1 работает только с кортежами. Если мы используем ее с чем-то другим, будет выброшено исключение аргумента:

iex> tuple_size("hello")
** (ArgumentError) argument error

Однако, при использовании в гвардиях соответствующее предложение вместо этого не будет сопоставлено, а не будет выброшено исключение:

iex> case "hello" do
...>   something when tuple_size(something) == 2 ->
...>     :worked
...>   _anything_else ->
...>     :failed
...> end
:failed

Во многих случаях мы можем воспользоваться этим. В приведенном выше коде мы использовали tuple_size/1 для проверки того, что заданное значение является кортежем и проверки его размера (вместо использования is_tuple(something) and tuple_size(something) == 2).

Однако, если у вашего условия проверки несколько условий, например, проверка на кортежи или карты, лучше вызывать функции проверки типа, такие как is_tuple/1, перед tuple_size/1, иначе всё условие проверки будет отклонено, если кортеж не задан. В качестве альтернативы, ваша функция может использовать несколько условий проверки, как показано в следующем разделе.

Несколько условий проверки в одном операторе

Существует дополнительный способ упрощения цепочки or выражений в условиях проверки: Elixir поддерживает запись "нескольких условий проверки" в одном операторе. Следующий код:

def is_number_or_nil(term) when is_integer(term) or is_float(term) or is_nil(term),
  do: :maybe_number
def is_number_or_nil(_other),
  do: :something_else

можно альтернативно записать как:

def is_number_or_nil(term)
    when is_integer(term)
    when is_float(term)
    when is_nil(term) do
  :maybe_number
end

def is_number_or_nil(_other) do
  :something_else
end

Если каждое выражение условия проверки всегда возвращает булево значение, оба формата эквивалентны. Однако, помните, что если любой вызов функции в условии проверки вызывает исключение, всё условие проверки отклоняется. Для иллюстрации этого, следующая функция не будет обнаруживать пустые кортежи:

defmodule Check do
  # If given a tuple, map_size/1 will raise, and tuple_size/1 will not be evaluated
  def empty?(val) when map_size(val) == 0 or tuple_size(val) == 0, do: true
  def empty?(_val), do: false
end

Check.empty?(%{})
#=> true

Check.empty?({})
#=> false # true was expected!

Это можно исправить, убедившись, что исключения не возникают, либо с помощью проверок типа, как is_map(val) and map_size(val) == 0, либо с помощью нескольких условий проверки, так что если исключение приводит к отклонению одного условия проверки, следующее условие оценивается.

defmodule Check do
  # If given a tuple, map_size/1 will raise, and the second guard will be evaluated
  def empty?(val)
      when map_size(val) == 0
      when tuple_size(val) == 0,
      do: true

  def empty?(_val), do: false
end

Check.empty?(%{})
#=> true

Check.empty?({})
#=> true

Где можно использовать шаблоны и условия проверки

В примерах выше мы использовали оператор совпадения (=) и операторы функции для демонстрации шаблонов и условий проверки соответственно. Вот список встроенных конструкций в Elixir, которые поддерживают шаблоны и условия проверки.

match?/2:

match?({:ok, value} when value > 0, {:ok, 13})

операторы функций:

def type(term) when is_integer(term), do: :integer
def type(term) when is_float(term), do: :float

case выражения:

case x do
  1 -> :one
  2 -> :two
  n when is_integer(n) and n > 2 -> :larger_than_two
end

анонимные функции (fn/1):

larger_than_two? = fn
  n when is_integer(n) and n > 2 -> true
  n when is_integer(n) -> false
end

for и with поддерживают шаблоны и условия проверки в левой части <-:
```
for x when x >= 0 <- [1, -2, 3, -4], do: x
```
with также поддерживает ключевое слово else, которое поддерживает сопоставление шаблонов и условия проверки.
try поддерживает шаблоны и условия проверки в catch и else
receive поддерживает шаблоны и условия проверки для сопоставления с полученными сообщениями.
пользовательские условия проверки также можно определить с помощью defguard/1 и defguardp/1. Пользовательское условие проверки может быть определено только на основе существующих условий проверки.

Обратите внимание, что оператор совпадения (=) не поддерживает условия проверки:

{:ok, binary} = File.read("some/file")

Пользовательские шаблоны и выражения условий проверки

Только перечисленные в этой странице конструкции допускаются в шаблонах и условиях проверки. Однако, мы можем воспользоваться макросами, чтобы написать пользовательские шаблоны и условия проверки, которые могут упростить наши программы или сделать их более специфичными для предметной области. В конечном счете, важным является то, что выход макросов сводится к комбинации вышеупомянутых конструкций.

Например, модуль Record в Elixir предоставляет ряд макросов для использования в шаблонах и условиях проверки, позволяющих кортежам иметь именованные поля во время компиляции.

Для определения собственных условий проверки Elixir даже предоставляет удобства в defguard и defguardp. Давайте рассмотрим быстрый пример: мы хотим проверить, является ли аргумент чётным или нечётным целым числом. С помощью сопоставления шаблонов это невозможно, так как существует бесконечное число целых чисел, и поэтому мы не можем сопоставить шаблон с каждым из них. Поэтому мы должны использовать условия проверки. Мы сосредоточимся только на проверке чётных чисел, так как проверка нечётных чисел почти идентична.

Такое условие проверки будет выглядеть так:

def my_function(number) when is_integer(number) and rem(number, 2) == 0 do
  # do stuff
end

Было бы повторяющимся писать каждый раз, когда нам нужна эта проверка. Вместо этого вы можете использовать defguard/1 и defguardp/1 для создания макросов условий проверки. Вот пример:

defmodule MyInteger do
  defguard is_even(term) when is_integer(term) and rem(term, 2) == 0
end

и затем:

import MyInteger, only: [is_even: 1]

def my_function(number) when is_even(number) do
  # do stuff
end

Хотя можно создавать пользовательские условия проверки с помощью макросов, рекомендуется определять их с помощью defguard/1 и defguardp/1, которые выполняют дополнительные проверки на этапе компиляции.

← Предыдущая страница Операторы

Следующая страница → Справочник по синтаксису

© 2012 Plataformatec
Licensed under the Apache License, Version 2.0.
https://hexdocs.pm/elixir/1.14.1/patterns-and-guards.html