Config.Providerповедение

Определяет API провайдера, который загружает конфигурацию во время загрузки.

Провайдеры конфигурации обычно используются во время релизов для загрузки внешней конфигурации во время загрузки системы. Это делается путём запуска виртуальной машины с минимальным количеством работающих приложений, затем вызовом всех провайдеров и перезапуском системы. Это требует изменяемого конфигурационного файла на диске, так как результаты работы провайдеров записываются в файловую систему. Для получения дополнительной информации о конфигурации во время выполнения см. mix release.

Несколько конфигурационных файлов

Одно из распространённых применений провайдеров конфигурации — указание нескольких конфигурационных файлов в релизе. Elixir поставляется с одним провайдером, называемым Config.Reader, который может обрабатывать встроенные конфигурационные файлы Elixir.

Например, предположим, что вы хотите отобразить некоторую базовую конфигурацию в встроенном config/runtime.exs файле Mix, но также хотите поддерживать дополнительные конфигурационные файлы. Для этого вы можете добавить это в раздел def project вашего mix.exs.

releases: [
  demo: [
    config_providers: [
      {Config.Reader, {:system, "RELEASE_ROOT", "/extra_config.exs"}}
    ]
  ]
]

Вы можете поместить этот extra_config.exs файл в свой релиз несколькими способами:

1. Если он доступен на хосте во время сборки релиза, вы можете поместить его в "rel/overlays/extra_config.exs", и он будет автоматически скопирован в корень релиза.

2. Если он доступен на целевом устройстве во время развертывания, вы можете просто скопировать его в корень релиза как шаг в вашем процессе развертывания.

Теперь после загрузки системы она загрузит как config/runtime.exs, так и extra_config.exs на ранней стадии процесса загрузки. Вы можете узнать больше об опциях на Config.Reader.

Пользовательский провайдер конфигурации

Вы также можете реализовать пользовательские провайдеры конфигурации, аналогично тому, как работает Config.Reader. Например, предположим, что вам нужно загрузить конфигурацию из файла JSON и загрузить её в систему. Данный провайдер конфигурации будет выглядеть следующим образом:

defmodule JSONConfigProvider do
  @behaviour Config.Provider

  # Let's pass the path to the JSON file as config
  @impl true
  def init(path) when is_binary(path), do: path

  @impl true
  def load(config, path) do
    # We need to start any app we may depend on.
    {:ok, _} = Application.ensure_all_started(:jason)

    json = path |> File.read!() |> Jason.decode!()

    Config.Reader.merge(
      config,
      my_app: [
        some_value: json["my_app_some_value"],
        another_value: json["my_app_another_value"],
      ]
    )
  end
end

Затем, при указании вашего релиза, вы можете указать провайдера в конфигурации релиза:

releases: [
  demo: [
    config_providers: [
      {JSONConfigProvider, "/etc/config.json"}
    ]
  ]
]