Источник Написание документации

Elixir рассматривает документацию как объект первого класса. Документация должна быть лёгкой для написания и лёгкой для чтения. В этом руководстве вы узнаете, как писать документацию на Elixir, охватывая такие конструкции, как атрибуты модулей, стилистические рекомендации и doctest.

Markdown

Документация Elixir написана с использованием Markdown. В интернете существует множество руководств по Markdown, мы рекомендуем руководство с GitHub в качестве отправной точки:

• Основные синтаксические конструкции форматирования и написания текста

Атрибуты модулей

Документация на Elixir обычно прикрепляется к атрибутам модулей. Посмотрим на пример:

defmodule MyApp.Hello do
  @moduledoc """
  This is the Hello module.
  """
  @moduledoc since: "1.0.0"

  @doc """
  Says hello to the given `name`.

  Returns `:ok`.

  ## Examples

      iex> MyApp.Hello.world(:john)
      :ok

  """
  @doc since: "1.3.0"
  def world(name) do
    IO.puts("hello #{name}")
  end
end

Атрибут @moduledoc используется для добавления документации к модулю. Атрибут @doc используется перед функцией для предоставления документации для неё. Помимо указанных выше атрибутов, @typedoc также может использоваться для добавления документации к типам, определённым в рамках типов спецификаций, которые мы рассмотрим позже. Elixir также позволяет добавлять метаданные к документации, передавая список ключевых слов в @doc и аналогичные функции.

Аргументы функций

При документировании функции имена аргументов выводятся компилятором. Например:

def size(%{size: size}) do
  size
end

Компилятор выведет этот аргумент как map. Иногда вывод может быть не оптимальным, особенно если функция содержит несколько разделов с сопоставлением аргумента на различных значениях в каждом случае. Вы можете указать правильные имена для документации, объявив только заголовок функции в любой момент до реализации:

def size(map_with_size)
def size(%{size: size}) do
  size
end

Метаданные документации

Elixir позволяет разработчикам прикреплять произвольные метаданные к документации. Это делается путём передачи списка ключевых слов соответствующему атрибуту (таким как @moduledoc, @typedoc, и @doc). Распространёнными метаданными являются :since, которые анотируют версию, в которой был добавлен конкретный модуль, функция, тип или обратный вызов, как показано в примере выше.

Ещё одними распространёнными метаданными являются :deprecated, которые генерируют предупреждение в документации, объясняя, что их использование не рекомендуется:

@doc deprecated: "Use Foo.bar/2 instead"

Обратите внимание, что ключ :deprecated не выдаёт предупреждение при вызове функций разработчиками. Если вы хотите, чтобы код также выдавал предупреждение, вы можете использовать атрибут @deprecated:

@deprecated "Use Foo.bar/2 instead"

Метаданные могут иметь любой ключ. Инструменты документации часто используют метаданные для предоставления большего количества данных читателям и обогащения пользовательского опыта.

Рекомендации

При написании документации:

• Первый абзац документации должен быть кратким и простым, обычно в одну строку. Инструменты, такие как ExDoc, используют первую строку для генерации сводки.

• Ссылайтесь на модули по их полному имени.

  Markdown использует обратные кавычки (`) для цитирования кода. Elixir дополняет это, автоматически генерируя ссылки, когда упоминаются имена модулей или функций. По этой причине всегда используйте полные имена модулей. Если у вас есть модуль под названием MyApp.Hello, всегда ссылайтесь на него как на `MyApp.Hello` и никогда как на `Hello`.

• Ссылки на функции должны быть по имени и арности, если они локальные, как в `world/1`, или по модулю, имени и арности, если ссылаетесь на внешний модуль: `MyApp.Hello.world/1`.

• Для ссылки на @callback добавьте c:, как в `c:world/1`.

• Для ссылки на @type добавьте t:, как в `t:values/0`.

• Начинайте новые разделы с заголовков второго уровня Markdown ##. Заголовки первого уровня зарезервированы для имён модулей и функций.

• Размещайте документацию перед первым разделом функций с несколькими разделами. Документация всегда относится к каждой функции и арности, а не к каждому разделу.

• Используйте ключ :since в метаданных документации, чтобы отметить добавление новых функций или модулей в ваш API.

Doctest

Мы рекомендуем разработчикам включать примеры в свою документацию, часто в собственном разделе ## Examples. Для того, чтобы примеры не устаревали, фреймворк тестирования Elixir (ExUnit) предоставляет функцию под названием doctest, которая позволяет разработчикам тестировать примеры в своей документации. Doctest работает, разбирая примеры кода, начинающиеся с iex> из документации. Вы можете узнать больше о них по ссылке ExUnit.DocTest.

Документация ≠ Комментарии к коду

Elixir рассматривает документацию и комментарии к коду как разные понятия. Документация — это явный договор между вами и пользователями вашего Application Programming Interface (API), будь то сторонние разработчики, коллеги или ваше будущее «я». Модули и функции должны всегда быть документированы, если они являются частью вашего API.

Комментарии к коду предназначены для разработчиков, читающих код. Они полезны для маркировки улучшений, оставления заметок (например, почему вам пришлось прибегнуть к обходу из-за ошибки в библиотеке) и так далее. Они связаны с исходным кодом: вы можете полностью переписать функцию и удалить все существующие комментарии к коду, и она продолжит работать так же, без изменений в поведении или документации.

Поскольку к закрытым функциям нельзя получить доступ извне, Elixir выдаст предупреждение, если закрытой функции есть атрибут @doc и отбросит его содержимое. Однако вы можете добавлять комментарии к коду к закрытым функциям, как и к любому другому коду, и мы рекомендуем разработчикам делать это всякий раз, когда они считают, что это добавит полезную информацию для читателей и тех, кто поддерживает такой код.

Подводя итог, документация — это договор с пользователями вашего API, которые, возможно, не имеют доступа к исходному коду, а комментарии к коду предназначены для тех, кто взаимодействует непосредственно с исходным кодом. Вы можете выразить и обучить различные гарантии о вашем программном обеспечении, разделив эти два понятия.

Скрытие внутренних модулей и функций

Помимо модулей и функций, которые библиотеки предоставляют в рамках своего публичного интерфейса, библиотеки могут также реализовывать важную функциональность, которая не является частью их API. Хотя к этим модулям и функциям можно получить доступ, они предназначены для внутреннего использования в библиотеке и, следовательно, не должны иметь документации для конечных пользователей.

Удобно, что Elixir позволяет разработчикам скрывать модули и функции из документации, установив @doc false для скрытия конкретной функции или @moduledoc false для скрытия всего модуля. Если модуль скрыт, вы можете даже документировать функции в модуле, но сам модуль не будет отображаться в документации:

defmodule MyApp.Hidden do
  @moduledoc false

  @doc """
  This function won't be listed in docs.
  """
  def function_that_wont_be_listed_in_docs do
    # ...
  end
end

Если вы не хотите скрывать весь модуль, вы можете скрыть функции по отдельности:

defmodule MyApp.Sample do
  @doc false
  def add(a, b), do: a + b
end

Однако помните, что @moduledoc false или @doc false не делают функцию закрытой. Функцию выше всё ещё можно вызвать как MyApp.Sample.add(1, 2). Более того, если MyApp.Sample импортируется, функция add/2 также будет импортирована в вызывающую сторону. По этим причинам будьте осторожны при добавлении @doc false к функциям, вместо этого используйте один из этих двух вариантов:

• Переместите функцию без документации в модуль со свойством @moduledoc false, как MyApp.Hidden, гарантируя, что функция не будет случайно экспонирована или импортирована. Помните, что вы можете использовать @moduledoc false для скрытия целого модуля и всё ещё документировать каждую функцию с помощью @doc. Инструменты всё равно проигнорируют модуль.

• Начните имя функции с одного или двух подчёркиваний, например, __add__/2. Функции, начинающиеся с подчёркивания, автоматически обрабатываются как скрытые, хотя вы также можете быть явными и добавить @doc false. Компилятор не импортирует функции с ведущими подчёркиваниями, и они намекают любому, кто читает код, на их предполагаемое закрытое использование.

Code.fetch_docs/1

Elixir хранит документацию внутри предварительно определённых фрагментов в байткоде. Документация не загружается в память при загрузке модулей, вместо этого она может быть прочитана из байткода на диске с помощью функции Code.fetch_docs/1. Недостатком является то, что модули, определённые в памяти, такие как те, которые определены в IEx, не могут получить доступ к своей документации, так как они не записывают свой байт-код на диск.