Определяет API провайдера, загружающего конфигурацию во время загрузки.

Провайдеры конфигурации обычно используются во время релизов для загрузки внешней конфигурации во время запуска системы. Это делается путём запуска виртуальной машины с минимальным количеством работающих приложений, вызовом всех провайдеров и последующим перезапуском системы. Это требует изменяемого файла конфигурации на диске, так как результаты работы провайдеров записываются в файловую систему. Дополнительную информацию о конфигурации во время выполнения см. в mix release.

Множественные файлы конфигурации

Одним из распространённых способов использования провайдеров конфигурации является указание нескольких файлов конфигурации в релизе. Elixir поставляется с одним провайдером под названием Config.Reader, способным обрабатывать встроенные файлы конфигурации Elixir.

Например, предположим, что вы хотите вывести некоторую базовую конфигурацию в встроенном файле config/runtime.exs Mix, но также хотите поддерживать дополнительные файлы конфигурации. Для этого вы можете добавить это в раздел def project вашей mix.exs.

releases: [
  demo: [
    config_providers: [
      {Config.Reader, {:system, "RELEASE_ROOT", "/extra_config.exs"}}
    ]
  ]
]

Вы можете поместить этот extra_config.exs файл в свой релиз несколькими способами:

1. Если он доступен на хосте при сборке релиза, вы можете поместить его в "rel/overlays/extra_config.exs", и он будет автоматически скопирован в корень релиза.

2. Если он доступен на целевой машине во время развертывания, вы можете просто скопировать его в корень релиза в качестве шага в процессе развертывания.

Теперь, когда система загрузится, она загрузит как config/runtime.exs , так и extra_config.exs на ранней стадии процесса загрузки. Вы можете узнать больше об этом на Config.Reader.

Настройка провайдера конфигурации

Вы также можете реализовать собственные провайдеры конфигурации, аналогично тому, как работает Config.Reader. Например, предположим, что вам нужно загрузить некоторую конфигурацию из файла JSON и загрузить её в систему. Данный провайдер конфигурации будет выглядеть так:

defmodule JSONConfigProvider do
  @behaviour Config.Provider

  # Let's pass the path to the JSON file as config
  @impl true
  def init(path) when is_binary(path), do: path

  @impl true
  def load(config, path) do
    # We need to start any app we may depend on.
    {:ok, _} = Application.ensure_all_started(:jason)

    json = path |> File.read!() |> Jason.decode!()

    Config.Reader.merge(
      config,
      my_app: [
        some_value: json["my_app_some_value"],
        another_value: json["my_app_another_value"],
      ]
    )
  end
end

Затем, при определении вашего релиза, вы можете указать провайдера в конфигурации релиза:

releases: [
  demo: [
    config_providers: [
      {JSONConfigProvider, "/etc/config.json"}
    ]
  ]
]