Source Структуры

Мы узнали о картах в предыдущих главах:

iex> map = %{a: 1, b: 2}
%{a: 1, b: 2}
iex> map[:a]
1
iex> %{map | a: 3}
%{a: 3, b: 2}

Структуры — это расширения, построенные поверх карт, которые обеспечивают проверки на этапе компиляции и значения по умолчанию.

Определение структур

Для определения структуры используется конструкция defstruct/1:

iex> defmodule User do
...>   defstruct name: "John", age: 27
...> end

Список ключевых слов, используемый с defstruct, определяет, какие поля будет иметь структура, а также их значения по умолчанию. Структуры принимают имя модуля, в котором они определены. В приведенном выше примере мы определили структуру с именем User.

Теперь мы можем создавать User структуры, используя синтаксис, аналогичный синтаксису создания карт:

iex> %User{}
%User{age: 27, name: "John"}
iex> %User{name: "Jane"}
%User{age: 27, name: "Jane"}

Структуры обеспечивают гарантии на этапе компиляции, что будут разрешены только поля, определенные с помощью defstruct:

iex> %User{oops: :field}
** (KeyError) key :oops not found expanding struct: User.__struct__/1

Доступ к структурам и их обновление

Структуры используют тот же синтаксис для доступа к полям и их обновления, что и карты с фиксированными ключами:

iex> john = %User{}
%User{age: 27, name: "John"}
iex> john.name
"John"
iex> jane = %{john | name: "Jane"}
%User{age: 27, name: "Jane"}
iex> %{jane | oops: :field}
** (KeyError) key :oops not found in: %User{age: 27, name: "Jane"}

При использовании синтаксиса обновления (|) Elixir понимает, что новые ключи не будут добавлены в структуру, позволяя картам внизу разделять свою структуру в памяти. В приведенном выше примере john и jane используют одинаковую структуру ключей в памяти.

Структуры также могут использоваться в сопоставлении с образцом, как для сопоставления со значением конкретного ключа, так и для проверки, что сопоставляемое значение является структурой того же типа, что и сопоставляемое значение.

iex> %User{name: name} = john
%User{age: 27, name: "John"}
iex> name
"John"
iex> %User{} = %{}
** (MatchError) no match of right hand side value: %{}

Структуры представляют собой обычные карты

Структуры — это просто карты с «специальным» полем с именем __struct__, которое хранит имя структуры:

iex> is_map(john)
true
iex> john.__struct__
User

Однако структуры не наследуют никаких протоколов карт. Например, вы не можете перечислить или получить доступ к структуре:

iex> john = %User{}
%User{age: 27, name: "John"}
iex> john[:name]
** (UndefinedFunctionError) function User.fetch/2 is undefined (User does not implement the Access behaviour)
             User.fetch(%User{age: 27, name: "John"}, :name)
iex> Enum.each(john, fn {field, value} -> IO.puts(value) end)
** (Protocol.UndefinedError) protocol Enumerable not implemented for %User{age: 27, name: "John"} of type User (a struct)

Структуры вместе с протоколами предоставляют одну из самых важных функций для разработчиков Elixir: полиморфизм данных. Это то, что мы рассмотрим в следующей главе.

Значения по умолчанию и обязательные ключи

Если при определении структуры вы не укажете значение по умолчанию для ключа, будет предположено nil:

iex> defmodule Product do
...>   defstruct [:name]
...> end
iex> %Product{}
%Product{name: nil}

Вы можете определить структуру, объединяющую оба поля со явными значениями по умолчанию и неявными nil значениями. В этом случае вы должны сначала указать поля, которые неявно имеют значение nil:

iex> defmodule User do
...>   defstruct [:email, name: "John", age: 27]
...> end
iex> %User{}
%User{age: 27, email: nil, name: "John"}

Выполнение в обратном порядке вызовет синтаксическую ошибку:

iex> defmodule User do
...>   defstruct [name: "John", age: 27, :email]
...> end
** (SyntaxError) iex:107: unexpected expression after keyword list. Keyword lists must always come last in lists and maps.

Вы также можете потребовать, чтобы определенные ключи были указаны при создании структуры, используя атрибут модуля @enforce_keys:

iex> defmodule Car do
...>   @enforce_keys [:make]
...>   defstruct [:model, :make]
...> end
iex> %Car{}
** (ArgumentError) the following keys must also be given when building struct Car: [:make]
    expanding struct: Car.__struct__/1

Требование ключей обеспечивает простую гарантию на этапе компиляции, чтобы помочь разработчикам при создании структур. Она не применяется к обновлениям и не обеспечивает никакой проверки значений.