Указывает API поставщика, который загружает конфигурацию во время загрузки.

Поставщики конфигурации обычно используются во время релизов для загрузки внешней конфигурации во время загрузки системы. Это делается путём запуска виртуальной машины с минимальным количеством запущенных приложений, затем вызова всех поставщиков и перезапуска системы. Это требует изменяемого конфигурационного файла на диске, так как результаты работы поставщиков записываются в файловую систему. Для получения дополнительной информации о конфигурации во время выполнения, см. mix release.

Множественные файлы конфигурации

Одно из распространённых применений поставщиков конфигурации заключается в указании нескольких файлов конфигурации в релизе. Elixir поставляется с одним поставщиком, называемым Config.Reader, который может обрабатывать встроенные файлы конфигурации Elixir.

Например, предположим, что вы хотите вывести некоторую базовую конфигурацию в встроенном файле config/runtime.exs Mix, но также хотите поддерживать дополнительные файлы конфигурации. Для этого вы можете добавить это в раздел def project вашего mix.exs.

releases: [
  demo: [
    config_providers: [
      {Config.Reader, {:system, "RELEASE_ROOT", "/extra_config.exs"}}
    ]
  ]
]

Вы можете разместить этот extra_config.exs файл в своём релизе несколькими способами:

1. Если он доступен на хосте во время сборки релиза, вы можете разместить его в "rel/overlays/extra_config.exs", и он будет автоматически скопирован в корень релиза.

2. Если он доступен на целевом устройстве во время развертывания, вы можете просто скопировать его в корень релиза в качестве шага вашего развертывания.

Теперь, после загрузки системы, она загрузит как config/runtime.exs , так и extra_config.exs в начале процесса загрузки. Вы можете узнать больше об опциях на Config.Reader.

Пользовательский поставщик конфигурации

Вы также можете реализовать пользовательских поставщиков конфигурации, аналогично тому, как работает Config.Reader. Например, предположим, что вам нужно загрузить некоторые настройки из файла JSON и загрузить их в систему. Данный поставщик конфигурации будет выглядеть следующим образом:

defmodule JSONConfigProvider do
  @behaviour Config.Provider

  # Let's pass the path to the JSON file as config
  @impl true
  def init(path) when is_binary(path), do: path

  @impl true
  def load(config, path) do
    # We need to start any app we may depend on.
    {:ok, _} = Application.ensure_all_started(:jason)

    json = path |> File.read!() |> Jason.decode!()

    Config.Reader.merge(
      config,
      my_app: [
        some_value: json["my_app_some_value"],
        another_value: json["my_app_another_value"],
      ]
    )
  end
end

Затем, при указании релиза, вы можете указать поставщика в конфигурации релиза:

releases: [
  demo: [
    config_providers: [
      {JSONConfigProvider, "/etc/config.json"}
    ]
  ]
]