Диапазон

Диапазоны представляют последовательность нуля, одного или многих возрастающих или убывающих целых чисел с общим разностным значением, называемым шагом.

Наиболее распространённый способ создания и сопоставления с диапазонами — это обозначения first..last и first..last//step, автоматически импортированные из Kernel:

iex> 1 in 1..10
true
iex> 5 in 1..10
true
iex> 10 in 1..10
true

Диапазоны всегда включают конечные значения. Когда определён шаг, целые числа будут принадлежать диапазону только в том случае, если они соответствуют шагу:

iex> 5 in 1..10//2
true
iex> 4 in 1..10//2
false

При определении диапазона без шага шаг будет определён на основе первой и последней позиции диапазона. Если last >= first, это будет возрастающий диапазон с шагом 1. В противном случае это убывающий диапазон. Однако следует отметить, что неявные убывающие диапазоны устарели. Поэтому, если вам нужен убывающий диапазон от 3 до 1, предпочтительнее написать 3..1//-1 вместо этого.

../0 также может быть использован как сокращение для создания диапазона 0..-1//1, также известного как диапазон полного среза:

iex> ..
0..-1//1

Сферы применения

Диапазоны обычно используются в Elixir для двух целей: как коллекция или для представления среза другой структуры данных.

Диапазоны как коллекции

Диапазоны в Elixir являются перечисляемыми и, следовательно, могут быть использованы с модулем Enum:

iex> Enum.to_list(1..3)
[1, 2, 3]
iex> Enum.to_list(3..1//-1)
[3, 2, 1]
iex> Enum.to_list(1..5//2)
[1, 3, 5]

Диапазоны также могут содержать единственный элемент:

iex> Enum.to_list(1..1)
[1]
iex> Enum.to_list(1..1//2)
[1]

Или даже не содержать элементов вообще:

iex> Enum.to_list(10..0//1)
[]
iex> Enum.to_list(0..10//-1)
[]

Диапазон полного среза, возвращаемый ../0, представляет собой пустую коллекцию:

iex> Enum.to_list(..)
[]

Диапазоны как срезы

Диапазоны также часто используются для срезов коллекций. Вы можете использовать их для среза строк или любых перечисляемых объектов:

iex> String.slice("elixir", 1..4)
"lixi"
iex> Enum.slice([0, 1, 2, 3, 4, 5], 1..4)
[1, 2, 3, 4]

В этих случаях первые и последние значения диапазона отображаются на позиции в коллекциях.

Если указано отрицательное число, оно отображается на позицию с конца:

iex> String.slice("elixir", 1..-2//1)
"lixi"
iex> Enum.slice([0, 1, 2, 3, 4, 5], 1..-2//1)
[1, 2, 3, 4]

Диапазон 0..-1//1, возвращаемый ../0, возвращает коллекцию как есть, поэтому он называется диапазоном полного среза:

iex> String.slice("elixir", ..)
"elixir"
iex> Enum.slice([0, 1, 2, 3, 4, 5], ..)
[0, 1, 2, 3, 4, 5]

Определение

Возрастающий диапазон first..last//step — это диапазон от first до last с возрастанием на step, где step должно быть положительным целым числом, а все значения v должны быть first <= v and v <= last. Таким образом, диапазон 10..0//1 является пустым диапазоном, потому что нет значения v , которое 10 <= v and v <= 0.

Аналогично, убывающий диапазон first..last//step — это диапазон от first до last с убыванием на step, где step должно быть отрицательным целым числом, а значения v должны быть first >= v and v >= last. Таким образом, диапазон 0..10//-1 является пустым диапазоном, потому что нет значения v , которое 0 >= v and v >= 10.

Представление

Внутри диапазоны представлены как структуры:

iex> range = 1..9//2
1..9//2
iex> first..last//step = range
iex> first
1
iex> last
9
iex> step
2
iex> range.step
2

Вы можете напрямую получить доступ к полям диапазона (first, last, и step), но не должны их изменять или создавать диапазоны вручную. Вместо этого используйте соответствующие операторы или new/2 и new/3.

Диапазоны реализуют протокол Enumerable с версией для эффективного использования памяти всех вызовов обратного вызова Enumerable:

iex> range = 1..10
1..10
iex> Enum.reduce(range, 0, fn i, acc -> i * i + acc end)
385
iex> Enum.count(range)
10
iex> Enum.member?(range, 11)
false
iex> Enum.member?(range, 8)
true

Такие вызовы функций эффективны с точки зрения памяти, независимо от размера диапазона. Реализация протокола Enumerable использует логику, основанную только на конечных значениях, и не материализует весь список целых чисел.