Порт

Функции для взаимодействия с внешним миром через порты.

Порты предоставляют механизм для запуска процессов операционной системы, внешних по отношению к Erlang VM, и взаимодействия с ними посредством обмена сообщениями.

Пример

iex> port = Port.open({:spawn, "cat"}, [:binary])
iex> send(port, {self(), {:command, "hello"}})
iex> send(port, {self(), {:command, "world"}})
iex> flush()
{#Port<0.1444>, {:data, "hello"}}
{#Port<0.1444>, {:data, "world"}}
iex> send(port, {self(), :close})
:ok
iex> flush()
{#Port<0.1464>, :closed}
:ok

В приведенном примере мы создали новый порт, который выполняет программу cat. cat — это программа, доступная в операционных системах семейства Unix, которая получает данные с нескольких входных потоков и конкатенирует их в выходе.

После создания порта мы отправили ему два команды в виде сообщений, используя send/2. Первое сообщение имеет двоичную нагрузку "hello", а второе — "world".

После отправки этих двух сообщений мы вызвали вспомогательную функцию IEx flush(), которая вывела все полученные от порта сообщения; в данном случае, мы получили "hello" и "world" обратно. Обратите внимание, что сообщения находятся в двоичном формате, потому что мы передали опцию :binary при открытии порта в Port.open/2. Без этой опции она бы вернула список байтов.

После завершения всех операций мы закрыли порт.

Elixir предоставляет множество удобств для работы с портами, а также некоторые недостатки. Мы рассмотрим их ниже.

API сообщений и функций

Существуют два API для работы с портами. Это может быть асинхронное взаимодействие через обмен сообщениями, как в примере выше, или вызов функций этого модуля.

Сообщения, поддерживаемые портами, и соответствующие функции API перечислены ниже:

• {pid, {:command, binary}} — отправляет заданные данные в порт. См. command/3.

• {pid, :close} — закрывает порт. Если порт еще не закрыт, он ответит сообщением {port, :closed} после очистки своих буферов и фактического закрытия. См. close/1.

• {pid, {:connect, new_pid}} — устанавливает new_pid в качестве нового владельца порта. После открытия порта порт связывается и подключается к вызывающему процессу, а общение с портом происходит только через подключенный процесс. Это сообщение делает new_pid новыми подключенными процессами. Если порт не завершил работу, он ответит старому владельцу сообщением {port, :connected}. См. connect/2.

В свою очередь, порт отправит подключенному процессу следующие сообщения:

• {port, {:data, data}} — данные, отправленные портом
• {port, :closed} — ответ на сообщение {pid, :close}
• {port, :connected} — ответ на сообщение {pid, {:connect, new_pid}}
• {:EXIT, port, reason} — сигналы завершения в случае сбоя порта. Если причина не :normal, это сообщение будет получено только если процесс-владелец обрабатывает сигналы завершения

Механизмы открытия

Порт можно открыть с помощью четырех основных механизмов.

В качестве краткого резюме, отдавайте предпочтение параметрам :spawn и :spawn_executable, упомянутым ниже. Другие два параметра, :spawn_driver и :fd, предназначены для расширенного использования внутри VM. Также рассмотрите использование System.cmd/3, если вам нужно только выполнить программу и получить ее возвращаемое значение.

spawn

Кортеж :spawn получает двоичные данные, которые будут выполнены как полное вызов. Например, мы можем использовать его для прямого вызова "echo hello":

iex> port = Port.open({:spawn, "echo hello"}, [:binary])
iex> flush()
{#Port<0.1444>, {:data, "hello\n"}}

:spawn извлечет имя программы из аргумента и пройдется по переменной окружения $PATH вашей операционной системы, ища соответствующую программу.

Хотя это удобно, это означает, что невозможно вызвать исполняемый файл, имеющий пробелы в имени или любом из его аргументов. По этим причинам чаще всего предпочтительно использовать :spawn_executable.

spawn_executable

Spawn executable — более ограниченная и явная версия spawn. Она ожидает полные пути к исполняемому файлу, который вы хотите выполнить. Если они находятся в вашей $PATH, вы можете получить их, вызвав System.find_executable/1:

iex> path = System.find_executable("echo")
iex> port = Port.open({:spawn_executable, path}, [:binary, args: ["hello world"]])
iex> flush()
{#Port<0.1380>, {:data, "hello world\n"}}

При использовании :spawn_executable, список аргументов можно передать через параметр :args, как показано выше. Полный список параметров см. в документации для функции Erlang :erlang.open_port/2.

fd

Параметр имени :fd позволяет разработчикам получить доступ к дескрипторам файлов in и out, используемых Erlang VM. Вы будете использовать их только в том случае, если вы переиспользуете основные части системы выполнения, такие как процессы :user и :shell.

Процессы операционной системы-зомби

Порт можно закрыть с помощью функции close/1 или отправкой сообщения {pid, :close}. Однако, если VM аварийно завершит работу, долго выполняемая программа, запущенная портом, останется с закрытыми каналами stdin и stdout, но не будет автоматически завершена.

Хотя большинство инструментов командной строки Unix завершатся после закрытия каналов связи, не все приложения командной строки сделают это. Вы можете легко проверить это, запустив порт, а затем отключив VM и проверив в вашей операционной системе, все еще ли работает процесс порта.

Хотя мы рекомендуем плавное завершение, обнаруживая, был ли закрыт stdin/stdout, мы не всегда контролируем, как завершается стороннее программное обеспечение. В таких случаях вы можете обернуть приложение в скрипт, который проверяет stdin. Вот такой скрипт, который подтверждено работает в оболочках bash:

#!/usr/bin/env bash

# Start the program in the background
exec "$@" &
pid1=$!

# Silence warnings from here on
exec >/dev/null 2>&1

# Read from stdin in the background and
# kill running program when stdin closes
exec 0<&0 $(
  while read; do :; done
  kill -KILL $pid1
) &
pid2=$!

# Clean up
wait $pid1
ret=$?
kill -KILL $pid2
exit $ret

Обратите внимание, что программа выше перехватывает stdin, поэтому вы не сможете общаться с лежащим в основе программным обеспечением через stdin (с положительной стороны, программное обеспечение, которое считывает stdin, обычно завершается при закрытии stdin).

Теперь вместо:

Port.open(
  {:spawn_executable, "/path/to/program"},
  args: ["a", "b", "c"]
)

Вы можете вызвать:

Port.open(
  {:spawn_executable, "/path/to/wrapper"},
  args: ["/path/to/program", "a", "b", "c"]
)